Einwirkungen für Eisenbahnverkehr

SOFiSTiK Teddy
1

Hallo,

Ich möchte Eisenbahnverkehrslasten (LM71) mit dem Satz LZUG eingeben aber ich verstehe nicht, wie das Modul SOFILOAD die vielen Lastfälle (Vertikalkräfte, Anfahren, Bremsen, Seitenstoß) den unterschiedlichen Einwirkungen zuteilt und wie ich sie dann in Lastgruppen nach EC1-2 Tabelle 6.11 kombinieren kann.

Bisher habe ich meine Lastfälle getrennt eingegeben, so dass ich sie mit MAXIMA anhand ihrer Einwirkungskategorie in Lastgruppen mit entsprechendem Faktor kombinieren konnte:

+PROG MAXIMA
KOPF Lastgruppen
LET#L_PHI #L
LET#PHI_3 2.16/(SQR(#L_PHI)-0.2)+0.73
IF #PHI_3 > 2
 LET#PHI_3 2
ENDIF
STO#PHI #PHI_3 $ Den Wert sieht man in der Tabelle der Ausgabe
$ Wir ändern temporär die Sup-Regel der Kategorie L_C (Lastmodell 71),
$ da wir die vertikalen Lasten bei der Bildung der Lastgruppen immer dabei haben wollen.
$ Ohne Zug, kein Anfahren/Bremsen (L_A) oder Seitenstoß (L_S).
KOMB NR 1 EXTR EXPL BASE 1100 TYPE GR_1 BEZ "gr11"
ADD TYP L_C FAKU 1 FAKF 0
LF NR -1 TYP ALEX FAKT #PHI
ADD TYP  FAKU FAKF
    L_A  1    0
    L_S  0.5  0

SUPP KOMB 1 EXTR MAMI ETYP STAB ZUST MY,MZ,VZ,VY,N,MT
SUPP KOMB 1 EXTR MAMI ETYP KNOT ZUST P

KOMB NR 2 EXTR EXPL BASE 1200 TYPE GR_1 BEZ "gr12"
ADD TYP L_C FAKU 1 FAKF 0
LF NR -1 TYP ALEX FAKT #PHI
ADD TYP FAKU FAKF
    L_A 0.5  0
    L_S 1    0

SUPP KOMB 2 EXTR MAMI ETYP STAB ZUST MY,MZ,VZ,VY,N,MT
SUPP KOMB 2 EXTR MAMI ETYP KNOT ZUST P

ENDE

Die weiteren Einwirkungen (Wind usw.) kommen in einem späteren MAXIMA-Lauf zur Erstellung der Bemessungskombinationen. Die Lastgruppen haben eigene ψ-Beiwerte, das läuft super.

Nun möchte ich es mit dem Satz LZUG probieren, damit ich die Vorzüge der achsenbasierte Modellierung/Parametrisierung nutzen kann. Wenn ich die Verkehrslasten mit dem Satz LZUG vorbereite und mit COPY eingebe:

LF NR 200 TYP NONE BEZ "Eigenschaften Wanderlast LM71"
LZUG TYP LM71 YEX 0 PHI 1 $ Keine Exzentrizität YEX, kein dynamischer Beiwert

SPUR 'HA' TYP EN
LOOP#I 20
    LET#J #I+1
    LF NR 201+#I TYP L_C BEZ "Wanderlast LM71 Stellung #J"
    COPY NR 200 REF HA DX #I/20*#L WIDE 10
ENDLOOP

landen alle Verkehrslasten in einem einzigen Lastfall ohne Unterscheidung, ob es sich um eine horizontale oder vertikale Belastung handelt. Und wo ist der Wind (LZUG P6 und P7)?
Wie kann ich dann meine Lastgruppen nach EC1-2 Tabelle 6.11 erstellen?

2

Ich empfehle hier einmal unser Tutorial einer Eisenbahnrahmenbrücke anzuschauen. Dort ist das Thema Überlagerung ausführlich diskutiert und eine Lösung vorgeschlagen, wie das umgesetzt werden kann.
Siehe hierzu auch das Kapitel Kombinatorik.

3

Vielen Dank für die schnelle Rückmeldung und danke für den Verweis auf das Tutorial. Ich hatte es mir früher schon mal angeschaut. Leider finde ich keine weiteren Informationen zu meiner Frage.

Ich sehe, dass im Modul MAXIMA die Lastgruppen anhand von Einwirkungskategorien erstellt werden (Ihr Link). Wie werden die Lasten den Einwirkungskategorien zugeteilt, wenn die Lasten mit LZUG erstellt werden?

Im Tutorial wird mit SOFiPLUS/SSD und freien Lasten gearbeitet (“Die Eingabe der Lastfälle erfolgt graphisch mit “Freien Lasten” in SOFiPLUS X.”). Ich möchte in Teddy mit dem Satz LZUG meine Lasten erstellen.

4

So, nach weiterer Recherche und Nachfrage bei einem Kollegen kam ich zu folgender (Teil-)Lösung: Lasten aus Lastenzügen können beim Kopieren (COPY) mit der Eingabe (TYP) je nach Richtung ausgewählt werden (siehe Handbuch 2025 Seite 3-46).

Um vertikale Eisenbahnlasten, Seitenstoß und Bremsen nach drei Einwirkungen zu trennen (z. B. L_C, L_S und L_A), kann man also so vorgehen:

+PROG SOFILOAD
KOPF Verkehrslasten
ECHO OPT LAST WERT VOLL

LF NR 200 TYP NONE BEZ "Eigenschaften Wanderlast LM71"
LZUG TYP LM71 PHI 1 YEX 0 $ Keine Exzentrizität YEX, kein dynamischer Beiwert

SPUR 'HA' TYP EN
LOOP#I 20
    LET#J #I+1
    LF NR 201+#I TYP L_C BEZ "Wanderlast LM71 Stellung #J"
    COPY NR 200 REF HA TYP GR1 DX #I/20*#L $ vertikale Komponente
ENDLOOP

LF NR 71 TYP L_A BEZ "Bremsen"
COPY NR 200 REF HA TYP GR2L DX #L/2 $ horizontale Komponente longitudinal

LF NR 81 TYP L_S BEZ "Seitenstoß"
COPY NR 200 REF HA TYP GR2T DX #L/2 $ horizontale Komponente transversal

ENDE

Wie LZUG die Anfahr- und Bremslasten getrennt erstellt, habe ich noch nicht verstanden.
Die Trennung von Wind und Seitenstoß (beide horizontal und transversal zur Erzeugungsachse) ist mir auch noch nicht gelungen.
Ich würde mich freuen, wenn mir jemand dazu helfen könnte.

5

Bremsen und Anfahren ist im Grunde das gleiche. Gibt es einen LZUG mit DIR B, wirkt diese Längskraft in beide Richtungen, wenn man ELLA verwendet. Erzeugt man Lastfälle mit COPY, muss man schauen, in welche Richtung diese Last wirkt.
Um je einen Lastfall sowohl für Bremsen als auch für Anfahren zu erzeugen, könnte man z.B. zwei Lastenzüge verwenden, wobei einer eine positive und der andere eine negative “Bremslast” hat.
Für Wind und Seitenstoß gilt das analog.

6

Vielen Dank für die Erklärung!

Wenn ich richtig verstehe, ist der Satz LZUG auf die Nutzung von ELLA zugeschnitten (was die Tatsache erklärt, warum die Seiten zu LZUG in den Handbüchern SOFiLOAD und ELLA identisch sind). Nur bei der Nutzung von ELLA werden die ganzen Parameter berücksichtigt (z. B. LZUG DIR B).

Wenn man aber mit SOFiLOAD COPY arbeitet, muss man diese unterschiedlichen Lastfälle, Richtungen und die zugehörigen Einwirkungen händisch einpflegen.

Ist das korrekt? Irgendwie hatte ich das im Handbuch von SOFiLOAD (Seiten 5-1 ff.) nicht ganz verstanden.

7

Ja, das ist korrekt.

Es gibt allerdings eine Sache, die ELLA mit einem LZUG nicht kann: Die Räder von einem LZUG haben Abmessungen, so dass eine einzelne Radlast auch als Flächenlast wirken könnte. Genau das kann aber mit ELLA nicht gemacht werden, ELLA bringt dann immer eine Punktlast auf.
Erzeugt man aber einen Lastfall mit COPY in SOFiLOAD, will dabei Flächenelemente belasten und definiert in SOFiLOAD entsprechend ein STEU COPY 2+4*6, bekommt man diese Flächenlasten.