!#!Info Example: Stress verification at prestressed concrete cross-section
!#!Info Keyword: Prestress Concrete, Stress, Construction stages
!#!Info Program: AQB
!#!Chapter Material and Cross-section
+PROG AQUA URS:1
KOPF Material and Cross-section definition
ECHO quer,mat ja
steu bewq 2
NORM 'DIN' NDC 'EN1992-2004'
BETO 1 C 35
STAH 11 Y 1770
QNR 1 MNR 1
QPOL RECT MNR 1 DY 1[m] DZ 1[m]
ENDE
!#!Chapter System definition
+PROG SOFIMSHA urs:6
KOPF Simply Supported Beam
ECHO voll nein
SYST RAUM GDIV 1000 GDIR ZZ
KNOT NR X Y Z
1 0 0 0 FIX PPMX
2 10 0 0
3 20 0 0 FIX XPMX
GRUP 10
STAB FIT 1 2 QNR 1 TEIL 10
STAB FIT 2 3 QNR 1 TEIL 10
ENDE
!#!Chapter Tendon
+PROG TENDON urs:9
KOPF Prestressing
ECHO voll nein
ECHO sysp,sgeo,last ja
UNIT 5 $units: sections in mm, geometry+loads in m
$SYSP NRSV 19 MAT 11 ZV 3899 AZ 2850 LITZ 19 MINR 8.60 BETA 0.30 MUE 0.21 EXZ 9.9 SS 3 DA 97 $19 wires: A_p = 19*150mm^2 = 2850 mm^2
!*!Label Bitte hier schauen VS und VK verwenden
SYSP NRSV 19 MAT 11 ZV 3899 AZ 2850 LITZ 19 MINR 8.60 BETA 0.30 MUE 0.21 EXZ 9.9 SS 3 DA 97 VS 5 $19 wires: A_p = 19*150mm^2 = 2850 mm^2
AXES NRH 1 VAL1 0.00 0.00 0.00 TYP POLY ART STAB
1 VAL1 20.00 0.00 0.00 BEZ "tendon_axis"
HOCH NRH 1 TYP REFX S 0,20 SF 1,2
SGEO NRG 1 NRH 1 NRSV 19 $Tendon geometry
ZPUV S U V DVS TYP=FELD $definition points of geometry: TYPE = SPAN station via high points
1 0 0.0 -
1.50 - 0.4 0
2 0 0.0 -
CS IBA1 11 IBA2 12 IBA3 - $construction stages
VSIG 'li' ANWS 'TS' KAPA 1.5 $prestress-procedure
TEND NRS 1 NRG 1 LF 2
$ tendon plots:
ECHO plot voll
SIZE W 30
SCHR H1 0.50 H3 0.20
PLOT GEOA NR 0 FAKH 5 TYPG DUTE ANZ 1 $plot tendon geometry
PLOT FAKT NR 1 FAKH 50 $plot stresses and forces
ENDE
!#!Chapter Analysis
+PROG SOFILOAD URS:13
KOPF Loading
SEIT UNIE 5
ECHO voll nein
ACT g_1,p
LF 1 EGZ 1.0 TYP 'g_1' BEZ 'G'
LF 2 TYP 'p' BEZ 'P'
ENDE
+PROG ASE URS:4
KOPF Analysis
ECHO voll nein
LF 1 TYP 'g_1'
LF 2 TYP 'p'
ENDE
!#!Chapter P CS0
+PROG AQB urs:2
KOPF P CS0
ECHO voll nein
ECHO komb,tabs
steu
STAB 10010 X 1.0 BA0 11 BA1 12
LF 2 TYP p QT CS0
KOMB SUM LF1 p LFSP 100
SPAN K
ENDE
!#!Chapter G+P CS0
+PROG AQB urs:3
KOPF G+P CS0
ECHO voll nein
ECHO komb,tabs
STAB 10010 X 1.0 BA0 11 BA1 12
LF 1 TYP g_1 QT CS0
LF 2 TYP p QT CS0
KOMB SUM LF1 g LF2 p LFSP 101
SPAN K
ENDE
!#!Chapter P CS1
+PROG AQB urs:7
KOPF P CS1
ECHO voll nein
ECHO komb,tabs
STAB 10010 X 1.0 BA0 11 BA1 12
LF 2 TYP p QT CS1
KOMB SUM LF1 p LFSP 102
SPAN K
ENDE
!#!Chapter G+P CS1
+PROG AQB urs:8
KOPF G+P CS1
ECHO voll nein
ECHO komb,tabs
STAB 10010 X 1.0 BA0 11 BA1 12
LF 1 TYP g_1 QT CS1
LF 2 TYP p QT CS1
KOMB SUM LF1 g LF2 p LFSP 103
SPAN K
ENDE
!#!Chapter Results
+prog template urs:5
KOPF Result summary
$reference values
LET#X_REF -12.47,-4.82,-11.76,-4.51 $[MPa]
LET#D_ABS_ALL 3.0 $absolute tolerance
LET#D_REL_ALL 3.0 $relative tolerance
$extract calculated value from database
loop#i 4
@KEY BEAM_STR 100+#i 10010 $cdb record 105 = Stresses in cross-section of beams, loadcase number, beamnumber
STO#X(#i) @(2)/1000 $stress at bottom
endloop
$ compute deviation
LOOP#i X
LET#D_ABS(#i) ABS(#X_REF(#i)-#X(#i))
LET#D_REL(#i) ABS(#D_ABS(#i)/#X_REF(#i)*100.0)
ENDLOOP
$printouts
STO#PRINT1 'I','II','III','IV'
STO#PRINT2 ' 0',' 0','1',' 1'
$ print summary
TXA Stresses at concrete
TXA
TXA
TXA Case CS sigma,ref sigma,calc diff diff tol_all result
TXA [MPa] [MPa] [MPa] [%] [%]
TXA --------------------------------------------------------------------------------
LOOP#i X
LET#IS_OK 0
IF (#D_REL<#D_REL_ALL)
LET#IS_OK 1
ENDIF
IF (#IS_OK==1)
TXA #PRINT1(#i) #PRINT2(#i) #(#X_REF(#i),8.2) #(#X(#i),8.2) #(#D_ABS(#i),8.2) #(#D_REL(#i),8.2) #(#D_REL_ALL,8.2) OK
ELSE
TXA #PRINT1(#i) #PRINT2(#i) #(#X_REF(#i),8.2) #(#X(#i),8.2) #(#D_ABS(#i),8.2) #(#D_REL(#i),8.2) #(#D_REL_ALL,8.2) Failed
ENDIF
ENDLOOP
ENDE
+PROG RESULTS urs:15
KOPF Plot Stresses for G+P CS0
SIZE DINA "-URS"
BEOB TYP BLIC X -0.795666 Y 0.483621 Z 0.364727 ACHS POSZ
DBO NAME "beam_sss.sign" ND 3
DBO NAME "beam_sss.signy" ND 3
DBO NAME "beam_sss.signz" ND 3
LF NR 101
LF ENR 10010 X 1
QUER TYP SIG ETYP STAB RTYP NONL DARS DLIN FILL NEIN SCHR 0.4
ENDE
+PROG WING urs:11
KOPF Plot Structure
SEIT UNIE 0
STEU OPT INP
STEU OPT GSTR WERT STAN
STEU OPT ACHS WERT STAN
SEIT SPRA 1 UNIA 5
SIZE DINA URS M 0
SIZ2
UND POSI 1 POSL 0 POSR 100 POSU 0 POSO 100
SCH3 HAUF 0.700000
RAST TYP NEIN RICH STAN VMH 0 VMQ 0 VM3 0 TOLW 15 TOLZ -5
FARB F12 1317
FAR2 F5 1771 F21 1771 F22 1771 F23 1771 F24 1771
LF NR 1 BEME 1
BOX
BEOB TYP BLIC X 0.864813 Y -0.422351 Z 0.271511 ACHS POSZ DREH 0
VERS TYP NEIN EXPO 0 SMOV NEIN
AUSW NR 0
STRU NUME VOLL FILL NEIN DARS DSTR UNIT STAN SCHR FIBU
ENDE