PROG AQUA urs:1
HEAD MATERIALS AND CROSS-SECTIONS
UNIT 5
NORM 'NS' 'en199x-200x-bridge' COUN 47 CAT 'D' SNOW '1' UNIT 5

$ MATERIALEGENSKAPER
CONC 1    C '55' TYPR    B TITL "=C 55/67 (EN 1992)"            $ Brudekket
STEE 2    B '500B' TMAX 32 TITL "=B 500 B (EN 1992)"            $ Søyla
MATE 3 E 210000 G 81000 GAM 78.5 FT 520 TITL "=Macalloy 520"    $ Skråstagene

CTRL
$ CROSS SECTIONS
SREC 1  H 400 B 13400 MNO 1    $ Tverrsnitt for brudekket
SCIT 2  D 1000        MNO 2    $ Tverrsnitt for søyla
SCIT 3  D 100         MNO 3    $ Tverrsnitt for skråstag 1, 2, 11, 12
SCIT 4  D 85          MNO 3    $ Tverrsnitt for skråstag 3, 4, 5, 10
SCIT 5  D 76          MNO 3    $ Tverrsnitt for skråstag 6, 7, 8, 9

END



$ Exported by SOFIMSHC     Version  23.00-70
PROG SOFIMSHC urs:2
HEAD DEVELOPMENT OF STRUCTURE
SYST 3d GDIV 10000 GDIR NEGZ
CTRL MESH 1
ctrl node 1

$ OPPRETTER STRUKTURELLE PUNKTER FOR BRUDEKKET OG SKRÅSTAGENE
SPT       1 X    0.0         0.0  0.0     FIX xpmx   $ ENE ENDEN AV BRUDEKKET
SPT       2 X    10.319      0.0  0.0
SPT       3 X    17.643      0.0  0.0
SPT       4 X    24.967      0.0  0.0
SPT       5 X    32.291      0.0  0.0
SPT       6 X    39.615      0.0  0.0
SPT       7 X    46.939      0.0  0.0
SPT       8 X    54.263      0.0  0.0
SPT       9 X    61.587      0.0  0.0
SPT       10 X   73.256      0.0  0.0     FIX PPMM   $ ANDRE ENDEN AV BRUDEKKET
SPT       11 X   73.256      0.0  0.0     FIX PP     $ SKRÅSTAG som er festet til fundament
SPT       12 X   74.887      0.0  0.0     FIX PP     $ SKRÅSTAG som er festet til fundament
SPT       13 X   76.517      0.0  0.0     FIX PP     $ SKRÅSTAG som er festet til fundament
SPT       14 X   78.148      0.0  0.0     FIX PP     $ SKRÅSTAG som er festet til fundament
SPT       15 X   79.778      0.0  0.0     FIX PP     $ SKRÅSTAG som er festet til fundament

$ PUNKTENE FOR SØYLA
SPT       101 X    54.263    0.1   -4.295    FIX PPMM     $Bunn av søylen
SPT       102 X    54.263    0.1   26.585    FIX PY             $Toppen av søylen

$ DEFINERER BRUDEKKET
SLN       1 NPA      1      2   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       2 NPA      2      3   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       3 NPA      3      4   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       4 NPA      4      5   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       5 NPA      5      6   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       6 NPA      6      7   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       7 NPA      7      8   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       8 NPA      8      9   GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1
SLN       9 NPA      9      10  GRP 1 STYP B SDIV 0.5 SNO 1 DRX 0 0 -1

$ DEFINERER SØYLA
SLN       101 NPA  101    102   GRP 102 STYP B SDIV 0.5 SNO 2 DRX 0 0 -1

$ DEFINERER SKRÅSTAGENE SOM ER FESTET TIL BRUDEKKET
SLN       201 NPA    2    102   GRP 201 STYP T SDIV 0.5 SNO 3 DRX 0 0 -1  $ SKRÅSTAG 1
SLN       202 NPA    3    102   GRP 202 STYP T SDIV 0.5 SNO 3 DRX 0 0 -1  $ SKRÅSTAG 2
SLN       203 NPA    4    102   GRP 203 STYP T SDIV 0.5 SNO 4 DRX 0 0 -1  $ SKRÅSTAG 3
SLN       204 NPA    5    102   GRP 204 STYP T SDIV 0.5 SNO 4 DRX 0 0 -1  $ SKRÅSTAG 4
SLN       205 NPA    6    102   GRP 205 STYP T SDIV 0.5 SNO 4 DRX 0 0 -1  $ SKRÅSTAG 5
SLN       206 NPA    7    102   GRP 206 STYP T SDIV 0.5 SNO 5 DRX 0 0 -1  $ SKRÅSTAG 6
SLN       208 NPA    9    102   GRP 207 STYP T SDIV 0.5 SNO 5 DRX 0 0 -1  $ SKRÅSTAG 7

$ DEFINERER SKRÅSTAGENE SOM ER FESTET TIL FUNDAMENT
SLN       301 NPA    11   102   GRP 301 STYP T SDIV 0.5 SNO 5 DRX 0 0 -1  $ SKRÅSTAG  8
SLN       302 NPA    12   102   GRP 302 STYP T SDIV 0.5 SNO 5 DRX 0 0 -1  $ SKRÅSTAG  9
SLN       303 NPA    13   102   GRP 303 STYP T SDIV 0.5 SNO 4 DRX 0 0 -1  $ SKRÅSTAG  10
SLN       304 NPA    14   102   GRP 304 STYP T SDIV 0.5 SNO 3 DRX 0 0 -1  $ SKRÅSTAG  11
SLN       305 NPA    15   102   GRP 305 STYP T SDIV 0.5 SNO 3 DRX 0 0 -1  $ SKRÅSTAG  12


$ Oppretter en "dummy" linje for kjøretøyets bane (ikke en del av strukturen)
SLN 999 NPA 1 NPE 10 GRP 999



END



$ BEREGNER EGENVERDIER FOR BRUA
+PROG DYNA urs:3
HEAD EIGEN VALUE OF BRIDGE
GRP 1,102,201,202,203,204,205,206,207,301,302,303,304,305
EIGE 25 LANC LC 2001
end



+prog sofimsha urs:4
head SPRING
syst rest
echo full no
$ OPPRETTER NODER FOR FJÆRELEMENTET
node 501 x -1.0 y 0.0 z 0.0                      $ Node i bunnen av fjæra
node 502 x -1.0 y 0.0 z 1.0                      $ Node i toppen av fjæra

$ DEFINERER FJÆRELEMENT
mass 502 mz 5.75                                 $ Massen på toppen av fjæra (f.eks. et kjøretøy)
grp 600
spri no 700 na 501 ne 502 dx 0 dy 0 dz 1.0  cp 1595.0 dp 5.746   $ Cp = stivhet, Dp = dempning

$ KOBLER FJÆRA KINEMATISK FOR AT DEN SKAL FØLGE KJØRETØYET
node 501,502 fix py
KINE ND 501 FIX PX ND1 502 FD1 1  $ Kinematisk kobling. Restriksjon i x. 1 frihetsgrad i z-retning.

end



$ DEFINERER LASTTILFELLER OG KJØRETØYMODELLER
+PROG SOFILOAD urs:5
HEAD VEHICLE LOADING

$ OPPRETTER LASTTILFELLET FOR HØYHASTIGHETSTOG
LC 1001 TYPE none titl 'Loadtrain HSML A1'         $ Definerer høyhastighetstoget som en lastmodell
 TRAI HSLM P1 A10                                  $ Type HSLM A1, spesifikke parametere for tog

$$ OPPRETTER LASTTILFELLE FOR FJÆRMODELL
    LC 1002 type none titl "Sprung Mass"               $ Representerer lasten fra fjærelementet
    trai user                                          $ Brukerdefinert kjøretøy
    trpl p 56.40 a -0 cont 501                         $ Punktlast på 56.4 kN ved kontaktpunktet node 501
END



+PROG template urs:6
head SPEED OF VEHICLE
$ DEFINERER HASTIGHETSPARAMETERE FOR KJØRETØYET
LET#V 50.0                                         $ Hastighet i km/h
STO#V #V                 $ Lagrer hastigheten for bruk i senere programmer
$ DEFINERER RAYLEIGH-DEMPINGSKONSTANTER BASERT PÅ EGENVERDIER
LET#a 0.03832903
LET#b 0.00960154

end




!#!Chapter Train Passing LC 1001 with Track Irregularities
+prog sofiload urs:8
head Loadcase for track irregularities

let#WW_c 0.8246                     $ extrem frequencies [rad/m]
let#WW_r 0.0206                     $ extrem frequencies [rad/m]
let#WW_s 0.4380                     $ extrem frequencies [rad/m]
let#Av 1.080E-6 $4.032E-7 $1.080E-6 $ TWO LEVEL OF NOISE LOW/HIGH: (4.032E-7,1.080E-6)
let#n_WW 1024                       $  number of points to define the power spectra
let#Lmin  7                         $ [m]  minimal wave length
let#Lmax 20                         $ [m]  maximal wave length
let#WW_min 2*#PI/#Lmax              $ [rad/m] corresponds to Lmax - Omega value based on smallest wavelength of irregularity
let#WW_max 2*#PI/#Lmin              $ [rad/m] corresponds to Lmin - Omega value based on largest wavelength of irregularity
let#dWW (#WW_max-#WW_min)/#n_WW     $ [rad/m] sampling spatial circular frequency

!*!Label  Intensitiy Function
let#tmax 73.256/(#V/3.6)
lc 301 type none titl 'I(t)'
func t #tmax F 1.0 t1 1.0 s COMP T2 0.1*#tmax

!*!Label Power Spectra
lc 401 type none titl 'Sv(f)'
func t=[1/sec] f=[M2/M]
loop#i #n_WW
  let#WW #WW_min+#i*#dWW
  let#S_WW #Av*#WW_c**2/(#WW**2+#WW_c**2)/(#WW**2+#WW_r**2)
  let#w (#V/3.6)*#WW
  let#G_w  #S_WW/(#V/3.6)/(2*#PI)
  func t #w  f #G_w
endloop

!*!Label Track irregularities
LOOP#i 5
    LET#temp #V
    LC 20000+#i TYPE none TITL 'Irreg. #i, v=#temp km/h'
    let#Tmin 2*#pi/(#WW_max*(#V/3.6))
    let#Tmax 73.256/(#V/3.6)
    let#STEP #Lmin/(5*(#V/3.6))

    simq 401 301 DT #STEP TMIN #Tmin #Tmax NFRE #n_WW AG -1.00 TITL 'ORE B'
ENDLOOP

end


+prog dyna urs:9
head Kjøretøyanalyse med sporuregelmessigheter


LOOP#i 3
    $CTRL RLC #i*100000+100000  1+2+8
    LET#temp #V
    LET#LCUV 20000+#i  $ Definerer riktig lasttilfelle-ID for hver iterasjon
    LET#LCST 3000+#i
    LET#accFile "SpringAcc_Iter"#LCUV".txt"
    LET#dispFile "SpringDisp_Iter"#LCUV".txt"
    LET#bridgeAccFile "BridgeAcc_Iter"#LCUV".txt"
    LET#bridgeDispFile "BridgeDisp_Iter"#LCUV".txt"

    HIST U-Z FROM 501 TO 502 LCST #LCST DUMP #dispFile
    HIST A-Z FROM 1 TO 10 INC 1 LCST #LCST DUMP #bridgeAccFile
    HIST U-Z FROM 1 TO 10 INC 1 LCST #LCST DUMP #bridgeDispFile

    mass 0
    ctrl mcon 3
    CTRL SPRI 700
    grp -                                $ Tar med alle elementer i analysen
    GRP 1 RADA 0.03832903 RADB 0.00960154  $ Rayleigh-demping for brua
    step N 5275 DT 0.001
    LC  1002                           $ Laster tog langs skinnegang
    CONT NR 999 V #V/3.6 0.0 LCUV #LCUV         $ Automatiske tidsverdier i noder
    echo



ENDLOOP

$HIST U-Z FROM 502 LCST 200 DUMP 'Node502_LC200.txt'
$HIST U-Z FROM 502 LCST 201 DUMP 'Node502_LC201.txt'
$HIST U-Z FROM 502 LCST 202 DUMP 'Node502_LC202.txt'

end