+PROG SOFILOAD urs:21.1
HEAD Loads
ACT G_1
ACT G_2 SUP ALEX
ACT T GAMU 1.5*0.6 PSI0 0.8 $ 60% STIFNESS IN ULS
ACT A
ACT E
ACT E_2
ACT Z GAMU 1.0 GAMF 0 PSI0 1 PSI1 1 PSI2 1 PART Q SUP USEX TITL “Second order effects”
ACT P
ACT L_T
ACT L_U
ACT ZL GAMU 1.35 GAMF 0 PSI0 0 PSI1 0 PSI2 0 PS1S 0 PART Q SUP EXCL TITL “Braking/Traction”
ACT C
ACT R
ACT F GAMU 1.2
ACT X GAMU 1.35 GAMF 0 PSI0 1 PSI1 1 PSI2 1 PART G SUP USEX TITL “Imperfections”
ACT W SUP EXEX
ACT W_1 SUP EXEX PSI0 1 PSI1 0 PSI2 0 PS1S 1 TITL “Wind incl. traffic”
LC (1 9999 1) TYPE DEL
$------------------------------------------------------------------------------ LAR FOR SLAB LOADING
LOOP#I #SN
LAR NO X1 Y1 X2 Y2 X3 Y3 X4 Y4
1+10*(#I+1) GPT #SLAB_LEN(#I) GPT #SLAB_LEN(#I+1) #COOR_X(#SLAB_LEN(#I+1)) #COOR_Y(#SLAB_LEN(#I+1))+#L_W #COOR_X(#SLAB_LEN(#I)) #COOR_Y(#SLAB_LEN(#I))+#L_W $LEFT WALKWAY AREA
2+10*(#I+1) #COOR_X(#SLAB_LEN(#I)) #COOR_Y(#SLAB_LEN(#I))+#L_W #COOR_X(#SLAB_LEN(#I+1)) #COOR_Y(#SLAB_LEN(#I+1))+#L_W #COOR_X(#SLAB_LEN(#I+1)) #COOR_Y(#SLAB_LEN(#I+1))+#L_W+#A_W #COOR_X(#SLAB_LEN(#I)) #COOR_Y(#SLAB_LEN(#I))+#L_W+#A_W $ASPHALT AREA
3+10*(#I+1) GPT #SLAB_LEN(#I)+1 GPT #SLAB_LEN(#I+1)+1 #COOR_X(#SLAB_LEN(#I+1)+1) #COOR_Y(#SLAB_LEN(#I+1)+1)-#R_W #COOR_X(#SLAB_LEN(#I)+1) #COOR_Y(#SLAB_LEN(#I)+1)-#R_W $RIGHT WALKWAY AREA
ENDLOOP
$------------------------------------------------------------------------------
LC 1 TYPE G_1 FACD 1 TITL “Self-weight”
$$ ADDITIONAL ABUTMENT SELF-WEIGHT
$BEAM PA EYA=[M] FROM=GRP TO=10
$ 2.500.6025 (#A_CB_W-0.6)0.5-#A_CB_E $GUARDBALLAST
$ 5.000.30250.5 (#A_CB_W-0.2)0.5-#A_CB_E $APPROACH SLAB
$ 5.001.00190.5 = $EMBANKMENT ABOVE THE APPROACH SLAB
LC 39 TYPE G_1 TITL “Add. slab self-weight”
LOOP#I #SN
LOOP#J #BEAM_NUM
IF #J==0 ; LET#W #SLAB_LE+#BEAM_SPA/2 ; ELSEIF #J==#BEAM_NUM-1 ; LET#W #SLAB_RE+#BEAM_SPA/2 ; ELSE ; LET#W #BEAM_SPA ; ENDIF
BEAM FROM GRP TO ‘MB#(#J+1)#(#I+1)’ TYPE PG PA #ADD_T*#W25
BEPL FROM GRP TO ‘MB#(#J+1)#(#I+1)’ TYPE PG P -#ADD_T#W*25 OPT QUAM
ENDLOOP
ENDLOOP
$------------------------------------------------------------------------------
LC 2 GAMU 1.0 GAMF 1.0 TYPE G_2 TITL “Walkways”
AREA REF LAR NO (11 1+10*#SN 10) P1 0.3325 $LEFT WALKWAY = (A_WALKWAY)/#L_W)GAMMA_C
AREA REF LAR NO (13 3+10#SN 10) P1 0.2525 $RIGHT WALKWAY = (A_WALKWAY)/#R_W)*GAMMA_C
LC 3 GAMU 1.5 GAMF 0.8 TYPE G_2 TITL “Asphalt”
AREA REF LAR NO (12 2+10*#SN 10) P1 0.10*24
LC 4 GAMU 1.2 GAMF 0.8 TYPE G_2 TITL “Waterproofing”
AREA REF LAR NO (12 2+10*#SN 10) P1 0.01*24
LC 5 GAMU 1.05 GAMF 0.95 TYPE G_2 TITL “Barriers and handrails”
LINE REF EDG NO (1 1+2*#SN-2 2) P1 0.9 $LEFT BARRIER
LINE REF EDG NO (2 2+2*#SN-2 2) P1 0.9+0.35 $RIGHT BARRIER
LC 9 TYPE G_2 TITL “Non-str. self-weight (UNFAV)”
COPY 2,3,4,5 GAMU
LC 10 TYPE G_2 TITL “Non-str. self-weight (FAV)”
COPY 2,3,4,5 GAMF
$------------------------------------------------------------------------------
LC 11 TYPE T TITL “Pos. uniform temperature”
BEAM FROM GRP TO 1,4 TYPE DT PA 38.0
QUAD FROM GRP TO 2 TYPE DTXY P 38.0
LC 12 TYPE T TITL “Neg. uniform temperature”
BEAM FROM GRP TO 1,4 TYPE DT PA -30.5
QUAD FROM GRP TO 2 TYPE DTXY P -30.5
LC 13 TYPE T TITL “Pos. linear temperature”
BEAM FROM GRP TO 1 TYPE DTZ PA -15*0.7
LC 14 TYPE T TITL “Neg. linear temperature”
BEAM FROM GRP TO 1 TYPE DTZ PA 8*1.0
$ COMBINATION OF UNIFORM TEMPERATURE AND NON-LINEAR GRADIENT - APPROACH 2
LET#T_N 11,12
LET#T_M 13,14,13,14
LET#W_N 1.00,1.00,0.35,0.35
LET#W_M 0.75,0.75,1.00,1.00
LOOP#I 2
LOOP#J 4
LC NO 15+#J+4*#I TYPE T TITL “Temperature combination #(#(J)+1+4*#(I))”
COPY NO #T_N(#I) FACT #W_N(#J)
COPY NO #T_M(#J) FACT #W_M(#J)
ENDLOOP
ENDLOOP
LC 23 TYPE NONE TITL “Pos. uniform temperature (B&J)”
COPY 11
BEAM FROM GRP TO 1 TYPE DT PA 20
LC 24 TYPE NONE TITL “Neg. uniform temperature (B&J)”
COPY 12
BEAM FROM GRP TO 1 TYPE DT PA -20
$------------------------------------------------------------------------------
LET#L #L_BR
IF (360+2.7*#L<180)
LET#QLK 180
ELSEIF (360+2.7*#L>900)
LET#QLK 900
ELSE
LET#QLK 360+2.7*#L
ENDIF
PRT#QLK
PRT#L
LC NO 31 TYPE ZL TITL “Brake/Traction +X”
LINE TYPE PXX P1 #QLK/#L X1 0 Y1 0 X2 #L
LC NO 32 TYPE ZL TITL “Brake/Traction -X”
COPY 31 FACT -1
IF #L>=200
LC NO 33 TYPE ZL TITL “Brake/Traction +X”
LINE TYPE PXX P1 #QLK/200 X1 0 Y1 0 X2 200
LC NO 34 TYPE ZL TITL “Brake/Traction -X”
COPY 33 FACT -1
LC NO 35 TYPE ZL TITL “Brake/Traction +X”
LINE TYPE PXX P1 #QLK/200 X1 #L-200 Y1 0 X2 #L
LC NO 36 TYPE ZL TITL “Brake/Traction -X”
COPY 35 FACT -1
LC NO 37 TYPE ZL TITL “Brake/Traction +X”
LINE TYPE PXX P1 #QLK/200 X1 (#L-200)/2 Y1 0 X2 (#L+200)/2
LC NO 38 TYPE ZL TITL “Brake/Traction -X”
COPY 37 FACT -1
ELSE
ENDIF
$------------------------------------------------------------------------------
LC NO 40 TYPE NONE TITL “Nominal non-str. self-weight” $USED ONLY AS A MASS
COPY 2,3,4,5
LC NO 41 TYPE NONE TITL “Seizmic live load” $USED ONLY AS A MASS
LET#SLL 0.2*(3*9+(#A_W-3)2.5)/#A_W
PRT#SLL
AREA REF LAR NO (12 2+10#SN 10) P1 #SLL $LOAD ON ASPHALT AREA
$------------------------------------------------------------------------------
$LET#SET 10 $EXPECTED SETTLEMENT IN MM
$LOOP#K #SN+1
$ IF (#K==0)|(#K==#SN)
$ LC NO 51+#K TYPE F TITL “Settlement of support #(#K+1)”
$ NODE NO (161+#K100 161+#K100+#A_PILE_N-1 1) TYPE WZZ P1 #SET
$ ELSE
$ LC NO 51+#K TYPE F TITL “Settlement of support #(#K)”
$ NODE NO (100*(#K+1)+100*(#SN+1)+31 100*(#K+1)+100*(#SN+1)+#PILE_N_L*#PILE_N_T+30 1) TYPE WZZ P1 #SET
$ ENDIF
$ENDLOOP
$ NOT USED HERE BECAUSE OF HASE
$------------------------------------------------------------------------------
$ WIND LOAD ON SUPERSTRUCTURE
LET#W 6.25 $WIND LOAD WITHOUT TRAFFIC IN KN/M
LC NO 71 TYPE W TITL “Wind load w/o traffic +Y”
LINE REF EDG NO (1 1+2*#SN-2 2) TYPE PYY P1 #W
LC NO 72 TYPE W TITL “Wind load w/o traffic -Y”
LINE REF EDG NO (2 2+2*#SN-2 2) TYPE PYY P1 -#W
LC NO 73 TYPE W TITL “Wind load w/o traffic +X”
LINE TYPE PXX P1 0.25*#W X1 0 Y1 0 X2 #L
LC NO 74 TYPE W TITL “Wind load w/o traffic -X”
COPY 73 FACT -1
LET#W 7.65 $WIND LOAD WITH TRAFFIC
LET#PSI0 0.6
LC NO 81 TYPE W_1 TITL “Wind load with traffic +Y”
LINE REF EDG NO (1 1+2*#SN-2 2) TYPE PYY P1 #PSI0*#W
LC NO 82 TYPE W_1 TITL “Wind load with traffic -Y”
LINE REF EDG NO (2 2+2*#SN-2 2) TYPE PYY P1 -#PSI0*#W
END
+PROG SOFILOAD urs:21.2
HEAD
LC 2,3,4,5 TYPE NONE
END
#DEFINE ASE_GRP
GRP ALL
GRP 3,5 OFF
GRP2 2 QUEA 1E-5
#ENDDEF
#DEFINE ASE_GRP_SEISM
GRP ALL
GRP 3,5 OFF
GRP 9 FACS #FACS
GRP2 2 QUEA 1E-5
#ENDDEF
#DEFINE DYNA_GRP_SEISM
GRP 3,5 OFF
#ENDDEF
#DEFINE ASE_HASE
SYST PROB LINE
STEX
#ENDDEF
+PROG HASE urs:22.8
HEAD Halfspace stiffness
ECHO FULL EXTR
$CTRL SOLV NONL $ may be quicker and more efficient on big systems
HALF TYPE COOR FAKX 1 1 1 Z #ZMIN ZVAR AUTO
BORE (1 #SN+1 1)
GRP 11
END
+PROG ASE urs:1
HEAD T-beam philosophy definition
ECHO FULL FULL
#INCLUDE ASE_HASE
TBEX NOG AUTO
END
+PROG ASE urs:22.1
HEAD Calculation of forces and moments
ECHO
CTRL OPT SOLV VAL -
#INCLUDE ASE_HASE
#INCLUDE ASE_GRP
LC ALL
END
+PROG ASE urs:32.3
HEAD Calculation of imperfections
ECHO FULL NO
ECHO DISP FULL
#INCLUDE ASE_HASE
#INCLUDE ASE_GRP
LC 100 DLZ 1.00 FACT 1.00 TITL ‘Buckling eigenvalue PLC’
LCC 40
END
+PROG ASE urs:22.7
HEAD
CTRL WARN 609
ECHO FULL EXTR
SYST PLC 100
CTRL DIFF 8000
#INCLUDE ASE_HASE
#INCLUDE ASE_GRP
OBLI SX 1/100
LC 501 TYPE X DLZ 1.00 FACT 1.00 TITL ‘Imperfections’
LCC 40
END
SYST PLC 100
CTRL DIFF 8000
#INCLUDE ASE_HASE
#INCLUDE ASE_GRP
OBLI SY 1/200
LC 502 TYPE X DLZ 1.00 FACT 1.00 TITL ‘Imperfections’
LCC 40
END
+PROG SOFILOAD urs:32.6
HEAD
LC (501 530 1) TYPE DEL
END
+PROG SOFILOAD urs:24.5
HEAD Definition of Response Spectra - type 1
HEAD acc. to BDS EN 1998-1:2005/NA:2012
LET#IMPORTANCE_FACT 1.4
LET#S 1.2
LET#A_GR 0.11*9.81
STO#Q_LONG 1.5
STO#Q_TRAN 1.5
STO#NUMB_EIGE 60
$ ELASTIC SPECTRA IS USED. COLUMN MOMENT REDUCTION BY Q IS DONE IN AQB
LC 990 TYPE NONE TITL “100% X”
RESP TYPE EC-1 CLAS C MOD - SA #S SB 2.5*#S SMIN 0.200 TB 0.100 TC 0.500 TD 2.000 TE 4.000 K1 1.000 K2 2.000 AG #IMPORTANCE_FACT*#A_GR AH 1
ACCE DIR AX 1 AY 0
LC 991 TYPE NONE TITL “100% Y”
RESP TYPE EC-1 CLAS C MOD - SA #S SB 2.5*#S SMIN 0.200 TB 0.100 TC 0.500 TD 2.000 TE 4.000 K1 1.000 K2 2.000 AG #IMPORTANCE_FACT*#A_GR AH 1
ACCE DIR AY 1 AX 0
LC 992 TYPE NONE TITL “100% Z”
RESP TYPE EC-1 CLAS C MOD - SA 1.0 SB 3.0 SMIN 0.200 TB 0.100 TC 0.400 TD 2.000 TE 4.000 K1 1.000 K2 2.000 AG #IMPORTANCE_FACT*#A_GR AV 0.85
ACCE DIR AY 0 AX 0 AZ 1
END
+PROG ASE urs:28.1 $ CALCULATION OF EIGENVALUES
HEAD Calculation Of Eigenvalues
ECHO EIGE YES
ECHO GRP FULL
CTRL OPT SOLV VAL -
CTRL MCON 3
LET#FACS 0.4
#INCLUDE ASE_HASE
#INCLUDE ASE_GRP_SEISM
MASS 0
MASS -39
MASS -40
MASS -41
EIGE NEIG #NUMB_EIGE ETYP SIMU NITE - MITE - LC 8001
END
!*! PROG DYNA - EXTR
#DEFINE DYNA_EXTR
EXTR TYPE MAX STYP=CQC ACT=NONE
U #LC
N ++
VY ++
VZ ++
MT ++
MY ++
MZ ++
RS1 ++ ; RS2 ++ ; RS3 ++ ; RS4 ++
RS5 ++ ; RS6 ++ ; RS7 ++ ; RS8 ++
RS9 ++ ; RS10 ++ ; RS11 ++ ; RS12 ++
RS13 ++ ; RS14 ++ ; RS15 ++ ; RS16 ++
P ++ ; M ++
#ENDDEF
+PROG DYNA urs:24.2
HEAD Calculation of Spectras
ECHO EIGE,MASS YES
#INCLUDE DYNA_GRP_SEISM
CTRL STYP 3
EIGE NEIG #NUMB_EIGE TYPE REST LC 8001
MODD (1 #NUMB_EIGE 1) D 0.05
LC 990 $ 100X
LET#LC 701
#INCLUDE DYNA_EXTR
END
+PROG DYNA urs:24.3
HEAD Calculation of Spectras
ECHO EIGE,MASS YES
#INCLUDE DYNA_GRP_SEISM
CTRL STYP 3
EIGE NEIG #NUMB_EIGE TYPE REST LC 8001
MODD (1 #NUMB_EIGE 1) D 0.05
LC 991 $ 100Y
LET#LC 801
#INCLUDE DYNA_EXTR
END
+PROG DYNA urs:24.4
HEAD Calculation of Spectras
ECHO EIGE,MASS YES
#INCLUDE DYNA_GRP_SEISM
CTRL STYP 3
EIGE NEIG #NUMB_EIGE TYPE REST LC 8001
MODD (1 #NUMB_EIGE 1) D 0.05
LC 992 $ 100Z
LET#LC 901
#INCLUDE DYNA_EXTR
END
!*! PROG MAXIMA - combination 100_30_30
#DEFINE EARQ_X_Y
LC NO TYPE FACT
700+#A A1 1.0 ; 800+#B F 0.3 $ 100X “+” 30Y
700+#A A1 1.0 ; 800+#B F -0.3
700+#A A1 -1.0 ; 800+#B F 0.3
700+#A A1 -1.0 ; 800+#B F -0.3
800+#B A1 1.0 ; 700+#A F 0.3 $ 100Y “+” 30X
800+#B A1 1.0 ; 700+#A F -0.3
800+#B A1 -1.0 ; 700+#A F 0.3
800+#B A1 -1.0 ; 700+#A F -0.3
#ENDDEF
#DEFINE EARQ_X_Y_Z
LC NO TYPE FACT
700+#A A1 1.0 ; 800+#B F 0.3 ; 900+#C F 0.3 $ 100X “+” 30Y “+” 30Z
700+#A A1 1.0 ; 800+#B F 0.3 ; 900+#C F -0.3
700+#A A1 1.0 ; 800+#B F -0.3 ; 900+#C F 0.3
700+#A A1 1.0 ; 800+#B F -0.3 ; 900+#C F -0.3
700+#A A1 -1.0 ; 800+#B F 0.3 ; 900+#C F 0.3
700+#A A1 -1.0 ; 800+#B F 0.3 ; 900+#C F -0.3
700+#A A1 -1.0 ; 800+#B F -0.3 ; 900+#C F 0.3
700+#A A1 -1.0 ; 800+#B F -0.3 ; 900+#C F -0.3
800+#B A1 1.0 ; 700+#A F 0.3 ; 900+#C F 0.3 $ 100Y “+” 30X “+” 30Z
800+#B A1 1.0 ; 700+#A F 0.3 ; 900+#C F -0.3
800+#B A1 1.0 ; 700+#A F -0.3 ; 900+#C F 0.3
800+#B A1 1.0 ; 700+#A F -0.3 ; 900+#C F -0.3
800+#B A1 -1.0 ; 700+#A F 0.3 ; 900+#C F 0.3
800+#B A1 -1.0 ; 700+#A F 0.3 ; 900+#C F -0.3
800+#B A1 -1.0 ; 700+#A F -0.3 ; 900+#C F 0.3
800+#B A1 -1.0 ; 700+#A F -0.3 ; 900+#C F -0.3
900+#C A1 1.0 ; 700+#A F 0.3 ; 800+#B F 0.3 $ 100Z “+” 30X “+” 30Y
900+#C A1 1.0 ; 700+#A F 0.3 ; 800+#B F -0.3
900+#C A1 1.0 ; 700+#A F -0.3 ; 800+#B F 0.3
900+#C A1 1.0 ; 700+#A F -0.3 ; 800+#B F -0.3
900+#C A1 -1.0 ; 700+#A F 0.3 ; 800+#B F 0.3
900+#C A1 -1.0 ; 700+#A F 0.3 ; 800+#B F -0.3
900+#C A1 -1.0 ; 700+#A F -0.3 ; 800+#B F 0.3
900+#C A1 -1.0 ; 700+#A F -0.3 ; 800+#B F -0.3
#ENDDEF
+PROG MAXIMA urs:24.6
HEAD
ECHO FULL NO ; ECHO TABS YES ; ECHO RSET FULL
CTRL WARN 34
$ U | N | Vy | Vz | Mt | My | Mz | RS1 | … | RS16 | P | M
$ #A,#B,#C values 1 | 2 | 3 | 4 | 5 | 6 | 7 | 8 | … | 23 | 24 | 25
$ #A —> X ; #B —> Y ; #C —> Z
COMB 1 STAN BASE 3600 TYPE E TITL ‘Seizmic IE behaviour (X,Y)’
LET#A 1 ; LET#B 1
#INCLUDE EARQ_X_Y
LET#A 2 ; LET#B 2
#INCLUDE EARQ_X_Y
LET#A 3 ; LET#B 4
#INCLUDE EARQ_X_Y
LET#A 4 ; LET#B 4
#INCLUDE EARQ_X_Y
LET#A 8 ; LET#B 8
#INCLUDE EARQ_X_Y
LET#A 9 ; LET#B 11
#INCLUDE EARQ_X_Y
LET#A 8 ; LET#B 9
#INCLUDE EARQ_X_Y
LET#A 8 ; LET#B 11
#INCLUDE EARQ_X_Y
SUPP 1 MAMI BEAM N,MY,MZ,VZ,VY,MT
SUPP 1 MAMI NODE UX,UY
COMB 2 STAN BASE - TYPE E_B TITL ‘Seizmic IE behaviour (X,Y,Z)’
LET#A 1 ; LET#B 1 ; LET#C 1
#INCLUDE EARQ_X_Y_Z
LET#A 8 ; LET#B 8 ; LET#C 8
#INCLUDE EARQ_X_Y_Z
LET#A 9 ; LET#B 10 ; LET#C 8
#INCLUDE EARQ_X_Y_Z
LET#A 12 ; LET#B 11 ; LET#C 8
#INCLUDE EARQ_X_Y_Z
LET#A 24 ; LET#B 24 ; LET#C 24
#INCLUDE EARQ_X_Y_Z
LET#A 25 ; LET#B 25 ; LET#C 24
#INCLUDE EARQ_X_Y_Z
LET#BASE 3700
SUPP 2 MAMI NODE UX,UY LC 71+#BASE
SUPP 2 MAMI SPRI P,M LC 45+#BASE
LOOP#I 2
IF #I==0 ; LET#K 0 ; ELSE ; LET#K #SN ; ENDIF
LOOP#J #BEAM_NUM
SUPP TYPE LC FROM=‘B#(#K+1)#(#J+1)’ EXTR=MAMI COMB=2 ETYP=RSET
'B#(#K+1)#(#J+1)PZ’ 1+#BASE
'B#(#K+1)#(#J+1)UX’ 3+#BASE
'B#(#K+1)#(#J+1)UY’ 5+#BASE
'B#(#K+1)#(#J+1)RX’ 7+#BASE
'B#(#K+1)#(#J+1)_RY’ 9+#BASE
ENDLOOP
ENDLOOP
COMB 3 COMC 1 EXTR STAN BASE - TYPE E
LET#BASE 3600
LOOP#I #SN-1
LOOP#J #COL_NUM
SUPP TYPE LC FROM=‘F#(#I+1)’ EXTR=MAMI COMB=3 ETYP=RSET
‘N_C#(#J+1)F#(#I+1)’ 1+#J10+#BASE
‘VY_C#(#J+1)F#(#I+1)’ 3+#J10+#BASE
‘MZ_C#(#J+1)F#(#I+1)’ 5+#J10+#BASE
‘VZ_C#(#J+1)F#(#I+1)’ 7+#J10+#BASE
‘MY_C#(#J+1)F#(#I+1)’ 9+#J*10+#BASE
ENDLOOP
ENDLOOP
END