+PROG TEMPLATE urs:1
KOPF Parameter

!Geometrie
sto#b  0.3   ! Trägerbreite [m]
sto#h  0.4   ! Trägerhöhe [m]
sto#L  3.8   ! Trägerlänge [m]

!Material
 !Beton
sto#fck  30    ! Chark. Zylinderdruckfestigkeit [N/mm²]

!Bewehrung
 !untere Lage
STO#N1   3                  ! Anzahl Bewehrungsstäbe
STO#Ds1 14                  ! Durchmesser [mm]
STO#As1 =PI*#Ds1^2/400*#N1  ! Fläche [cm²]
prt#As1
STO#d1 50                   ! Abstand SP Bew. - UK Balken [mm]

 !obere Lage
STO#N2   2                  ! Anzahl Bewehrungsstäbe
STO#Ds2 10                  ! Durchmesser [mm]
STO#As2 =PI*#Ds2^2/400*#N2  ! Fläche [cm²]
prt#As2
STO#d2 50                   ! Abstand SP Bew. - OK Balken [mm]

ENDE

!+!Kapitel Querschnitt
+PROG AQUA urs:2
KOPF Querschnittsdefinition
ECHO VOLL VOLL

NORM DIN EN1992-2004

! Materialien
BETO 1 ART C FCN #fck !FCT 5 FCTK 5
STAH 2 ART B GUET 500B FY 500 FT 540  ! Betonstahl
ARBL EPS GEBR 1.0 TS I MUET #As1/(#b*2.5*#d1*10) FCTF 1.0

! Querschnitt
QB 1 H #h*1000 B #b*1000 MNR 1 SO #d2 SU #d1 BTYP ECKE DASO #ds2 DASU #ds1 MBW 2 !ASB #pi*0.3^2/0.15

QNR 2 MNR 1 MBW 2 BEZ 'Rechteckquerschnitt'

! Geometrie
QPOL U
QP  11  #b*1000/2 -#h/2*1000
    12  #b*1000/2  #h/2*1000
    13 -#b*1000/2  #h/2*1000
    14 -#b*1000/2 -#h/2*1000

! Bewehrung
LBEW 'L1'  YA -#D2 ZA  #D2 REFA 11     $$
           YE  #D2 ZE  #D2 REFE 14 A #N2[-] D #DS2 RANG 1 TORS AKTI

LBEW 'L2'  YA -#D1 ZA -#D1 REFA 12     $$
           YE  #D1 ZE -#D1 REFE 13 A #N1[-] D #DS1 RANG 2 TORS AKTI

RANG 1 TID 'Asl,o' MBW 2
RANG 2 TID 'Asl,u' MBW 2

ENDE

+PROG AQB urs:5
KOPF Interaktionskurven
ECHO VOLL EXTR

CAPA NQ 1 TASK MC STAT SL MY 1000 N 0
CAPA NQ 2 TASK MC STAT SL MY 1000 N 0

ENDE