!#!Info Example: Prestressed bridge with design
!#!Info Keyword: temperature; settlement; prestress; tendon; Design; traffic
!#!Info Program: CSM
$
$
$ Example bridge construction
$ **************************
$ - csm31_design.dat \design major bridge example with automatic dimensioning with the CSM
$ - csm31_design_cabd.dat \cabd with axis variables haunched in folder more\csm31_design_cabd.dat
$ - csm10_composite_cabd.dat \cabd Concreting in Step back reversal method - Creep and shrinkage
$ - csm31_design_ella.dat \more in folder csm.dat\..\more\
$ - csm31_design_aci.dat \more super example for manuel design
$ csm32_slab_design.dat \design as prestressed_slab.dat but with CSM
$
$ - extern_prestress_cables.dat ase\english\bridge\
$ - extern_prestress_cables.dat "
$ - bridge_design_manual_aqb.dat "
$ - box_girder_torsion_shear_design.dat "
$ - stahl_verbund_*.dat "
$ - tendon_failure.dat ase.dat\..\nonlinear_quad\tendon_failure.dat
$ - prestressed_slab.dat bemess.dat\..\ without CSM
$ further design examples:
$ - bemess6_design.dat bemess.dat\..\ Building slab
$ - bemess5_Schwingbreiten.dat bemess.dat\..\ SLS design slabs
$ - See also csm.dat\english\overview_csm_examples_english.pdf:
$ - Numerous bridge examples can also
$ - be inserted with SSD task „beam and slabbridge“
$ -
$ - There you can easily create a bridge and then
$ - look into the produced input file (SSD-Task-beam and slabbridge - right mouse button - edit)
!#!Kapitel System
+PROG AQUA URS:1
HEAD Prestressed bridge - checks with the CSM-Design Module
NORM 'NS' 'en199X-200X-BRIDGE' CAT 'B' $ road bridges
CTRL REST 1
UNIT 5 $ units: sections in mm, geometry+loads in m
$ CTRL styp BEM
echo mat,sect full
!*!Label Material
CONC 1 C 40 $ = C40/50
STEE 2 S 500 $ standard reinforcement steel 500
STEE 7 S '235' $ TMAX 0 $ structural steel for tubes, rolled steel ...
STEE 11 Y '1860A' $ prestessing steel
$ fp0,1k = 1600 N/mm2
$ fpk = 1860 N/mm2
$ 0.8*fpk = 0.80*1860 = 1488 N/mm2
$ 0.9*fp0,1k = 0.90*1600 = 1440 N/mm2
$ sigp,max = min(1488,1440) = 1440 N/mm2 EN-1992-1-1 5.10.2.1(1) maximum stress
$ sigp,SLS = 0.65*fpk = 0.65*1860 = 1209 N/mm2 EN-1992-1-1 7.2(5) on traffic opening permanent
$ sigp,rare= sigp,max
!*!Label Section 1
SECT 1 MNO 1
#define section
POLY OPZ MNO 1
VERT no Y Z R EXP
1 0.00[m] 0.00[m] - 0.50 $ air contact
2 -4.00[m] 0.00[m] - 1.00 $ for all following points
3 -4.00[m] 0.25[m]
4 -1.70[m] 0.45[m]
5 -1.30[m] 0.62[m] -1.0[m]
6 -0.90[m] 1.35[m] -1.0[m]
7 0.00[m] 1.35[m]
let#zmax 1350 $ mm
$
$ Torsionsbox: *---------------------> y
$ |
$ *----------|----------* #ztop
$ | |<--#ytop->|
$ | | |
$ | | |
$ | |<--#ybot->|
$ *----------|----------* #zbot
$ z
let#ytop 750 $ [mm] y-value of Torsionsbox above
let#ybot 750 $ [mm] y-value of Torsionsbox below
let#ztop 110 $ [mm] z-value of Torsionsbox above
let#zbot #zmax-110 $ " of Torsionsbox below
LAY 0 'TORS' type min $ default for reinforcement layers
LAY 1 'BOT' type opt $ 'bot' lower reinforcement 'bot'
LAY 2 'TOP' type opt $ 'top' upper reinforcement 'top'
RF Y #ytop,-#ytop Z #ztop AS 10[cm2] LAY 0 TORS acti D 12
RF Y #ybot,-#ybot Z #zbot AS 10[cm2] LAY 0 TORS acti D 12
$ bending reinforcement:
let#ytop 1900 $ [mm]
let#ybot 850 $ [mm]
let#ztop 60 $ [mm]
let#zbot #zmax-60
RF Y #ytop,#ytop/3,-#ytop/3,-#ytop Z #ztop AS 10[cm2] LAY 2 TORS pass D 20 $ above
RF Y #ybot,#ybot/3,-#ybot/3,-#ybot Z #zbot AS 10[cm2] LAY 1 TORS pass D 20 $ below
CUT 1 ZB 500 MNO 1 LAY 1 $ By x=3.80 m of the support above the tendon
CUT 2 ZB 700 MNO 1 LAY 1 $ By x=3.80 m of the support underneath the tendon
CUT 3 YB 1300 MNO 1 LAY 3 TYPE FLAN $ belt
CTRL WARN 10463
SPT NO Y Z MNO
'TOP' 0 0 1
'BOT' 0 #zmax 1 $ input literal BOT in kapitel letters
#enddef
#include section
NEFF YMIN -9000 YMAX -3900 ZMIN -1000 ZMAX +9000 type Z
NEFF YMIN 3900 YMAX 9000 ZMIN -1000 ZMAX +9000 type Z
SECT 2 MNO 1 $ Noneffective width over middle support
#include section
CTRL WARN 346
SPT NO Y Z MNO
'SIDE' 4000[mm] 0 1 $ noneffective part
NEFF ymin -9000 ymax -2850 zmin -1000 zmax +9000 type Z
NEFF ymin 2800 ymax 9000 zmin -1000 zmax +9000 type Z
!*!Label Section 9
SREC 9 H 1.5[m] B 4[m] $ piers
END
+PROG AQUA urs:2
HEAD Plot sections
CTRL REST 3
CTRL WARN 10463
ECHO MAT NO ; ECHO SECT YES ; ECHO PICT FULL
END
+PROG RESULTS urs:7
HEAD Plot sections
SIZE TYPE "URS"
LC SECT 2 ; STRU TYPE CROS
END
+PROG SOFIMSHA urs:3
HEAD Prestressed bridge - checks with the CSM-Design Module
UNIT 5 $ units: sections in mm, geometry+loads in m
SYST SPAC GDIV 1000 POSZ
NODE (101 121 1) X (0 21.4/10)
GRP 1
BEAM (101 108 1) (101 1) (102 1) NCS 1 NP -1
BEAM 109 109 110 NCS 1.2 NP -1 $ the noneffective width is input constant in the beam over the support
BEAM 110 110 111 NCS 2 NP -1 $ to avoid effects of haunched center of stiffness
GRP 2
BEAM 111 111 112 NCS 2 NP -1
BEAM 112 112 113 NCS 2.1 NP -1 $ in a beam with variable section
BEAM (113 120 1) (113 1) (114 1) NCS 1 NP -1 $ the interpretation of results is more difficult
$
GRP 9
$ Den folgenden Block können Sie ohne Änderung verwenden und nur die
$ darunter stehenden Variablen let#node ... setzen !
$ (Voraussetzung: Knotennummern im Überbau < 1000)
#define support01
let#dhspring 0 $ m bearing height
$ bearing springs
let#sy 0.5*#b0
TRAN node #node dy #sy dz #h dno 51000
if #b0 ; tran node #node dy -#sy dz #h dno 53000 ; endif
TRAN node #node dy #sy dz #h dno 52000
if #b0 ; tran node #node dy -#sy dz #h dno 54000 ; endif
$ node on top of pier: node 49000...
tran node #node dz #h dno 49000
node #node+51000 FIX KF #node $ coupling
if #b0 ; node #node+53000 FIX KF #node ; endif $ coupling
node #node+52000 FIX KF #node+49000 $ coupling
if #b0 ; node #node+54000 FIX KF #node+49000 ; endif $ coupling
SPRI #node+0 #node+51000 #node+52000 DZ 1 CP 1E7 $ vertical bearing
if #b0 ; SPRI #node+1 #node+53000 #node+54000 DZ 1 CP 1E7 ; endif
$ transverse bearing springs:
SPRI #node+3 #node+51000 #node+52000 dy 1 CP 1E6 $ transverse
$ longitudinal bearing springs:
let#cp_long 1.0 $ weak - to get bearing displacements
if #logitud ; let#cp_long 1E6 ; endif $ longitudinal fixed bearing
SPRI #node+7 #node+51000 #node+52000 dx 1 CP #cp_long $ longitudinal
if #b0 ; SPRI #node+8 #node+53000 #node+54000 dx 1 CP #cp_long ; endif $ longitudinal
$ node bottom of pier: node 50000...
tran node #node dz #UKpier dno 50000
BEAM #node 50000+#node 49000+#node NCS 9 KR POSY
node #node+50000 FIX F $ fixed support
#enddef
$
let#node 101 $ basenumber of node in superstructure
let#h 1.5 $ m cross section height
let#b0 3.5 $ m bearingspread
let#UKpier 4 $ m bottom level pier
let#logitud 0 $ =1 bearing fixed in longitud. direction
#include support01
$
let#node 111 $ basenumber of node in superstructure
let#logitud 1 $ =1 bearing fixed in longitud. direction
let#UKpier 9 $ m bottom level pier
#include support01
$
let#node 121 $ basenumber of node in superstructure
let#logitud 0 $ =1 bearing fixed in longitud. direction
let#UKpier 4 $ m bottom level pier
#include support01
$
$ A round of bending moments over the middle support and shear check positions
$ can be defined with beam sections - see more\..\csm31_design_ella.dat - SOFIMSHA
END
+prog sofimsha urs:15.1
head Result Sets for support tables
syst rest $ keep system and add elements
ctrl rest 2 $ keep loads inside the database
rset del $ deletes old RESTs
$ Important are the RSETs mainly iyou e.g. want:
$ Get maximum support force in right support PZ_r with corresponding force in left support PZ_l :
rset id 'axi1' titl 'Support axis 1'
rset id 'PZ_r','PZ_l' set SPRI item p no 9101,9102 $ 9101/9102 = right/left support spring
rset id 'PX_r','PX_l' set SPRI item p no 9108,9109 $ 9108 ... = springs in X-direction
rset id 'VX_r','VX_l' set SPRI item v no 9108,9109 $ "
rset id 'PHIY' set SPRI item phi no 9104 $ 9104 ... = spring in Y-direction
rset id 'axi2' titl 'at middle pier'
rset id 'PZ_r','PZ_l' set SPRI item p no 9111,9112 $ 9111/9112 = Support axis 2 at middle pier
rset id 'PX_r','PX_l' set SPRI item p no 9118,9119
rset id 'VX_r','VX_l' set SPRI item v no 9118,9119
rset id 'PHIY' set SPRI item phi no 9114
rset id 'axi3' titl 'Support axis 3'
rset id 'PZ_r','PZ_l' set SPRI item p no 9121,9122 $ 9111/9112 = Support axis 3
rset id 'PX_r','PX_l' set SPRI item p no 9128,9129
rset id 'VX_r','VX_l' set SPRI item v no 9128,9129
rset id 'PHIY' set SPRI item phi no 9124
end
+PROG SOFIMSHC urs:5
HEAD Axis for SOFILOAD load trains, SSD Tendons, Animator environment
UNIT 5 $ units: sections in mm, geometry+loads in m
SYST REST
GAX 'AX_1'
GAXB X1 0 0 0 X2 100 0 0 $ create axis from point 1 to point 2 (also with R)
$ GAX...TYPC SPLI and GAXC can create an axis through a set of points
end
!#!Kapitel Loading, Prestress
+PROG SOFILOAD URS:4
HEAD actions and loads
$ actions bridge design
$ All actions should be defined in a separate SOFILOAD run as shown here.
UNIT 5 $ units: sections in mm, geometry+loads in m
ECHO ACT Full $ Please check GAMU factors, especially for L_U and L_T (in germany GAMU 1.35)
ACT G_1 TITL 'dead load'
ACT G_2 TITL 'dead load'
ACT P GAMU 1.00 GAMF 1.00 PSI0 1.00 PSI1 1.00 PSI2 1.00 TITL 'prestress'
ACT C TITL 'C+S'
ACT ZC GAMU 1.00 1 SUP PERM PSI0 1.00 PSI1 1.00 PSI2 1.00 TITL ' life load creep part'
ACT L_T GAMU - 0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S - TITL 'TS Tandemsystem'
ACT L_U GAMU - 0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'UDL basic load'
ACT L_1 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'UDL overload span 1'
ACT L_2 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'UDL overload span 2'
ACT L_3 GAMU 1.35 0 SUP EXCL PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'UDL overload span 3'
$ The GAMU and PSI factores are taken from the .ini file depending on the design code (-> check)
$ You can also define them nanually here e.g. with:
$ ACT L_T GAMU 1.35::1.50 0 SUP EXCL PSI0 0.75 PSI1 0.75 PSI2 0.20 PS1S - TITL 'TS Tandemsystem'
$ ACT L_U GAMU 1.35::1.50 0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'UDL basic load'
$ Superposition with ELLA traffic loading see more\csm31_design_ella.dat
$ here SUP COND=special case, since L_U is applied in MAXIMA/AQB without inter superposition!
$ L_1 with multiple UDL over loads in transvers direction needs EXCL, because only one to be taken
ACT SL GAMU 1.50 0 SUP COND PSI0 0.40 PSI1 0.40 PSI2 0.20 PS1S - TITL 'loading during construction'
$--------------------------------------------------------------------------
ACT FAT GAMU 1.50 0 SUP EXCL PSI0 1 1 1 TITL 'Fatigue LM3'
ACT SF GAMU 1.00 0 SUP EXCL PSI0 1 1 1 TITL 'possible settlement ULS'
ACT ZF GAMU 1.00 0 SUP EXCL PSI0 1 1 1 TITL 'probable settlement SLS'
$ Acc. DIN FB 101 - C.2.3 for settlements GAMA=1.00.
ACT W TITL 'wind transvers'
ACT T GAMU 0.81 0 SUP EXCL PSI0 0.80 PSI1 0.60 PSI2 0.50 PS1S - TITL 'temperatur'
$ In the ULS design you can usually take the temperature forces only with 60 %
$ because the concrete may crack and will have only 60% stiffness for the temperature effect in ULS.
$ Hence to simplify, set the ULS-gama-u value by 1.35 to 0.81 (0.81 = 1.35*0.60).
$ So: safety factor = 1.35 but only with factor 0.6 due to reduced stiffness (60% stiffness)
$---------------------------------------------------------------------------------------------------------
ACT R_1 GAMU 1.35 GAMF 0.90 SUP PERM TITL 'earth pressure'
$ Attention: if you use R or R_1 in CSM as construction stage, the earth pressure will be taken into account as variable action!
$ That is OK if the earth pressure is small compared to the other variable actions.
$ But if the earth pressure is very high it may happen that it will not be applied as favorable
$ as the container of the variable actions may not be applied due to their GAMF 0.
$
$ So in case the earth pressure is not small and you want to see the favorable effect in the forces
$ please use TYPE B or e.g. TYPE G_3 or G_4 in CSM with the corresponding safety factors in SOFILOAD!
$
$ But earth pressure is always taken into account correct as unfavorable!
ACT B GAMU 1.35 1 PART G SUP PERM PSI0 1 1 1 TITL 'construction stage'
$
$ The signs SUP PERM,COND,EXCL are necessary and set itself according to
$ the definition of traffic load cases:
$ SUP EXCL - only one out of available load cases
$ SUP CONC - all of the available load cases, if acting unfavourable
$ Meaning of PSI-Value:
$
$ Fraction :(1.00*Q-Leit + PSI0*Qki)*GAMU-GAMF
$
$ Rare : 1.00*Q-Leit + PSI0*Qki
$ frequent: PSI1*Q-Leit + PSI2*Qki
$ quasi : PSI2*Q-Leit + PSI2*Qki = PSI2*Q-all
$ not : PSI1*Q-Leit + PSI1*Qki
$
$ to : (ING-BAY-Buba-S.15)
$ See MAXIMA - theoretical basics
$ G if as generic term effects G the under effects
$ G_1 and G_2 combined! alike L the L_U plus L_T combined!
$ not but Z the ZF and ZS, as no underline follows!
$------------------------------------------------------------------------------------------------
END
END
$ Overview used user - load case nos:
$ 1- 99 basic load cases see following Sofiload-rund
$ UDL base-loads are definied in a way that they can be combined additive
$ (LC 21-24) ACT - SUP COND, thus no inter superposition is necessary
$
$ The Tandemsystem-Load cases 41-61 exclude each other EXCL
$ an also no inter superposition is necessary!
+PROG TENDON urs:20
HEAD Delete old tendons in database
TDEL 0 0 0
END
+PROG TENDON urs:9
HEAD Parabolic Prestress
UNIT 5 $ units: sections in mm, geometry+loads in m
$ Definition of prestressing system:
$ We recommend to input all data as user defined prestressing system.
$ For the static analysis the following values are sufficient:
SYSP NOPS MAT ZV AZ LITZ MINR BETA MUE ECC SP DO
$ 1 11 2430[kN] 1800[mm2] 12 6.50[m] 0.3 0.20 4[mm] 3[mm] 82[mm] $ csm3_parabel and csm32_slab, 12 wires
$ 1 11 3078[kN] 2250[mm2] 15 7.10[m] 0.3 0.20 4[mm] 3[mm] 92[mm] $ 15 wires
1 11 3848[kN] 2850[mm2] 19 6.50[m] 0.3 0.21 4[mm] 3[mm] 97[mm] $ csm31_beam 19 wires
$ 1 11 2430[kN] 1800[mm2] 12 6.50[m] 0.0 0.00 0[mm] 0[mm] 10[mm] $ csm3_casting_yard
$
$ reference axis and span definition:
AXES NOH 1 TYPE AUTO 101 121
TOPP NOH 1 KIND NODE S 101,111,121 SP 1,2,3
$ S=101 .. SP 1 = Node 101 is beginning first span
$ or TOPP NOH 1 KIND NODE S 101,102,111,120,121 SP 0,1,2,3,4 with excess from 101-102
$ tendon geometry definition: NOPS = prestressing system for max-min radius parameters + duct-excentricities
TGEO NOG 1 NOH 1 NOPS 1
$ Definition points of geometry: (TYP=SPAN/FELD station via highpoints)
PTUV S U V DVS RV RL TYPE=SPAN
1 0 0.4 - - -
1.4 - 1.22 0 - -
2 0 0.16 0 9.5 1.3
2.6 - 1.22 0 - -
3 0 0.4 - - -
$ Additional values: construction stages:
CS ICS1 11 12
$ prestress-procedure $ Anspann-Vorgehen
PSIG 'RILE' ANWS 9 KAPA - K3 1280 $
$ k3 = estimated limit to reduce stress at traffic opening (after first creep+shrinkage)
$ max-sigma-traffic opening in most cases (e.g. to EN-1992-1-1 7.2(5)) -> 0.65 fpk (or 0.75 depending on design code)
$ 1260 N/mm2 = choosen tendon stress at day of stressing before first creep and steel relaxation
$ after this day we have about 6% loss up to traffic opening : 0.94*1280 = 1203N/mm2 = allowable 0.65*ft see AQUA above
$ final tendon definition:
TEND NOT 1 NOG 1 NTEN 4 LC 3 LC0 0
$
echo plot full $ tendon plots:
SIZE URS
$
PLOT GEOE NO all FACH 5 TYPG DUTE
PLOT FACT NO 1 FACH 15
end
+PROG SOFILOAD urs:8
HEAD
UNIT 5 $ units: sections in mm, geometry+loads in m
LC 1 FACD 1.0 TITL 'G_1' TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
LC 2 TITL 'G_2' TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
BEAM GRP 1,2 TYPE PZZ 15
LC 3 TITL 'prestress' TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
$ Traffic via influence line evaluation: see csm.dat\...\more\csm31_design_ella.dat
$ would require L_U EXCL!
$ here SUP COND=special case, since L_U is applied in MAXIMA/AQB without inter superposition!
$ L_1 with multiple UDL over loads in transvers direction needs EXCL, because only one to be taken
$ Load model 1 acc. EN 1991 german annex with alpha values
!*!Label UDL
$ UDL basic load 3 kN/m2 = alpha-qgr*2.50 = 1.2*2.50
$ alpha-qgr*2.50 = 1.2*2.50 = 3 kN/m2 residual areas
LC 21 TITL 'UDL-span-1-r' TYPE L_U
BEAM GRP 1 TYPE PZZ PA 3.0*4.80 EYA 2.4[m] $ 4.80 m width
LC 22 TITL 'UDL-span-1-l' TYPE L_U $ = half bridge
BEAM GRP 1 TYPE PZZ PA 3.0*4.80 EYA -2.4[m] $ 4.80 m width
LC 23 TITL 'UDL-span-2-r' TYPE L_U
BEAM GRP 2 TYPE PZZ PA 3.0*4.80 EYA 2.4[m] $ 4.80 m width
LC 24 TITL 'UDL-span-2-l' TYPE L_U
BEAM GRP 2 TYPE PZZ PA 3.0*4.80 EYA -2.4[m] $ 4.80 m width
$ overload lane 1+2
$ alpha-q1*9.00 = 1.333*9.00 = 12 kN/m2 lane 1 alpha see din_en_1991-2_2012NA.pdf
$ alpha-q2*2.50 = 2.40 *9.00 = 6 kN/m2 lane 2
LC 31 TITL 'UDL-overload-r-1' TYPE L_1
BEAM GRP 1 TYPE PZZ PA (12.0-3.0)*3 EYA 2.10[m] $ 2.10 m maxi. excentricity
BEAM GRP 1 TYPE PZZ PA (6.0-3.0)*3 EYA 2.10-3.00[m] $ Lane 2 depending on national annex
LC 32 TITL 'UDL-overload-l-1' TYPE L_1
BEAM GRP 1 TYPE PZZ PA (12.0-3.0)*3 EYA -2.10[m]
BEAM GRP 1 TYPE PZZ PA (6.0-3.0)*3 EYA -2.10+3.00[m] $ Lane 2 depending on national annex
LC 33 TITL 'UDL-overload-r-2' TYPE L_2
BEAM GRP 2 TYPE PZZ PA (12.0-3.0)*3 EYA 2.10[m]
BEAM GRP 2 TYPE PZZ PA (6.0-3.0)*3 EYA 2.10-3.00[m] $ Lane 2 depending on national annex
LC 34 TITL 'UDL-overload-l-2' TYPE L_2
BEAM GRP 2 TYPE PZZ PA (12.0-3.0)*3 EYA -2.10[m]
BEAM GRP 2 TYPE PZZ PA (6.0-3.0)*3 EYA -2.10+3.00[m] $ Lane 2 depending on national annex
$ Maxima can take one loadcase of L_1 and one loadcase of L_2
!*!Label TS Tandem System
$ Tandemsystem : Lane 1:Wheel load 150 kN/Rad TS=SOFILOAD-TYP L !
$ Total excess load=600 kN (Please check safety factor GAMU ! 1.35/1.50)
$ Lane 2:Wheel load 100 kN/Rad
$ Total excess load=400 kN
$ =======================================================================
$ Case EYA1 Lane 1 is at right all xx m a Node position!
$----------------------------------------------------------------------------------------
$ Distribution of of lanes acc. EC
$ traffic width 7.20m:
$ vehicle full right: EYA1= 7.20m/2 - 1.50m = 2.10 m = center of lane 1
$ EYA2= 2.10 m - 3.00m = -0.90 m = center of lane 2
loop#1 20
LC 101+#1 TITL 'Tandem system lane 1+2' TYPE L_T
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY 2.10+1.0[m] $ EYA1
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY 2.10-1.0[m]
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY -0.90+1.0[m] $ EYA2
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY -0.90-1.0[m]
endloop
$ Achsabstand 1.20 m = +- 0.60 - axis distance 1.20 m = +- 0.60
LC 201 TITL 'Tandem system left lanes' TYPE L_T $ only two to show principle !
let#1 3
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10+1.0[m] $ EYA1 left
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10-1.0[m]
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90+1.0[m] $ EYA2 left
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90-1.0[m]
LC 202 TITL 'Tandem system left lanes' TYPE L_T $ only two to show principle !
let#1 6
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10+1.0[m] $ EYA1 left
BEPL FROM 1101 TO 2121 TYPE PZZ P 600/4 A 2.14*#1,2.14*#1+1.20 EY -2.10-1.0[m]
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90+1.0[m] $ EYA2 left
BEPL FROM 1101 TO 2121 TYPE PZZ P 400/4 A 2.14*#1,2.14*#1+1.20 EY +0.90-1.0[m]
!*!Label Settlement
$ The potential ground movements in the check of ultimate limit state are to be affixed, by their determination
$ accor. to (German)DIN FB 102 II-2.3.2.2(103)P, without any further checks a 0.6-times stiffness of
$ state I to be deposed (due to potential transfer in to state II).Accor. to the opinion of SOFiSTiK (Dr. Bellmann)
$ then in the superposition a load safety factor g=1.35 to be affixed
LC 81 TITL 'possible settlement ULS 1+3' TYPE SF $ 'mögl.Setzung ULS 1+3'
NODE NO 50101,50121 TYPE WZZ 1000*0.01*0.60[mm] $ entspricht Berechnungen mit 0.6-fachen Steifigkeiten
$ equivalent analysis with 0.6-times stiffness
LC 82 TITL 'possible settlement ULS 2' TYPE SF $ 'mögl.Setzung ULS 2'
NODE NO 50111 TYPE WZZ 1000*0.01*0.60[mm]
$ The probable ground movements in checks of serviceability
$ limit state must be applied 1.0- times, see DIN FB 102 II-2.3.4(110)P.
$ The 0.6- reduction is not feasible here!
$ 1 cm as possible settlement ULS and 0.5 cm as probable settlement SLS is applied in this analysis,
$ respectively per column axis applied and superposed unfavorable.
LC 83 TITL 'probable settlement SLS 1+3' TYPE ZF $ wahrscheinliche Setzung SLS 1+3
NODE NO 50101,50121 TYPE WZZ 1000*0.005[mm]
LC 84 TITL 'probable settlement SLS 2' TYPE ZF $ wahrscheinliche Setzung SLS 2
NODE NO 50111 TYPE WZZ 1000*0.005[mm]
!*!Label Temperature
$----------------------------------------------------------------------------------------------
Additional Explanations
According to EN1991-1-5 chapter 6 temperature loads belong to the variable actions.
Constant temparature (relative to erection temperature T0)
delta TN,con = dT = -27.0°C (con...contraction) Te,min=-17°C - T0=+10°C erection
delta TN,exp = dT = +27.0°C (exp...expansion) Te,max= 37°C - T0=+10°C erection
A temperature gradient will be applied according to table 6.1
delta TM,heat = DTZ = 12.3°C top surface warmer (15*0.82)
including surface factor k_sur 0.82
delta TM,cool = DTZ = -8.0°C bottom surface warmer
Positive values of DTY and DTZ mean that the temperature raises in the positive
direction of the corresponding Y resp. Z axis. This load type is only applicable
for sections having a distinct extension or geometry
---> x |===============| Top = 40°C
| | |
| |===============|
V z | | DTZ = 30°C - 40°C = -10°C
| |
| |
|===============| Bottom = 30°C
A simultaneous application of constant and variable temperature results in
8 combination according to EN1991-1-5 chapter 6.1.5:
delta TN + wm*delta TM and
wn*delta TN + delta TM
The combination factors are:
wn = 0.35
wm = 0.75
LC 86 TYPE none TITL 'TN-summer' ; BEAM GRP 1,2 TYPE DT PA 27.0 $ Te,max= 37°C - T0=+10°C erection
LC 87 TYPE none TITL 'TN-winter' ; BEAM GRP 1,2 TYPE DT PA -27.0 $ Te,min=-17°C - T0=+10°C erection
LC 88 TYPE none TITL 'DT warm on top' ; BEAM GRP 1,2 TYPE DTZ PA -12.3
LC 89 TYPE none TITL 'DT warm bottom' ; BEAM GRP 1,2 TYPE DTZ PA 8.0
$ Temperature combinations - Temperatur Kombinationen:
LC 90 TYPE T TITL 'T summer posdt TN+wm*dT' ; COPY 86 ; COPY 88 FACT 0.75
LC 91 TYPE T TITL 'T summer negdt TN+wm*dT' ; COPY 86 ; COPY 89 FACT 0.75
LC 92 TYPE T TITL 'T winter posdt TN+wm*dT' ; COPY 87 ; COPY 88 FACT 0.75
LC 93 TYPE T TITL 'T winter negdt TN+wm*dT' ; COPY 87 ; COPY 89 FACT 0.75
LC 94 TYPE T TITL 'T summer posdt wn*TN+dT' ; COPY 86 FACT 0.35 ; COPY 88
LC 95 TYPE T TITL 'T summer negdt wn*TN+dT' ; COPY 86 FACT 0.35 ; COPY 89
LC 96 TYPE T TITL 'T winter posdt wn*TN+dT' ; COPY 87 FACT 0.35 ; COPY 88
LC 97 TYPE T TITL 'T winter negdt wn*TN+dT' ; COPY 87 FACT 0.35 ; COPY 89
$ ----------------------- Einheitstemperaturlastfälle für Lagerwege -----
$ ----------------------- + 10 Grad gleichmässige Mittentemperatur -----
LC 98 TYPE none TITL 'Temp 10 degree constant'
BEAM GRP 1,2 TYPE DT PA 10 $ Überbau
$ ----------------------- + 10 Grad dt/h oben warm ---------
LC 99 TYPE none TITL 'Temp dt/h 10 degree warm on top'
BEAM GRP 1,2 TYPE DTZ PA -10
$----------------------------------------------------------------------------------------------
!*!Label Load in construction stage
$ load in construction stage on one span only:
LC 71 TITL 'SL_construction' TYPE none $ Typ none, $ as G_1, G_2 and P are subsequently generated by csm
BEAM GRP 1 TYPE PZZ PA 1*2.5 EYA 0.0[m]
!*!Label Wind
LC 72 TITL 'wind_transvers' TYPE W $ will not be used further!
BEAM GRP 1,2 TYPE PYY 30.0 $ only to test!
$----------------------------------------------------------------------------------------------
$
!*!Label Fatigue load model 3
$ Fatigue load model 3 : Wheel load 60 KN/Rad - 4 Axis
$ Axis distances 1.20 - 6.00 - 1.20
$ Attention: Do not define this load as TYP L, because this may not be superposed with the
$ load model 1 at all !!
$ Case A Lane 1 is at right: all xx m a Load position!
loop#1 18
LC 701+#1 TITL 'LM3_right' TYPE FAT
let#x1 #1*2.00 ; let#x2 #x1+1.20 ; let#x3 #x2+6.00 ; let#x4 #x3+1.20
BEPL FROM 1101 TO 2121 TYPE PZZ P 60 A #x1,#x2,#x3,#x4 EY 2.10+1.0[m]
BEPL FROM 1101 TO 2121 TYPE PZZ P 60 A #x1,#x2,#x3,#x4 EY 2.10-1.0[m]
endloop
END
+PROG ASE URS:6
HEAD Analysis of single load cases
ECHO FORC,DISP,LOAD no
LC 1,2,3 $ G_1, G_2, P
LC 9 FACD 1.0 TITL 'G_1+G_2+P' TYPE none
LCC 2,3 $ If LC 1 has yet loads apart of FACD, then also LCC 1!
$ To compare G1+G2+P in a LC 9
LC 21,22,23,24 $ UDL basic loads span 1
LC 31,32,33,34 $ UDL super loads span 2
LC (101 120 1) $ Tandem loads right
LC 201,202 $ Tandem loads left $ only two to show principle !
LC 71,72 $ construction and wind
LC 81,82,83,84 $ settlements
LC (90 99 1) $ temperature
LC (701 718 1) $ fatigue LM3
END
END
!#!Kapitel CSM Stage Analysis
+PROG CSM URS:87
HEAD Construction sequence
CTRL DL AUTO $ Dead load of gamma automatically
CTRL GPCS 0 $ CTRL GPCS 1 $ GPC-separated = more accurate in case of removing supports
ECHO RCRE full
$
CS 10 TYPE G_1 TITL 'G_1'
CS 11 TYPE P TITL 'Prestress'
CS 14 TYPE SL TITL 'loading during construction' $ 'SL is not included in the normal design - CSM Design Construction stages - at the end of this file'
CS 15 TYPE C_1 TITL 'Creep+shrinkage until G_2' T 40
CS 20 TYPE G_2 TITL 'G_2, asphalt, capping'
CS 25 TYPE C_1 TITL 'Creep until traffic opening' T 40
CS 34 TYPE ZC TITL '20 % UDL'
CS 35 TYPE C_2 TITL 'Creep until t-infinite' T 365*100 NCRE 2
$
GRP NO ICS1 T0 PHIF=1
- 10 14 $ all groups will be activated in construction stage 10, TO= 14 Days
$
$ LC: only secondary loads! prestress load cases will be automatically inserted!
LC 2 ICS1 20 $ g_2
LC 21,22,23,24,31,33 ICS1 34 FACT 0.2 $ 20 % permanent live load UDL for C+S
LC 71 ICS1 14 ATIL 14 $ temporary load in construction stage only SL !
SELE BEAM 1105 X 0[m] $ Beams for the AQB stress output
$ 2111 X 0[m]
SCAL AQ_S 5 $ Scale for the Plot-Output -> $(NAME)_csm.plb
BOX zmin -1 zmax 0.01 GRP 1,2 $ graphic box for WING (also for the design)
END
+apply "$(NAME)_csm.dat"
-PROG CSM URS:10
HEAD Check print construction stages for another beam
SELE BEAM 2111 X 0[m]
CTRL FILE '2111' $ filename for the created input file
END
-apply "$(NAME)_2111.dat"
$ The C+S loss of normal force is an inner stress state and thus not included in the
$ loadcases 4000...
$ This loss is calculated in AQB and lies in the 6000... loadcases.
$ With CTRL STOR 1 such AQB runs are created and store COMB-LCST 7000...
$ loadcases that include the C+S loss of normal force!
$ .
$ Please run csm31_design.dat and check this in -> WINGRAF BEAM-N LC 7010 to 7039.
$ .
!#!Kapitel Addition JE START
+prog ase urs:23
head Primary part of prestress
step 1 1 $ only beams with prestress are activated without any supports => this command delivers primary part of prestress
GRP 1 CS 11 T1 14.0 $FACD 1
GRP 2 CS 11 T1 14.0 $FACD 1
$GRUP 9 BA 11 T1 14.0 $FACD 1
ELEM ETYP SPRI 9111,9112 FACS 0
LC 25011 titl "Primary part of prestress"
LCC 3
end
+prog maxima urs:25
head Secondary part of prestress
COMB 99 EXTR STAN
LC 25011 TYPE G fact -1
LC 5011 TYPE G fact 1
SUM COMB 99 LC 26011 titl "Secondary part of prestress"
end
+prog DECREATOR urs:22
head
DSLN 1 NCS 1 HDIV 0.5
$ DGEO OPT LINE X1 0 0 0 X2 42.8 0 0 DRZ 1
DGEO OPT BEAM (1101 1110 1)
DGEO OPT BEAM (2111 2120 1)
LC 5011
LC 15011,16011
LC 25011,26011
end
!#!Kapitel Addition JE END
!#!Kapitel Superposition
-PROG CSM URS:88
HEAD Head Superpositioning for the following CSM design : ACT input and DESI MAX
$
ACT TYPE FOR $ Definition of additional actions: G,P,C are activated automatically
L_U SLS,ULS $ -> MAXIMA: SUP COND UDL base load
$ L_U...L_T in most times better with a MAXIMA pre superposition see csm33_earthquake_bridge.dat
L_1 SLS,ULS $ UDL oberload span 1 - take only one
L_2 SLS,ULS $ UDL oberload span 2 - take only one
L_T SLS,ULS $ tandem axle
$ Superposition with ELLA traffic loading see more\csm31_design_ella.dat
T SLS,ULS $ temperature
ZF SLS $ true settlement SLS
SF ULS $ possible settlement ULS
FAT FAT $ activates more exact fatigue design via damage equivalent range of steel stresses.
$ A simple fatigue check will be done without this line.
DESI MAX $ Only perform superpositioning without design
CTRL FILE 'maxi' $ filename for the created input file
END
-apply "$(NAME)_maxi.dat"
$ How to check the combination factors is written in the created _chek.dat input file at chapter Check-print ULS design
$ -> +PROG AQB $ Check Print ULS design at the COMB combinations.
!#!Kapitel Design (see YOUTUBE Video)
$ Please also watch the YOUTUBE video 'CSM DESI Bridge Design' on this topic -> https://www.youtube.com/watch?v=zoCshb
$ For result checks -> https://www.youtube.com/watch?v=in8OTk24f1U
$ and YOUTUBE video 'CSM DESI Beam Interpretations'
-PROG CSM urs:11
HEAD Checkprint design for one beam
$ After the superpositioning now with pure DESI CHEK a short and clear design of one beam can be done
DESI CHEK $ Important checkprint for one beam to verify the stress in defined stress points
SELE BEAM 1105 X 0[m] $ Beam for the check print
CTRL FILE 'chek' $ filename for the created input file
END
-apply "$(NAME)_chek.dat"
!#!Kapitel ULS Ultimate State design
-PROG CSM urs:12
HEAD ULS Ultimate State design of all beams
DESI ULTI $ ULS design only
CTRL FILE 'uls'
END
-apply "$(NAME)_uls.dat"
Comments to CSM DESI:
To not get confused by the huge amount of results we recommend to let them run separate (here only DESI ULTI).
Then you can better check the results separate and you have a better overview.
Using SSD you best insert multiple CSM-DESIGN tasks with only one design task each.
Using Teddy you can also open the created _gzt.dat file and run and check the results separate.
Please notice that with every CSM-DESI run also a WINGRAF .gra file is created.
In this file the actual result plots are already prepared for interactive changes (box, groups):
Please open windows explorer and double klick on file _uls.gra
Or open WINGRAF and from there open file _uls.gra
Then please immediately store the .gra file under another name to keep your changes.
Or in SSD: insert task 'Interactive graphics' and from there open file _gzt.gra
With a CSM-DESI STAN run (here at the end) you can also get an overview over the possible design tasks.
!#!Kapitel Minimum reinforcement and crack design
-PROG CSM urs:14
HEAD Minimum reinforcement and crack design of all beams
DESI MREI $ Minimum reinforcement
DESI CRAC $ Crack design only
CTRL FILE 'crac' $ filename for the created input file
END
-apply "$(NAME)_crac.dat"
!#!Kapitel Stress checks
-PROG CSM urs:15
HEAD Stress checks
DESI SIG $ Stress checks
CTRL FILE 'sig'
END
-apply "$(NAME)_sig.dat"
!#!Kapitel Decompression check
-PROG CSM urs:16
HEAD Decompression check
DESI DECO $ Decompression check only
GRPD 1,2 $ group selection
CTRL FILE 'deco'
END
-apply "$(NAME)_deco.dat"
!#!Kapitel Fatigue check
-PROG CSM urs:17
HEAD Fatigue check with damage equivalent stress range for load model LM3
DESI FAT PAR1 4 PAR8 2 $ PAR1 4 : only use MAMI-MY and MAMI-VZ for the permanent Temp/Settlement parts (to reduce calculation time)
$ PAR8 2 : only use MAMI-MY for the stress range relevant loads FAT (to reduce calculation time)
$ without PAR1 and PAR8 all possible combinations are calculated
LAM LAMS 1.44 LMS2 1.18 LAMT 1.30 LMT2 1.30 LAML 1.18 LML2 1.18 LAMC 0.85 $ FAT lambda values
$ The primary and secondary effect of prestress are automatically separated, see DESI FAT PAR3
$ see also comments in csm3_P0_P_1.dat
$ Comment: in file _csmlf.dat the two literals PB and ZP are defined for AQB LC
$ In the AQB design file _fat.dat" then these literals PB and ZP are used in AQB-COMB in the fatigue check
CTRL FILE 'fat'
END
-apply "$(NAME)_fat.dat"
$ Example to calculate the labda values according DIN Fachbericht 102 4.3.7.5
$ and Appendix A.106.2 (101)P see also EN 1992-2: Appendix NN.2 road bridges
$ and EN 1992-1-1 6.8.5(3) (6.71)
$ LET#phi 1.2 $ surface roughness 1.2 bis 1.4
$ LET#K2 1/7 $ exponent for Woehlerlines
$ LET#LAM1 1.30,1.06 $ coef. tendons/reinforcement in midspan A 106.2
$ or:
$ LET#LAM1 1.05,0.93 $ coef. tendons/reinforcement inner supports A 106.1
$ LET#LAM2 0.92*(3.0/2)**#K2 $ traffic 3.0 Mio vehicles/year
$ LET#LAM3 (90/100)**#K2 $ time of usage 90 years
$ LET#LAM4 (1/1)**#K2 $ traffic lanes - may be set!
$ LET#LAMT #PHI*#lam1(0)*#lam2*#lam3*#lam4 $$ tendons
$ LET#LAMS #PHI*#lam1(1)*#lam2*#lam3*#lam4 $$ reinforcement
$ LET#LAML #PHI*#lam1(1)*#lam2*#lam3*#lam4 $$ stirrups links
$ Concrete with sigma_c,perm according EN 1992-2 NN.3.2
$ Correction factores LAMC as product lambda_c1*lambda_c2*lambda_c3*lambda_c4
$ (for lambda-c,1 often value 0.85 is OK
$ for lambda-c,2,3,4 1.0, so all together LAMC 0.85 )
$ The lambda values must be input in the CSM DESI run with LAM.
-PROG TEMPLATE -E urs:19
HEAD Design Concept fatigue with damage equivalent stress range for load model LM3
Comments to the fatigue check:
In case settlement or temperature actions are defined in the CSM DESI MAXI run, the induced MAXIMA
creates a container Y_8 (combination TEMP_SETZ) that combines the most unfavorable forces of
settlement and temperature.
In the AQB run then in a loop in a time one of these Y_8 loadcases (LC 1841...) is used as permanent
part and the stress range is calculated with the fatigue acting FAT loadcases.
If necessary and possible, the reinforcement is increased in the fatigue design.
An additional loop performs the check one time for pk-inf and one time for pk-sup.
As for different span and support locations different axle load factors (1.40 und 1.75)
must be applied, three AQB design runs are started:
- In a first run with axle load factor 1.40 (span) for all elements the reinforcement fatigue check
is done. The used or increased reinforcement is stored in design case 23.
The maximum stresses can be plotted in Wingraf under the AQB LCST loadcase storage number.
See "Overview result access beam elements in WINGRAF" in the CSM DESI report.
- With the possible increased reinforcement then the concrete check with axle load factor 1.0 is done.
The results of this run can be plotted in Wingraf under the AQB LCST loadcase storage number.
This block runs after the span run with factor 1.40 to use the may be increased reinforcement!
- Finally the design for support regions is done with axle load factor 1.75 for all elements.
The used or increased reinforcement is stored in design case 25.
The user then has to decide manually, if a beam must be assigned to span or support region and
if for this beam either design case 23 or 25 is relevant.
Generally the used or increased reinforcement is always stored in a new design case.
This is also done in case no reinforcement is increased e.g. in a stress check.
That allows the user to check the reinforcement that has really been used for this design.
Overview over the design case numbers for beam elements:
number design:
11 Ultimate limit design
12 Crack design and minimum reinforcement
13 Concrete stress nonfrequent < 0.6 fck
14 Concrete stress permanent < 0.45 fck
15 Reinforcement stress rare/nonfrequent
16 Tendon stress permanent
17 Tendon stress characteristic (rare)
18 Decompression Eurocode
19 Decompression permanent Pk,inf
20 Fatigue couplings 0.75 prestress
21 Reinforcement stress range <70 MPa with LM1
23 Fatigue span axcle load factor 1.40
24 Fatigue concrete axcle load factor 1.0
25 Fatigue supports axcle load factor 1.75
26 Stress range LM3 without increasing lambda factors
31 Accidential
32 Earthquake
1 Maximum of all checks
END
$ =========================================================================================================
!#!Kapitel All checks without +apply to generate result table: Overview design tasks
-PROG CSM urs:18
HEAD
DESI STAN $ all usual checks
CTRL FILE 'all' $ All checks without +apply to generate result table: Overview design tasks
END
$ +apply "$(NAME)_all.dat"
!#!Kapitel Stresses from AQB checks
-PROG RESULTS urs:13
HEAD Stresses from AQB checks, Manual ULS design run with more output
SIZE TYPE "URS"
LC NO 2105 ENO 1105 X 0 ; CROS TYPE RFSS ETYP BEAM RTYP NONL SCHH 0.25 REPR DLIN
LC NO 2106 ENO 2111 X 0 ; CROS TYPE RFSS ETYP BEAM RTYP NONL SCHH 0.25 REPR DLIN
CROS TYPE SIG ETYP BEAM RTYP NONL SCHH 0.25 REPR DLIN $ only concrete stress
END
$ Overview output of results with PROG RESULTS see ase.dat\english\ase1_overview.dat
$ There see also "Stresses for unit forces AQB->GRAF"
-PROG AQB urs:34
HEAD Manual ULS design run with more output
ECHO FORC,USEP NO
ECHO COMB,REIN,DESI,STRE FULL
CTRL SVRF 1.00000 $ take into account reinforcement for C+S
CTRL VM VAL2 1.0 $ take into account normal force delta-N of torsion in bending design DESI
$ loadcases to be used:
#include "$(name)_csmlf.dat" $ AQB LC-loadcase definition of conctruction stages gpc
$ container of varying actions refer to ..._csmlf.dat
$ Y_D - presuperposed varying actions (ULS)
LC TYPE "Y_D " CST 9998 REF GROS
$ beams to be used:
BEAM 1105 x 0.0 CS auto
REIN LCR 91 $ Otherwise the old reinforcement results are deleted/overwritten
COMB MAXD MY TITL 'ULS_design+' LCST - LC1 G LC2 P LC3 C LC4 Y_D 1.0 $ Y_D in MAXIMA presuperposed ULS without gpc
DESI STAT ULTI $ ULS design
END
$
$
$ Example bridge construction - overview see top of this file and
$ - See also csm.dat\english\overview_csm_examples_english.pdf:
$
$
$ For design of construction stage 14 please activate following lines
$ +PROG CSM
$ head design of construction stage
$ Desi ULTB,DECB $ SIGB,CRAB
$ Desb CS 14 $ inclusive additional SL loads of CS 14
$ CTRL FILE 'desb' $ filename for the created input file
$ End
$ +apply "$(NAME)_desb.dat"
$
$ For a more complex construction stage design with various additional loadcases
$ see csm34_stage_design.dat (cable stayed bridge)
!#!Kapitel |\00Warum AQB UND MAXIMA |\01Why AQB AND MAXIMA
-prog TEMPLATE urs:21
head Why AQB AND MAXIMA superposition?
Comments to the superposition and design concept:
You find comments in the reports to CSM-DESI (e.g. in the output of the Checkprint Design)
Why AQB AND MAXIMA superposition?
Why AQB: because forces can act on different cross section stages:
1. Post-tensioned prestress P and structural dead load G_1 act on a partial cross section with
the ungrouted duct and do not create an additional stress change in the tendon (still unbonded).
(We assume that while stressing the tendon, the girder lifts from the formwork and
simultaneously activates G_1)
2. Additional dead load G_2 acts on the grouted cross section ( with tendon in bond)
and creates a stress change in the tendon.
Therefore we should not mix G_1 and G_2 before the design!
After a pre-superposition it is not possible to separate those effects!
3. Moreover in composite sections, the dead load G_1 usually acts on the steel part
of the section and the dead load G_2 acts on the composite steel and concrete.
4. Creep and shrinkage C create internal stress stages that cannot be taken into account
in MAXIMA.
In a composite section, shrinkage creates tension in the concrete and compression
in the steel while the external forces N and MY are zero.
In prestressed sections the loss of prestress due to creep and shrinkage is only an internal
stress state, the external forces N and MY are zero as well (without secondary effects).
5. All the variable load cases, that act on the final section can be pre-superimposed
in a MAXIMA container e.g. Y_D (CSM-DESI Eurocode design - see csm31_design.dat).
Why MAXIMA: because AQB only works on beams:
- All other elements like springs, cables or quads and support reactions do not have internal
section stages and can be superimposed in MAXIMA completely
(tendons in quad elements work in a different way than tendons in beam elements).
22.10.2014 Juergen Bellmann SOFiSTiK
end
$ Clean file folder:
-sys del $(project).$d?