!#!Kapitel Parametrisierung
+PROG TEMPLATE urs:6
KOPF Parametrisierung

! Material
STO#B    1               ! Wahl der Arbeitslinie --> 1 = Modifizierte ARBL mit TS, 2 = ARBL n. EC2 ohne TS

! System
STO#L    28.4            ! Pfeilerlänge [m]
STO#A    1/40            ! Pfeileranzug in Querrichtung
STO#n    20              ! Anzahl der Elemente - Empfehlung: Viele kurze Stäbe anstelle von Stabschnitten verwenden
STO#dl   #L/#n           ! Länge eines Elementes
STO#bo   5.50            ! Breite oben [m]
STO#d    1.50            ! Dicke konstant [m]
STO#d1   79              ! Verlegemaß der Längsbewehrung [mm]
STO#ux   0.100           ! Pfeilerkopfauslenkung [m]
                         ! (Schiefstellung ohne Schnittgrößen)

STO#db    16            ! Durchmesser Bewehrungsstab d
STO#ab    100           ! Verlegeabstand a

ENDE

!+!Kapitel Materialien und Querschnitte
+PROG AQUA urs:1
KOPF Materialien und Querschnitte
ECHO MAT,QUER,QDEF VOLL
ECHO PICT VOLL

!*!Label Norm
NORM DC DIN NDC EN1992-2004 COUN 49 CAT D

!*!Label Materialeigenschaften
! Beton Pfeiler mit TS
BETO NR 1  ART C 40 EC 24364
ARBL GEBR
                 EPS      SIG     TYP=SPL
                2.50      0       POL             ! Ansatz der Zugfestigkeit
                0.0812    1.40    POL
                0.0811    2.10    POL             ! 0.6*fctm
               -0.00     -0.00
               -0.40     -13.76
               -0.80     -25.65
               -1.20     -35.38
               -1.60     -42.62
               -2.00     -46.96
               -2.30     -48.00
               -2.70     -45.95
               -3.10     -39.26
               -3.50     -26.97
! Betonstahl
STAH NR 3 ART B GUET 500

!*!Label QS Pfeiler
! Pfeiler oben
QB NR 1 H #d*1000 B #bo*1000                SO #d1 MNR #B MBW 3 BTYP U DASO #db DASU #db A #ab AMIN 0 REF C ASB 20.53 SPT 4 BEZ ST_10_Oben
! Variabler Querschnitt
LET#i 1
LOOP  #n
        STO#bi  #bo+#dl*#i*#A*2                                             ! Breite var. [m]
        QB NR #i+1 H #d*1000 B #bi*1000     SO #d1 MNR #B MBW 3 BTYP U DASO #db DASU #db A #ab AMIN 0 REF C ASB 20.53 SPT 4 BEZ ST_10_Var.#i
        LET#i #i+1
ENDLOOP
ENDE

!#!Kapitel System
+PROG SOFIMSHC URS:7
KOPF System
SYST 3D GDIV 1000 GDIR POSZ
STEU MESH 1
STEU HMIN 1
ECHO MAT VOLL

SPT NR 1        X 0                Y 0 Z 0 FIX F                                 ! UK Pfeiler
SPT NR (2 #n 1) X (#ux/#n #ux/#n)  Y 0 Z (-#dl -#dl)
SPT NR #n+1     X #ux              Y 0 Z -#L FIX ZP                              ! OK Pfeiler
SPTS            TYP CYY CM 4.2E+07 GRP 10


LET#i   1
LOOP    #n

LET#qa  #n+2-#i
LET#qe  #n+1-#i
        SLN #i NPA #i NPE #i+1 QNR '#qa.#qe' GRP 1
        LET#i #i+1
ENDLOOP
ENDE

+PROG AQUA urs:17
KOPF Interpolation der Querschnitte
ECHO QUER JA
INTE   0
ENDE

!+!Kapitel Einwirkungen
!*!Label LF 1 - Momentenvorbelastung
+PROG SOFILOAD urs:3
KOPF Momentenvorbelastung
ECHO LAST JA

LF 1 BEZ 'Momentenvorbelastung'
KNOT 21 TYP MYY -10000
ENDE

!+!Kapitel Schnittgrößenermittlung (TH I + lin. el.)
+PROG ASE urs:4
KOPF Momentenvorbelastung
GRUP 10 NEIN
LF 1
ENDE

!+!Kapitel Nichtlineare Analyse
+PROG STAR2 urs:5
KOPF Nichtlineare Analyse
GRUP 10 NEIN
ECHO LAST JA
ECHO DEHN JA
ECHO MAT  JA

STEU II 20                                                  ! Theorie 2. Ordnung, weggesteuert, 20 Iterationen
DEHN S1 KSB SL KSV SL RISS JA RW 999 BB 0.4                 ! Ermittlung der Sekantensteifigkeit bei vorgegebenem Moment, KSV = SL --> Gebrauchszustandslinie ohne Materialsicherheit
LF 1000
    LC 1
ENDE