!#!Info  Example:       ELLA-Manual Example 1, Influence lines of a three span beam
!#!Info  Keyword:       influence lines; DIN 1045-1
!#!Info  Program:       ELLA
!#!Info  Date:          $Date: 2023-08-11 16:19:29 +0200 (Fri, 11 Aug 2023) $

PROG AQUA urs:1
HEAD MATERIAL
NORM DIN EN199X-200X
CONC 1 C 25 ; SREC 1 1600 4000 400 7800 REF UM
END

PROG SOFIMSHA urs:2
HEAD INFLUENCE LINES OF A THREE SPAN BEAM
SYST GIRD GDIV 1000
NODE 1   0 0 FIX F
NODE 2  40 0 FIX PP
NODE 3  80 0 FIX PPMX
NODE 4 120 0 FIX PP
$STAB (1 3 1) (1 1) (2 1) TEIL 4
BEAM mesh (1 3 1) (2 1) DIV 8
END

PROG SOFILOAD urs:3
HEAD ACTIONS AND LOADS
ECHO ACT
ACT G
ACT L
ACT L_U
ACT L_T
LC 1 TYPE G FACD 1.0
$
ECHO LANE,LOAD
GAX  AXIS X 0.0 Y 0.0 ; AXIS S 3.0 X 120
LANE AXIS EC WR 3.50 WL -3.50 YRA 3.75 YLA -3.75 SA 0.0 SE 1.0 L 40.0 $ CREATE THREE SPANS
LANE AXIS                                        SA 1.0 SE 2.0 L 40.0 $ NEEDED ESPECIALLY
LANE AXIS                                        SA 2.0 SE 3.0 L 40.0 $ FOR COPY IN SOFILOAD
$
LC 101 TYPE L TITL 'PRIMARY LANE'     ; TRAI LM1 300
LC 102 TYPE L TITL 'SECONDARY LANE'   ; TRAI LM1 200
END

+PROG ASE urs:4
head
LC 1
end


+PROG ELLA urs:5
HEAD ESTABLISH ALL INFLUENCE LINES
SIZE URS 0 HDIV 3 $ 0.30
SHOW AXIS.0 $ SHOW ONLY THE CENTRAL ONE
LSEL AXIS INT 0
CALC MY 51 52
CALC VZ 53 54
CALC MT 55 56
END


+PROG ELLA urs:8
HEAD EVALUATE WITH TWO INDEPENDANT LANES AND ACTIONS
SIZE -URS 0 HDIV 6
echo res no
ECHO LPOS FULL
SHOW AXIS.10 TYPE BEAM NO 4 X 0 ETYP EXTR
SAVE 100 L_T
CASE 1 GR0 ; POSL AXIS.10 101
             POSL AXIS.11 102
CASE 2 GR0 ; POSL AXIS.20 101
             POSL AXIS.21 102
SAVE 200 L_U
CASE 1 GRU ; POSL AXIS.10 101
             POSL AXIS.11 102
             POSL AXIS.0  P 2.5*0.75
CASE 2 GRU ; POSL AXIS.20 101
             POSL AXIS.21 102
             POSL AXIS.0  P 2.5*0.75
END
END


+PROG SOFILOAD urs:11
HEAD CONVERT LOAD POSITIONS FROM ELLA
ECHO LOAD

LC 2001 TYPE NONE
 COPY  151 TYPE ELLA REF "AXIS.10" CASE 1 NRE 4 0
 COPY  151 TYPE ELLA REF "AXIS.11" CASE 1 NRE 4 0
LC 2002 TYPE NONE
 COPY  152 TYPE ELLA REF "AXIS.20" CASE 2 NRE 4 0
 COPY  152 TYPE ELLA REF "AXIS.21" CASE 2 NRE 4 0

LC 2101 TYPE NONE
 COPY  251 TYPE ELLA REF "AXIS.10" CASE 1 NRE 4 0
 COPY  251 TYPE ELLA REF "AXIS.11" CASE 1 NRE 4 0
LC 2102 TYPE NONE
 COPY  252 TYPE ELLA REF "AXIS.20" CASE 2 NRE 4 0
 COPY  252 TYPE ELLA REF "AXIS.21" CASE 2 NRE 4 0


END