!#!Info  Example:       Prestressed bridge with design
!#!Info  Keyword:       temperature; settlement; prestress; tendon; Design; traffic
!#!Info  Program:       CSM
$
$

$ english file name: csm31_design.dat
$
$
$ Example bridge construction   i,c,b...Location of the data-files:
$ **************************
$                             ase = Your Program folder sofistik...\ase   \english   (aqb.zip)
$                               b = Your Program folder sofistik...\bemess\english
$                               c = Your Program folder sofistik...\csm   \english   (csm.zip)
$ - extern_prestress_cables.dat  ase\english\bridge\
$ - extern_prestress_cables.dat         "
$ - bridge_design_manual_aqb.dat        "
$ - box_girder_torsion_shear_design.dat "
$ - stahl_verbund_*.dat                 "
$
$ - csm31_design.dat            c\design major bridge example with automatic dimensioning with the CSM
$ - csm31_design_cabd.dat       c\cabd with axis variables haunched in folder more\csm31_design_cabd.dat
$ - csm31_design_ella.dat       c\more in folder more\csm31_design_ella.dat
$                                 See csm.zip -> sofistik...\csm.dat\english\csm31_design.dat
$
$ - prestressed_slab.dat        b FE-Prestressed concrete slab (without columns) incl. fatigue design

$   csm32_slab_design.dat       c\design as prestressed_slab.dat but with CSM

$ - csm10_composite_cabd.dat    c\cabd Concreting in Step back reversal method  - Creep and shrinkage

$ - bemess6_design.dat       b Building slab
$ - bemess5_Schwingbreiten.dat  b SLS design slabs

$ - See also csm.dat\english\overview_csm_examples_english.pdf:
$ -   Numerous bridge examples can also
$ -   be inserted with SSD task „beam and slabbridge“
$ -
$ -   There you can easily create a bridge and then
$ -   look into the produced input file (SSD-Task-beam and slabbridge - right mouse button - edit)

!#!Kapitel System
+PROG AQUA URS:1
HEAD Prestressed bridge - checks with the CSM-Design Module
NORM 'NS' 'en199X-200X-BRIDGE'     CAT 'B'  $ road bridges
CTRL REST 1
UNIT 5 $ units: sections in mm, geometry+loads in m
$ CTRL styp BEM
!*!Label Material
CONC  1  C   40        $ = C40/50
STEE  2  S 500               $ standard reinforcement steel 500
STEE  7    S  '235' $ TMAX  0 $ structural steel for tubes, rolled steel ...
STEE 11    Y '1860A' $ prestessing steel
                    $ fp0,1k = 1600 N/mm2
                    $ fpk    = 1860 N/mm2
                    $            0.8*fpk    = 0.80*1860 = 1488 N/mm2
                    $            0.9*fp0,1k = 0.90*1600 = 1440 N/mm2
                    $ sigp,max = min(1488,1440)         = 1440 N/mm2 EN-1992-1-1 5.10.2.1(1) maximum stress
                    $ sigp,SLS = 0.65*fpk   = 0.65*1860 = 1209 N/mm2 EN-1992-1-1 7.2(5)      on traffic opening permanent
                    $ sigp,rare= sigp,max
STEE 18    Y '1860'

!*!Label Section 1
SECT  1 MNO  1
POLY  OPZ MNO 1
VERT no    Y        Z   R   EXP
     1  0.00[m] 0.00[m] -  0.50 $ air contact
     2 -4.00[m] 0.00[m] -  1.00 $ for all following points
     3 -4.00[m] 0.25[m]
     4 -1.70[m] 0.45[m]
     5 -1.30[m] 0.62[m] -1.0[m]
     6 -0.90[m] 1.30[m] -1.0[m]
     7  0.00[m] 1.30[m]
let#zmax   1300 $ mm
$
$  Torsionsbox:  *---------------------> y
$                |
$     *----------|----------*     #ztop
$     |          |<--#ytop->|
$     |          |          |
$     |          |          |
$     |          |<--#ybot->|
$     *----------|----------*     #zbot
$                z
  let#ytop  750 $ [mm] y-value of Torsionsbox above
  let#ybot  750 $ [mm] y-value of Torsionsbox below
  let#ztop  110 $ [mm] z-value of Torsionsbox above
  let#zbot #zmax-110 $ "       of Torsionsbox below
RF Y #ytop,-#ytop Z #ztop AS 10[cm2] LAY 0 TORS acti D  12
RF Y #ybot,-#ybot Z #zbot AS 10[cm2] LAY 0 TORS acti D  12
$ bending reinforcement:
  let#ytop 1900 $ [mm]
  let#ybot  850 $ [mm]
  let#ztop   60 $ [mm]
  let#zbot #zmax-60
RF Y #ytop,#ytop/3,-#ytop/3,-#ytop Z #ztop AS 10[cm2] LAY 2 TORS pass D  20 $ above
RF Y #ybot,#ybot/3,-#ybot/3,-#ybot Z #zbot AS 10[cm2] LAY 1 TORS pass D  20 $ below
CUT 1 ZB  500    MNO 1        LAY 1 $ By  x=3.80 m of the support above the tendon
CUT 2 ZB  700    MNO 1        LAY 1 $ By  x=3.80 m of the support underneath the tendon
CUT 3 YB 1300    MNO 1        LAY 3 TYPE FLAN  $ belt
CUT 4 YB 1700    MNO 1        LAY 3 TYPE FLAN  $ belt
SPT    NO    Y   Z     MNO
     'TOP'   0   0      1
     'BOT'   0  #zmax   1 $ input literal BOT in kapitel letters
!*!Label Section 9
SREC 9 H 1.5[m] B 4[m] $ piers
END

+PROG SOFIMSHA urs:3
HEAD Prestressed bridge - checks with the CSM-Design Module
UNIT 5 $ units: sections in mm, geometry+loads in m
SYST SPAC GDIV 1000 POSZ
NODE (101 121 1) X (0 21.4/10)
GRP 1
  BEAM (101 110 1) (101 1) (102 1) NCS 1 NP -1
GRP 2
  BEAM (111 120 1) (111 1) (112 1) NCS 1 NP -1
  $
  BSEC NO 1101,2111 X 0.30 ncs 1 spec A typm HFAC
  BSEC NO 1101,2111 X 1.10 ncs 1 spec A typm SHEA
  BSEC NO 1110,2120 X 1.10 ncs 1 spec E typm SHEA
  BSEC NO 1110,2120 X 0.30 ncs 1 spec E typm HFAC
$
GRP 9
$ Den folgenden Block können Sie ohne Änderung verwenden und nur die
$ darunter stehenden Variablen let#node ... setzen !
$ (Voraussetzung: Knotennummern im Überbau < 1000)
#define support01
  let#dhspring        0 $ m bearing height
    $ bearing springs
    let#sy 0.5*#b0
             TRAN node #node dy  #sy dz #h dno 51000
    if #b0 ; tran node #node dy -#sy dz #h dno 53000 ; endif
             TRAN node #node dy  #sy dz #h dno 52000
    if #b0 ; tran node #node dy -#sy dz #h dno 54000 ; endif
    $ node on top of pier: node 49000...
             tran node #node                 dz #h dno 49000
             node #node+51000 FIX KF #node               $ coupling
    if #b0 ; node #node+53000 FIX KF #node      ; endif  $ coupling
             node #node+52000 FIX KF #node+49000         $ coupling
    if #b0 ; node #node+54000 FIX KF #node+49000 ; endif $ coupling
             SPRI #node+0 #node+51000 #node+52000 DZ 1 CP 1E7  $ vertical bearing
    if #b0 ; SPRI #node+1 #node+53000 #node+54000 DZ 1 CP 1E7  ; endif
    $ transverse bearing springs:
             SPRI #node+3 #node+51000 #node+52000 dy 1 CP 1E6 $ transverse
    $ longitudinal bearing springs:
    let#cp_long 1.0                       $ weak - to get bearing displacements
    if #logitud ; let#cp_long 1E6 ; endif $ longitudinal fixed bearing
             SPRI #node+7 #node+51000 #node+52000 dx 1 CP #cp_long $ longitudinal
    if #b0 ; SPRI #node+8 #node+53000 #node+54000 dx 1 CP #cp_long ; endif $ longitudinal
  $ node bottom of pier: node 50000...
  tran node #node dz #UKpier dno 50000
  BEAM #node 50000+#node 49000+#node NCS 9 KR POSY
  node #node+50000 FIX F                 $ fixed support
#enddef
$
let#node         101 $ basenumber of node in superstructure
let#h            1.5 $ m cross section height
let#b0           3.5 $ m bearingspread
let#UKpier         4 $ m bottom level pier
let#logitud        0 $ =1 bearing fixed in longitud. direction
#include support01
$
let#node         111 $ basenumber of node in superstructure
let#logitud        1 $ =1 bearing fixed in longitud. direction
let#UKpier         9 $ m bottom level pier
#include support01
$
let#node         121 $ basenumber of node in superstructure
let#logitud        0 $ =1 bearing fixed in longitud. direction
let#UKpier         4 $ m bottom level pier
#include support01

$ Group title for WINGRAF:
GRP   1 titl 'Superstructure span 1'
GRP   2 titl 'Superstructure span 2'
GRP   9 titl 'Pier'

END

!#!Kapitel Loading, Prestress
+PROG SOFILOAD URS:4
HEAD actions and loads
$ actions bridge design
$ All actions should be defined here.
$ This can be done in a separate SOFILOAD run as shown here.
ECHO ACT Full $ Please check GAMU factors, especially for L_U and L_T (in germany GAMU 1.35)
UNIT 5 $ units: sections in mm, geometry+loads in m
ACT G_1                                                              TITL 'dead load'
ACT G_2                                                              TITL 'dead load'
ACT P                                                            TITL 'prestress'
ACT C                                                                TITL 'C+S'
ACT ZC  GAMU 1.00 1 SUP PERM PSI0 1.00 PSI1 1.00 PSI2 1.00           TITL '                            life load creep part'
ACT L_T GAMU   -  0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S    - TITL 'TS Tandemsystem'
ACT L_U GAMU   -  0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'UDL basic load'
ACT L_1 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'UDL overload span 1'
ACT L_2 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'UDL overload span 2'
ACT L_3 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'UDL overload span 3'
$ The GAMU and PSI factores are taken from the .ini file depending on the design code (-> check)
$ You can also define them nanually here e.g. with:
$ ACT L_T GAMU 1.35::1.50 0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S    - TITL 'TS Tandemsystem'
$ ACT L_U GAMU 1.35::1.50 0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'UDL basic load'
  $ Superposition with ELLA traffic loading see more\csm31_design_ella.dat
  $ here SUP COND=special case, since L_U is applied in MAXIMA/AQB without inter superposition!
  $ L_1 with multiple UDL over loads in transvers direction needs EXCL, because only one to be taken
ACT SL  GAMU 1.50 0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S    - TITL 'loading during construction'
$--------------------------------------------------------------------------
ACT FAT GAMU 1.50 0 SUP EXCL PSI0 1 1 1                              TITL 'Fatigue LM3'
ACT SF  GAMU 1.00 0 SUP EXCL PSI0 1 1 1                              TITL 'possible settlement ULS'
ACT ZF  GAMU 1.00 0 SUP EXCL PSI0 1 1 1                              TITL 'probable settlement SLS'
  $ Acc. DIN FB 101 - C.2.3 for settlements GAMA=1.00.
ACT W                                                                TITL 'wind transvers'
ACT T   GAMU 0.81 0 SUP EXCL PSI0 0.80 PSI1 0.60 PSI2 0.50 PS1S    - TITL 'temperatur'
  $ In the ULS design you can usually take the temperature forces only with 60 %
  $ because the concrete may crack and will have only 60% stiffness for the temperature effect in ULS.
  $ Hence to simplify, set the ULS-gama-u value by 1.35 to 0.81 (0.81 = 1.35*0.60).
  $ So: safety factor = 1.35 but only with factor 0.6 due to reduced stiffness (60% stiffness)
  $---------------------------------------------------------------------------------------------------------
ACT Q   GAMU 1.50 GAMF 0.00 SUP COND PSI0 1.00 PSI1 1.00 PSI2 1.00  TITL 'life load in construction stages'
ACT B   GAMU 1.35 1 PART G SUP PERM PSI0 1 1 1                              TITL 'construction stage'
$
$ The signs SUP PERM,COND,EXCL are necessary and set itself according to
$ the definition of traffic load cases:
$    SUP EXCL - only one out of available load cases
$    SUP CONC - all of the available load cases, if acting unfavourable
           $ Meaning of PSI-Value:
           $
           $ Fraction :(1.00*Q-Leit + PSI0*Qki)*GAMU-GAMF
           $
           $ Rare    : 1.00*Q-Leit + PSI0*Qki
           $ frequent: PSI1*Q-Leit + PSI2*Qki
           $ quasi   : PSI2*Q-Leit + PSI2*Qki  =    PSI2*Q-all
           $ not     : PSI1*Q-Leit + PSI1*Qki
           $
           $ to  : (ING-BAY-Buba-S.15)
           $ See MAXIMA - theoretical basics
$ G if as generic term effects G the under effects
$ G_1 and G_2 combined! alike L the L_U plus L_T combined!
$ not but Z the ZF and ZS, as no underline follows!
$------------------------------------------------------------------------------------------------
END
END

$ Overview used user - load case nos:
$ 1- 99 basic load cases see following Sofiload-rund
$ UDL base-loads are definied in a way that they can be combined additive
$ (LC 21-24) ACT - SUP COND, thus no inter superposition is necessary
$
$ The  Tandemsystem-Load cases 41-61 exclude each other EXCL
$ an also no inter superposition is necessary!

+PROG TENDON urs:9
HEAD Parabolic Prestress
UNIT 5 $ units: sections in mm, geometry+loads in m
$ Definition of prestressing system:
$ We recommend to input all data as user defined prestressing system.
$ For the static analysis the following values are sufficient:
SYSP NOPS MAT   ZV       AZ    LITZ MINR   BETA  MUE ECC  SP     DO
      $ 1  11 2430[kN] 1800[mm2] 12 6.50[m] 0.3 0.20 4[mm] 3[mm] 82[mm] $ csm3_parabel and csm32_slab, 12 wires
      $ 1  11 3078[kN] 2250[mm2] 15 7.10[m] 0.3 0.20 4[mm] 3[mm] 92[mm] $            15 wires
        1  11 3848[kN] 2850[mm2] 19 6.50[m] 0.3 0.21 4[mm] 3[mm] 97[mm] $ csm31_beam 19 wires
      $ 1  11 2430[kN] 1800[mm2] 12 6.50[m] 0.0 0.00 0[mm] 0[mm] 10[mm] $ csm3_casting_yard
$
$ reference axis and span definition:
AXES NOH 1 TYPE AUTO  101 121
TOPP NOH 1 KIND NODE S 101,111,121 SP 1,2,3
           $ S=101 .. SP 1 =  Node 101 is beginning first span
$ or  TOPP NOH 1 KIND NODE S 101,102,111,120,121 SP 0,1,2,3,4 with excess from 101-102
$ tendon geometry definition:  NOPS = prestressing system for max-min radius parameters + duct-excentricities
TGEO NOG 1 NOH 1 NOPS 1
$ Definition points of geometry:  (TYP=SPAN/FELD station via highpoints)
PTUV    S     U     V   DVS    RV   RL   TYPE=SPAN
        1     0   0.4     -    -     -
      1.4     -   1.22    0    -     -
        2     0   0.16    0    9.5   1.3
      2.6     -   1.22    0    -     -
        3     0   0.4     -    -     -
$ Additional values: construction stages:
CS ICS1 11 22 $
$ prestress-procedure
PSIG 'RILE' ANWS 9 KAPA - K3 1280 $
        $ k3 = estimated limit to reduce stress at traffic opening (after first creep+shrinkage)
        $      max-sigma-traffic opening in most cases (e.g. to EN-1992-1-1 7.2(5)) -> 0.65 fpk (or 0.75 depending on design code)
$ final tendon definition:
TEND NOT 1 NOG 1 NTEN 4 LC 3 LC0 0
$
echo plot full $ tendon plots:
SIZE URS
$
PLOT GEOE NO all FACH  5 TYPG DUTE
PLOT FACT NO 1 FACH 15
end

+PROG SOFILOAD urs:8
HEAD
UNIT 5 $ units: sections in mm, geometry+loads in m
LC  1 FACD 1.0 TITL 'G_1'  TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm

LC  2         TITL 'G_2'  TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
   BEAM GRP 1,2 TYPE PZZ 15
LC  3 TITL 'prestress'    TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm

  $ Traffic via influence line evaluation: see csm.dat\...\more\csm31_design_ella.dat
  $ would require L_U EXCL!

  $ here SUP COND=special case, since L_U is applied in MAXIMA/AQB without inter superposition!
  $ L_1 with multiple UDL over loads in transvers direction needs EXCL, because only one to be taken

$ Load model 1 acc. EN 1991 german annex
!*!Label UDL
$ UDL basic load 3 kN/m2
LC 21 TITL 'UDL-span-1-r'   TYPE L_U
   BEAM GRP 1 TYPE PZZ PA 3.0*4.80        EYA  2.4[m] $ 4.80 m width
LC 22 TITL 'UDL-span-1-l'   TYPE L_U              $ = half bridge
   BEAM GRP 1 TYPE PZZ PA 3.0*4.80        EYA -2.4[m] $ 4.80 m width
LC 23 TITL 'UDL-span-2-r'   TYPE L_U
   BEAM GRP 2 TYPE PZZ PA 3.0*4.80        EYA  2.4[m] $ 4.80 m width
LC 24 TITL 'UDL-span-2-l'   TYPE L_U
   BEAM GRP 2 TYPE PZZ PA 3.0*4.80        EYA -2.4[m] $ 4.80 m width

$ overload lane 1+2
LC 31 TITL 'UDL-overload-r-1' TYPE L_1
   BEAM GRP 1 TYPE PZZ PA (12.0-3.0)*3    EYA  2.10[m] $ 2.10 m  maxi. excentricity
   BEAM GRP 1 TYPE PZZ PA  (6.0-3.0)*3    EYA  2.10-3.00[m] $ Lane 2 depending on national annex
LC 32 TITL 'UDL-overload-l-1'  TYPE L_1
   BEAM GRP 1 TYPE PZZ PA (12.0-3.0)*3    EYA -2.10[m]
   BEAM GRP 1 TYPE PZZ PA  (6.0-3.0)*3    EYA -2.10+3.00[m] $ Lane 2 depending on national annex

LC 33 TITL 'UDL-overload-r-2' TYPE L_2
   BEAM GRP 2 TYPE PZZ PA (12.0-3.0)*3    EYA  2.10[m]
   BEAM GRP 2 TYPE PZZ PA  (6.0-3.0)*3    EYA  2.10-3.00[m] $ Lane 2 depending on national annex
LC 34 TITL 'UDL-overload-l-2'  TYPE L_2
   BEAM GRP 2 TYPE PZZ PA (12.0-3.0)*3    EYA -2.10[m]
   BEAM GRP 2 TYPE PZZ PA  (6.0-3.0)*3    EYA -2.10+3.00[m] $ Lane 2 depending on national annex

$ Maxima can take one loadcase of L_1 and one loadcase of L_2

!*!Label TS Tandem System
$ Tandemsystem : Lane 1:Wheel load 150 kN/Rad TS=SOFILOAD-TYP L !
$                  Total excess load=600 kN    (Please check safety factor GAMU ! 1.35/1.50)
$                Lane 2:Wheel load 100 kN/Rad
$                  Total excess load=400 kN
$ =======================================================================
$ Case EYA1 Lane 1 is at right     all xx m a Node position!
$----------------------------------------------------------------------------------------

$ Distribution of of lanes acc.  EC
$ traffic width 7.20m:
$ vehicle full right: EYA1= 7.20m/2 - 1.50m =  2.10 m = center of lane 1
$                     EYA2= 2.10 m  - 3.00m = -0.90 m = center of lane 2

loop#1 20
 LC 101+#1 TITL 'Tandem system lane 1+2'   TYPE L_T
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY  2.10+1.0[m]  $ EYA1
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY  2.10-1.0[m]
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY -0.90+1.0[m]  $ EYA2
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY -0.90-1.0[m]
endloop
   $ Achsabstand   1.20 m = +- 0.60   - axis distance 1.20 m = +- 0.60

 LC 201    TITL 'Tandem system left lanes'   TYPE L_T    $ only two to show principle !
   let#1 4
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10+1.0[m]  $ EYA1 left
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10-1.0[m]
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90+1.0[m]  $ EYA2 left
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90-1.0[m]
 LC 202    TITL 'Tandem system left lanes'   TYPE L_T    $ only two to show principle !
   let#1 6
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10+1.0[m]  $ EYA1 left
   BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10-1.0[m]
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90+1.0[m]  $ EYA2 left
   BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90-1.0[m]

!*!Label Settlement
$ The potential ground movements in the check of ultimate limit state are to be affixed, by their determination
$ accor. to (German)DIN FB 102 II-2.3.2.2(103)P, without any further checks a 0.6-times stiffness of
$ state I to be deposed (due to potential transfer in to state II).Accor. to the opinion of SOFiSTiK (Dr. Bellmann)
$ then in the superposition a load safety factor g=1.35 to be affixed
LC 81 TITL 'possible settlement ULS 1+3'  TYPE SF  $ 'mögl.Setzung 1+3'
   NODE NO 50101,50121  TYPE WZZ 1000*0.01*0.60[mm] $ entspricht Berechnungen mit 0.6-fachen Steifigkeiten
                                           $ equivalent analysis with 0.6-times stiffness
LC 82 TITL 'possible settlement ULS 2'    TYPE SF  $ 'mögl.Setzung 2'
   NODE NO 50111        TYPE WZZ 1000*0.01*0.60[mm]
$ The probable ground movements in checks of serviceability
$ limit state must be applied 1.0- times, see DIN FB 102 II-2.3.4(110)P.
$ The 0.6- reduction is not feasible here!
$ 1 cm as possible settlement ULS and 0.5 cm as probable settlement SLS is applied in this analysis,
$ respectively per column axis applied and superposed unfavorable.
LC 83 TITL 'probable settlement SLS 1+3'  TYPE ZF    $ wahrscheinliche Setzung 1+3
   NODE NO 50101,50121 TYPE WZZ 1000*0.005[mm]
LC 84 TITL 'probable settlement SLS 2'    TYPE ZF    $ wahrscheinliche Setzung 2
   NODE NO 50111       TYPE WZZ 1000*0.005[mm]

$----------------------------------------------------------------------------------------------
LC 86 TYPE none TITL 'TN-summer'      ; BEAM GRP 1,2 TYPE DT   PA  37-10 $ 10 Grad Aufstelltemperatur
LC 87 TYPE none TITL 'TN-winter'      ; BEAM GRP 1,2 TYPE DT   PA -17-10 $ 10 degree erection temperature
LC 88 TYPE none TITL 'DT warm on top' ; BEAM GRP 1,2 TYPE DTZ  PA -7.9 $ (ING-BAY-Buba-S.10)
LC 89 TYPE none TITL 'DT warm bottom' ; BEAM GRP 1,2 TYPE DTZ  PA  5.0 $ (ING-BAY-Buba-S.10)

$ Temperature combinations   -    Temperatur  Kombinationen:
LC 90 TYPE T TITL 'T summer posdt TN+wm*dT' ; COPY 86           ; COPY 88 FACT 0.75
LC 91 TYPE T TITL 'T summer negdt TN+wm*dT' ; COPY 86           ; COPY 89 FACT 0.75
LC 92 TYPE T TITL 'T winter posdt TN+wm*dT' ; COPY 87           ; COPY 88 FACT 0.75
LC 93 TYPE T TITL 'T winter negdt TN+wm*dT' ; COPY 87           ; COPY 89 FACT 0.75
LC 94 TYPE T TITL 'T summer posdt wn*TN+dT' ; COPY 86 FACT 0.35 ; COPY 88
LC 95 TYPE T TITL 'T summer negdt wn*TN+dT' ; COPY 86 FACT 0.35 ; COPY 89
LC 96 TYPE T TITL 'T winter posdt wn*TN+dT' ; COPY 87 FACT 0.35 ; COPY 88
LC 97 TYPE T TITL 'T winter negdt wn*TN+dT' ; COPY 87 FACT 0.35 ; COPY 89
$ ----------------------- Einheitstemperaturlastfälle für Lagerwege -----
$ ----------------------- + 10 Grad gleichmässige Mittentemperatur  -----
LC 98 TYPE none TITL 'Temp 10 degree constant'
  BEAM GRP 1,2 TYPE DT   PA 10      $ Überbau
$ ----------------------- + 10 Grad dt/h oben warm   ---------
LC 99 TYPE none TITL 'Temp dt/h 10 degree warm on top'
  BEAM GRP 1,2 TYPE DTZ PA -10
$----------------------------------------------------------------------------------------------

!*!Label Load in construction stage
$ load in construction stage on one span only:
LC 71 TITL 'SL_construction'   TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
   BEAM GRP 1 TYPE PZZ PA 1*2.5           EYA  0.0[m]

!*!Label Wind
LC 72 TITL 'wind_transvers'  TYPE W   $ will not be used further!
   BEAM GRP 1,2 TYPE PYY  30.0        $ only to test!
END

+PROG ASE URS:6
HEAD Analysis of single load cases
ECHO FORC,DISP,LOAD no
LC  1,2,3       $ G_1, G_2, P
LC 9 FACD 1.0 TITL 'G_1+G_2+P' TYPE none
  LCC 2,3 $ If LC 1 has yet loads apart of FACD, then also LCC 1!
         $ To compare G1+G2+P in a LC 9
LC  21,22,23,24 $ UDL basic loads span 1
LC  31,32,33,34 $ UDL super loads span 2
LC  (101 120 1) $ Tandem loads right
LC   201,202    $ Tandem loads left $ only two to show principle !
LC  71,72       $ construction and wind
LC  81,82,83,84 $ settlements
LC   (90  99 1) $ temperature
END

!#!Kapitel CSM
+PROG CSM URS:87
HEAD Construction sequence
CTRL DL  AUTO  $ Dead load of gamma automatically
ECHO RCRE full
$
CS 10 TYPE G_1 TITL 'G_1'
CS 11 TYPE P   TITL 'Prestress 60 percent'           FACP 0.60
CS 15 TYPE C_1 TITL 'Creep until G_2'   T    40
CS 20 TYPE G_2 TITL 'G_2, Asphalt, capping'
CS 21 TYPE P   TITL 'tensioning to 100 percent'   ICS1 11 FACP 1.00
CS 25 TYPE C_1 TITL 'Creep until traffic opening'   T    40
CS 35 TYPE C_2 TITL 'C+S t-infinite'   T 365*100   NCRE 2
$
GRP  NO  ICS1 T0 PHIF=1
      -   10   14 $ all groups will be activated in construction stage 10, TO= 14 Days
$
$ LC: only secondary loads! prestress load cases will be automatically inserted!
LC  2 ICS1 20          $ g_2

  SELE BEAM 1105 X 0[m]    $ Beams for the AQB stress output
$           2111 X 0[m]
END
+apply "$(NAME)_csm.dat"

!#!Kapitel Superposition
+PROG CSM URS:88
HEAD Head Superpositioning for the following CSM design : ACT input and DESI MAX
$
ACT  TYPE FOR    $ Definition of additional actions: G,P,C are activated automatically
     L_U SLS,ULS $  -> MAXIMA: SUP COND     UDL base load
                 $  L_U...L_T in most times better with a MAXIMA pre superposition see csm33_earthquake_bridge.dat
     L_1 SLS,ULS $ UDL oberload span 1 - take only one
     L_2 SLS,ULS $ UDL oberload span 2 - take only one
     L_T SLS,ULS $ tandem axle
  $ Superposition with ELLA traffic loading see more\csm31_design_ella.dat
     T   SLS,ULS $ temperature
     ZF   SLS    $ true settlement SLS
     SF   ULS    $ possible settlement ULS ULS
DESI MAX $ Only perform superpositioning without design
CTRL FILE 'maxi' $ filename for the created input file
END
+apply "$(NAME)_maxi.dat"

!#!Kapitel Design final stage
+PROG CSM urs:12
HEAD decompression check final stage

DESI CHEK $ Important checkprint for one beam to verify the stress in defined stress points
DESI DECO $ decompression check
$ or:
$  DESI DECO      $ first decompression check
$  DESI ULTI      $ ULS design only
$  DESI STAN      $ all usual checks
BOX zmin -1 zmax 0.01 GRP 1,2 $ Graphik Box für WING   $ graphic box for WING
END
+apply "$(NAME)_desi.dat"

!#!Kapitel Design \|Bauzustand mit Teilvorspannung construction stage with partial prestress
+PROG CSM urs:2
HEAD DECO+ULTI construction stage with partial prestress
LCCS 71 ACT Q
DECS CS 20
DESI CHEK $ Checkprint to verify the stress in one beam in defined stress points
DESI ULTI,DECO
CTRL FILE 'decs' $ filename for the created input file
END
+apply "$(NAME)_decs.dat

$ Clean file folder:
+sys del $(project).$d?