$ Eisenbahnüberführung Schwarze Elster
$ ============================================
$ Stand: 18.08.23    Ersteller: Dario Schmekel
$ ============================================

!+!Kapitel Variablen - global
$ ===========================
+PROG TEMPLATE urs:6
KOPF Parameterdefinition
 STO#stw  42.25[m] $ Stützweite
 STO#lb    5.15[m] $ Lichte Breite des Überbaus
 STO#gb    6.15[m] $ gesamte Überbaubreite
 STO#ah    5.10[m] $ Achsabstand Obergurt und Untergurt
 STO#ak   6.036[m] $ Abstand der Fachwerkknoten des Untergurts/Obergurts
 STO#aq   0.671[m] $ Abstand der Querträger
 STO#nq         62 $ Anzahl der Querträger
 STO#neq         2 $ Anzahl der Enduerträger

ENDE

!+!Kapitel Material und Querschnitte
$ ==================================
+PROG AQUA urs:1
KOPF Material und Querschnitte
!*!Label NORM
$ -----------
  NORM DIN EN199X-200X-BRIDGE                 $ Stahlbaunorm: EC3

!*!Label Material
$ ---------------
 STAH NR 1 S 355

!*!Label Querschnitte                                                  $
$ -------------------                                                  $

!*!Label Erzeugung des Hauptträgers

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h   1.20[m] $ Höhe des Stahlhauptträger
 LET#b   0.50[m] $ Breite Hauptträger
 LET#t   0.02[m] $ Blechdicke

 QNR NR 1
 $ Hauptträger wird erzeugt durch Rechteck
  QPOL ART U MNR 1
   QP Y -#b/2  Z #h
   QP Y  #b/2  Z #h
   QP Y  #b/2  Z 0
   QP Y -#b/2  Z 0

 $ Öffnung des Hauptträgers
  QPOL ART U MNR 0
   QP Y -#b/2+#t  Z #h-#t
   QP Y  #b/2-#t  Z #h-#t
   QP Y  #b/2-#t  Z #t
   QP Y -#b/2+#t  Z #t

!*!Label Erzeugung des Hauptträgers im Auflagerbereich

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h   1.40[m] $ Höhe des Stahlhauptträger
 LET#b   0.50[m] $ Breite Hauptträger
 LET#t   0.02[m] $ Blechdicke

 QNR NR 2
 $ Hauptträger wird erzeugt durch Rechteck
  QPOL ART U MNR 1
   QP Y -#b/2  Z #h
   QP Y  #b/2  Z #h
   QP Y  #b/2  Z 0
   QP Y -#b/2  Z 0

 $ Öffnung des Hauptträgers
  QPOL ART U MNR 0
   QP Y -#b/2+#t  Z #h-#t
   QP Y  #b/2-#t  Z #h-#t
   QP Y  #b/2-#t  Z #t
   QP Y -#b/2+#t  Z #t


!*!Label Erzeugung des Obergurts/Portaldiagonalen
$ --------------------------------

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h    0.60[m] $ Höhe des Stahlhauptträger
 LET#b    0.50[m] $ Breite Hauptträger
 LET#tf   0.03[m] $ Gurtdicke
 LET#tw   0.02[m] $ Stegdicke

 QNR NR 3
 $ Erzeugen eines Rechtecks
  QPOL ART U MNR 1
   QP Y -#b/2  Z #h
   QP Y  #b/2  Z #h
   QP Y  #b/2  Z 0
   QP Y -#b/2  Z 0

 $ Erzeugen der Öffnung
  QPOL ART U MNR 0
   QP Y -#b/2+#tw  Z #h-#tf
   QP Y  #b/2-#tw  Z #h-#tf
   QP Y  #b/2-#tw  Z #tf
   QP Y -#b/2+#tw  Z #tf

!*!Label Erzeugung der Normaldiagonalen
$ --------------------------------

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h   0.50[m] $ Höhe der Normaldiagonale
 LET#b   0.50[m] $ Breite Normaldiagonale
 LET#t   0.02[m] $ Blechdicke

 QNR NR 4
 $ Erzeugen eines Rechtecks
  QPOL ART U MNR 1
   QP Y -#b/2  Z #h
   QP Y  #b/2  Z #h
   QP Y  #b/2  Z 0
   QP Y -#b/2  Z 0

 $ Erzeugung der Öffnung
  QPOL ART U MNR 0
   QP Y -#b/2+#t  Z #h-#t
   QP Y  #b/2-#t  Z #h-#t
   QP Y  #b/2-#t  Z #t
   QP Y -#b/2+#t  Z #t

!*!Label Erzeugung der Querträger
$ --------------------------------

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h     0.50[m] $ Höhe Querträger
 LET#bo   0.671[m] $ Obergurtbreite
 LET#to    0.02[m] $ Blechdicke Obergurt
 LET#t    0.018[m] $ Blechdicke Steg
 LET#bu    0.30[m] $ Ubergurtbreite
 LET#tu    0.02[m] $ Blechdicke Untergurt

QNR NR 5
 $ Erzeugen des Obergurts
  QPOL ART U MNR 1
   QP Y -#bo/2  Z #h
   QP Y  #bo/2  Z #h
   QP Y  #bo/2  Z #h-#to
   QP Y -#bo/2  Z #h-#to

 $ Erzeugung des Stegs
  QPOL ART U MNR 1
   QP Y -#t/2  Z #h-#to
   QP Y  #t/2  Z #h-#to
   QP Y  #t/2  Z #tu
   QP Y -#t/2  Z #tu

 $ Erzeugung des Untergurts
  QPOL ART U MNR 1
   QP Y -#bu  Z #tu
   QP Y  #bu  Z #tu
   QP Y  #bu  Z 0
   QP Y -#bu  Z 0

!*!Label Erzeugung der Endquerträger
$ --------------------------------

$ Variablen zur Querschnittserzeugung
$ -----------------------------------
 LET#h     0.70[m] $ Höhe Obergurt
 LET#bo    0.70[m] $ Obergurtbreite
 LET#to   0.018[m] $ Blechdicke Obergurt
 LET#t    0.015[m] $ Blechdicke Steg
 LET#bu    0.70[m] $ Ubergurtbreite
 LET#tu   0.018[m] $ Blechdicke Untergurt
 LET#lis   0.20[m] $ lichte Abstand der Stege

 QNR NR 6
 $ Erzeugen des Obergurts
  QPOL ART U MNR 1
   QP Y -#bo/2  Z #h
   QP Y  #bo/2  Z #h
   QP Y  #bo/2  Z #h-#to
   QP Y -#bo/2  Z #h-#to

 $ Erzeugung des linken Stegs
  QPOL ART U MNR 1
   QP Y -#t/2-#lis  Z #h-#to
   QP Y      -#lis  Z #h-#to
   QP Y      -#lis  Z #tu
   QP Y -#t/2-#lis  Z #tu

 $ Erzeugung des linken Stegs
  QPOL ART U MNR 1
   QP Y #lis       Z #h-#to
   QP Y #lis+#t/2  Z #h-#to
   QP Y #lis+#t/2  Z #tu
   QP Y #lis       Z #tu

 $ Erzeugung des Untergurts
  QPOL ART U MNR 1
   QP Y -#bu/2  Z #tu
   QP Y  #bu/2  Z #tu
   QP Y  #bu/2  Z 0
   QP Y -#bu/2  Z 0

Ende

!+!Kapitel SOFIMSHC: System und Geometrie
$ ========================================
+PROG SOFIMSHC urs:2
KOPF Systemgenerierung
!*!Label Koordinatensystem
$ ------------------------
 SYST ART 3d GDIV 10000
 STEU MESH 1+64                   $    2 - Vernetzung von Flächen und Stäben
 STEU HMIN 0.5[m]                 $   64 - Viereckige Elemente
                                  $ HMIN - Festlegung der max.Kantenlänge

!*!Label Erzeugung der Hauptträger
$ --------------------------------
$ Erzeugen des linken Hauptträgers
 SLN GRP 1 QNR 2 STYP b
  SLNB X1 -#stw/2-0.6  Y1 -#lb/2  X2 -#stw/2+0.6595  Y2 -#lb/2
 SLN GRP 1 QNR 2.1 STYP b
  SLNB X1 -#stw/2+0.6595  Y1 -#lb/2  X2 -#stw/2+0.6595+#aq  Y2 -#lb/2
 SLN GRP 1 QNR 1 STYP b
  SLNB X1 -#stw/2+0.6595+#aq  Y1 -#lb/2  X2 #stw/2-0.6595-#aq  Y2 -#lb/2   $ Zentrischer Balken, Nulllinie liegt in Schwerpunkt
 SLN GRP 1 QNR 1.2 STYP b
  SLNB X1 #stw/2-0.6595-#aq  Y1 -#lb/2  X2 #stw/2-0.6595  Y2 -#lb/2
 SLN GRP 1 QNR 2 STYP b
  SLNB X1 #stw/2-0.6595  Y1 -#lb/2  X2 #stw/2+0.6  Y2 -#lb/2

$ Erzeugen des rechten Hauptträgers
 SLN GRP 2 QNR 2 STYP b
  SLNB X1 -#stw/2-0.6  Y1 #lb/2  X2 -#stw/2+0.6595  Y2 #lb/2
 SLN GRP 2 QNR 2.1 STYP b
  SLNB X1 -#stw/2+0.6595  Y1 #lb/2  X2 -#stw/2+0.6595+#aq  Y2 #lb/2
 SLN GRP 2 QNR 1 STYP b
  SLNB X1 -#stw/2+0.6595+#aq  Y1 #lb/2  X2 #stw/2-0.6595-#aq  Y2 #lb/2   $ Zentrischer Balken, Nulllinie liegt in Schwerpunkt
 SLN GRP 2 QNR 1.2 STYP b
  SLNB X1 #stw/2-0.6595-#aq  Y1 #lb/2  X2 #stw/2-0.6595  Y2 #lb/2
 SLN GRP 2 QNR 2 STYP b
  SLNB X1 #stw/2-0.6595  Y1 #lb/2  X2 #stw/2+0.6  Y2 #lb/2

!*!Label Erzeugung der Querträger
$ -------------------------------
 LOOP#i #nq
  SLN GRP 3 QNR 5 STYP b EZA 0.7 EZE 0.7
   SLNB X1 -#stw/2+0.6595+#aq*#i Y1 -#lb/2  X2 -#stw/2+0.6595+#aq*#i Y2 #lb/2
  ENDLOOP

!*!Label Erzeugung der Endquerträger
$ -------------------------------
  SLN GRP 4 QNR 6 STYP b EZA 0.7 EZE 0.7
   SLNB X1 -#stw/2 Y1 -#lb/2  X2 -#stw/2 Y2 #lb/2
  SLN GRP 4 QNR 6 STYP b EZA 0.7 EZE 0.7
   SLNB X1 #stw/2 Y1 -#lb/2  X2 #stw/2 Y2 #lb/2

!*!Label Erzeugung der Auflager
$$ -----------------------------
 SPT NR 1 X -#stw/2  Y -#lb/2  Z 0  FIX PXPYPZ
 SPT NR 2 X  #stw/2  Y -#lb/2  Z 0  FIX PYPZ
 SPT NR 3 X -#stw/2  Y  #lb/2  Z 0  FIX PZ
 SPT NR 4 X  #stw/2  Y  #lb/2  Z 0  FIX PZ

!*!Label Erzeugung der Portaldiagonalen/Normaldiagonalen
$ -------------------------------
$ Erzeugen der unteren Strukturpunkte
 LOOP#i 8
  SPT NR 10+#i X -#stw/2+#i*#ak Y -#lb/2 Z 0
  SPT NR 20+#i X -#stw/2+#i*#ak Y  #lb/2 Z 0
 ENDLOOP

$ Erzeugen der oberen Strukturpunkte
 LOOP#i 7
  SPT NR 30+#i X -#stw/2+#ak/2+#i*#ak Y -#lb/2 Z -#ah
  SPT NR 40+#i X -#stw/2+#ak/2+#i*#ak Y  #lb/2 Z -#ah
  ENDLOOP

$ linke Seite der Diagonalen
  SLN GRP 5 QNR 3 STYP b NPA 1 NPE 30   $ Portaldiagonale
  SLN GRP 5 QNR 4 STYP b NPA 30 NPE 11
  SLN GRP 5 QNR 4 STYP b NPA 11 NPE 31
  SLN GRP 5 QNR 4 STYP b NPA 31 NPE 12
  SLN GRP 5 QNR 4 STYP b NPA 12 NPE 32
  SLN GRP 5 QNR 4 STYP b NPA 32 NPE 13
  SLN GRP 5 QNR 4 STYP b NPA 13 NPE 33
  SLN GRP 5 QNR 4 STYP b NPA 33 NPE 14
  SLN GRP 5 QNR 4 STYP b NPA 14 NPE 34
  SLN GRP 5 QNR 4 STYP b NPA 34 NPE 15
  SLN GRP 5 QNR 4 STYP b NPA 15 NPE 35
  SLN GRP 5 QNR 4 STYP b NPA 35 NPE 16
  SLN GRP 5 QNR 4 STYP b NPA 16 NPE 36
  SLN GRP 5 QNR 3 STYP b NPA 36 NPE  2 $ Portaldiagonale

$ rechte Seite der Diagonalen
  SLN GRP 6 QNR 3 STYP b NPA  3 NPE 40 $ Portaldiagonale
  SLN GRP 6 QNR 4 STYP b NPA 40 NPE 21
  SLN GRP 6 QNR 4 STYP b NPA 21 NPE 41
  SLN GRP 6 QNR 4 STYP b NPA 41 NPE 22
  SLN GRP 6 QNR 4 STYP b NPA 22 NPE 42
  SLN GRP 6 QNR 4 STYP b NPA 42 NPE 23
  SLN GRP 6 QNR 4 STYP b NPA 23 NPE 43
  SLN GRP 6 QNR 4 STYP b NPA 43 NPE 24
  SLN GRP 6 QNR 4 STYP b NPA 24 NPE 44
  SLN GRP 6 QNR 4 STYP b NPA 44 NPE 25
  SLN GRP 6 QNR 4 STYP b NPA 25 NPE 45
  SLN GRP 6 QNR 4 STYP b NPA 45 NPE 26
  SLN GRP 6 QNR 4 STYP b NPA 26 NPE 46
  SLN GRP 6 QNR 3 STYP b NPA 46 NPE 4  $ Portaldiagonale

!*!Label Erzeugen des Obergurts
$ -------------------------------
 LOOP#i 6
  SLN GRP 7 QNR 3 STYP b NPA 30+#i NPE 31+#i
  SLN GRP 7 QNR 3 STYP b NPA 40+#i NPE 41+#i
 ENDLOOP

!*!Label Benennung der Gruppen
$ --------------------------
GRUP NR 1 BEZ "Untergurt links"
GRUP NR 2 BEZ "Untergurt rechts"
GRUP NR 3 BEZ "Querträger"
GRUP NR 4 BEZ "Endquerträger"
GRUP NR 5 BEZ "Portaldiagonalen links"
GRUP NR 6 BEZ "Portaldiagonalen rechts"
GRUP NR 7 BEZ "Obergurt"

ENDE

!+!Kapitel Belastung
$===================
+PROG SOFILOAD urs:4
KOPF Belastung
 LF 1 BEZ "Eigengewicht Konstruktion"

 LF 2 BEZ 'Eigengewicht Fahrbahn'
  STAB VON GRP BIS 3 TYP PZP 10.23[kN/m]
  STAB VON GRP BIS 4 TYP PZP 10.23[kN/m]

 LF 3 bez 'Eigengewicht Gehsteig'
  STAB VON GRP BIS 1 TYP PZP 6.0[kN/m]
  STAB VON GRP BIS 2 TYP PZP 6.0[kN/m]
  STAB VON GRP BIS 1 TYP MXX -4.8[kNm/m]
  STAB VON GRP BIS 2 TYP MXX  4.8[kNm/m]
ENDE

+PROG ASE urs:3
KOPF Schnittgrößenermittlung

SYST PROB line
 LF 1 EGZ 1.1
ENDE

SYST PROB line
 LF 2
ENDE

SYST PROB line
 LF 3
ENDE

SYST PROB line
 LF 100 EGZ 1.1
 LC 2
 LC 3
ENDE