!#!Info  Example:       Cable stayed bridge optimization 20 staged analysis
!#!Info  Keyword:       construction stages; cable stayed bridge; optimization; equation system; pylon; target

$ On this topic, some YOUTUBE video exist, please search for 'SOFiSTiK Cable Optimization'

$ Here a list of the Optimization YOUTUBE videos (all videos see ASE-manual input command SYST)
$ https://youtu.be/PmAeevUeJcU         ASE cables formfinding        Cable sagging, formfinding, playing with cable forces
$ https://youtu.be/taaBfPlIRGA         CSM cantilever erection       CSM, CTRL CANT, creep and shrinkage
$ https://youtu.be/YxljlRZ2gME         CSM precamber optimization    Precamber, preparation for optimization
$ https://youtu.be/vRyBkK6kvvo         Nonlinear Force Optimization  with Cable Sagging : Introduction to CSM optimization
$ https://youtu.be/W2GqbTaRSsE         CSM force optimization        Cable stay optimization, explanations on a teddy file
$ https://youtu.be/XGL4lFmF1is         CSM OPTI deformation targets  Deformation targets in a staged analysis
$ https://youtu.be/vRyBkK6kvvo         Nonlinear Force Optimization  with Cable Sagging : Introduction to CSM optimization

!#!Info  Program:       CSM


!#!KAPITEL Material + cross sections
+PROG AQUA URS:1
HEAD Forcefinding with cable sagging on construction stages
UNIT 5 $ units: sections in mm, geometry+loads in m
NORM 'NS' 'en199X-200X-BRIDGE'     CAT 'B'  $ road bridges
STEE 1  S 355     TMAX 0
CONC 2  C   40               $ = C40/50
STEE 3  S  500    TITL 'reinforcement bars'
STEE 4   Y '1860' ES 160000 titl 'cable'

SECT NO 1 MNO 1 $ section superstructure
  let#t1 20  $ flange
  let#t2 20  $ web
  SV AZ 0.1 $ otherwise shear deformations appear too big
  PLAT 1 -5000[mm]    +0[mm]    +5000[mm]    +0[mm]  #t1[mm]
  PLAT 2 +5000[mm]    +0[mm]    +5000[mm] +1000[mm]  #t2[mm]
  PLAT 3 +5000[mm] +1000[mm]    -5000[mm] +1000[mm]  #t1[mm]
  PLAT 4 -5000[mm] +1000[mm]    -5000[mm]    +0[mm]  #t2[mm]

SCIT   2 D 4.50[m] T 0.50[m] MNO 2 MRF 3 $ section pylon

SCIT 3 D 90[mm] MNO 4                    $ section cables
SCIT 4 D 70[mm] MNO 4                    $ section cables backstay
END

!#!KAPITEL System generation
+PROG SOFIMSHA URS:2
HEAD Forcefinding with cable sagging on construction stages
UNIT 5 $ units: sections in mm, geometry+loads in m
SYST SPAC GDIV 1000 GDIR negz
NODE (1   1) X   -129,-105,-75,-45,-15
NODE (10 -1) X   +129,+105,+75,+45,+15
TRAN node 3,8 dz  20 dno 100
TRAN node 3,8 dz  25 dno 200
TRAN node 3,8 dz  30 dno 300  $ pier head
TRAN node 3,8 dz -15 dno 900  $ foundation

TRAN node 1  dx -2.0 dy +12,-12 dno 800,900  $ cable anchor block
TRAN node 10 dx +2.0 dy +12,-12 dno 800,900  $ cable anchor block

NODE 903,908 FIX f
NODE 801,810 FIX pp
NODE 901,910 FIX pp
NODE 1,10    FIX pypzmx

$ pylon GRP 0
GRP 0
  BEAM fit NA 903   3 NCS 2 KR POSY DIV 2
  BEAM fit NA   3 103 NCS 2 KR POSY DIV 2
  BEAM fit NA 103 203 NCS 2 KR POSY DIV 1
  BEAM fit NA 203 303 NCS 2 KR POSY DIV 1

  BEAM fit NA 908   8 NCS 2 KR POSY DIV 2
  BEAM fit NA  08 108 NCS 2 KR POSY DIV 2
  BEAM fit NA 108 208 NCS 2 KR POSY DIV 1
  BEAM fit NA 208 308 NCS 2 KR POSY DIV 1
$ superstructure
sto#div 10 $ looks better in precamber !
GRP 1  ;   let#1  3 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
           let#1  7 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
GRP 2  ;   let#1  2 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
           let#1  8 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
GRP 3  ;   let#1  4 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
           let#1  6 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div
GRP 4  ;   let#1  1 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div         EHIN MY
           let#1  9 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div AHIN MY
GRP 5  ;   let#1  5 ; BEAM fit NA #1 #1+1 NCS 1 DIV #div AHIN MY EHIN MYN

$ cables
GRP 101 ;  CABL NA 103   4 NCS 3
           CABL NA 108   7 NCS 3
GRP 102 ;  CABL NA 103   2 NCS 3
           CABL NA 108   9 NCS 3
GRP 103 ;  CABL NA 203   5 NCS 3
           CABL NA 208   6 NCS 3
GRP 104 ;  CABL NA 203 901 NCS 4
           CABL NA 203 801 NCS 4
           CABL NA 208 910 NCS 4
           CABL NA 208 810 NCS 4

$ Group title for WINGRAF:
GRP   0 titl 'Pylons'
GRP   1 titl 'Superstructure'
GRP   2 titl 'Superstructure'
GRP   3 titl 'Superstructure'
GRP   4 titl 'Superstructure'
GRP   5 titl 'Superstructure closing segment'
GRP 101 titl 'Cable midspan'
GRP 102 titl 'Cable sidespan'
GRP 103 titl 'Cable midspan'
GRP 104 titl 'Cable sidespan'

END
+PROG SOFIMSHC urs:5
HEAD Axis for SOFILOAD load trains, SSD Tendons, Animator environment
SYST REST
GAX 'AX_1'
GAXB X1 -200 0 0 X2 200 0 0  $ create axis from point 1 to point 2   (also with R)
$ GAX...TYPC SPLI and GAXC can create an axis through a set of points
end

!#!KAPITEL Loading
+PROG SOFILOAD URS:28
HEAD Definition of actions and loads
UNIT 5 $ units: sections in mm, geometry+loads in m
ECHO ACT Full $ Please check GAMU factors
ACT G_1
ACT G_2
ACT B   $ to be able to give a separate safety factor to this cable prestress
ACT P
ACT C
$
$ Loads used in CSM should get TYPE none because construction stages get an own type in CSM-CS
LC   2 TYPE NONE TITL 'g2'            ;  BEAM GRP 1,2,3,4,5 TYPE PG PA 20
LC   3 TYPE NONE TITL 'g1 additional' ;  BEAM GRP 1,2,3,4,5 TYPE PG PA 30

let#1 101 ; LC #1 TYPE NONE TITL 'cable WX' ; CABL GRP #1 TYPE WX PA -10 $ cable shortening 10 mm - scalable loadcases
let#1 102 ; LC #1 TYPE NONE TITL 'cable WX' ; CABL GRP #1 TYPE WX PA -10
let#1 103 ; LC #1 TYPE NONE TITL 'cable WX' ; CABL GRP #1 TYPE WX PA -10
let#1 104 ; LC #1 TYPE NONE TITL 'cable WX' ; CABL GRP #1 TYPE WX PA -10

LC 137 TYPE NONE TITL 'ballast sidespan   ' ; NODE 2,9 TYPE PG P1 100
LC 197 TYPE NONE TITL 'ballast midspan    ' ; NODE 5,6 TYPE PG P1 100
LC 139 TYPE NONE TITL 'weight last seg.+g1' ; NODE 2,9 TYPE PG P1 12.0*(34.54+30)
LC 199 TYPE NONE TITL 'weight last seg.+g1' ; NODE 5,6 TYPE PG P1 15.0*(34.54+30)
END

!#!KAPITEL First CSM run (estimated prestress)
+PROG CSM URS:29
HEAD 1. construction stage run
CTRL CANT 2  $ 1 = free cantilever erection with original inclination
             $ 2 = tangential cantilever erection - is inrelevant by using CAMB percamber MODE=line
CTRL DL AUTO $ Deadload applied automatically
CTRL PROB TH3
CS    10  TYPE G_1 TITL 'tower            ' ; GRP 0      $ GRP active starting from actual construntion stage ACTU
CS   110  TYPE G_1 TITL 'segment 1 + cable' ; GRP 1,101  $   "
CS 'act1' TYPE B   TITL 'cable stessing 1 '              ; LC 101 FACT  8 $ first estimated cable shortening
CS   120  TYPE G_1 TITL 'segment 2 + cable' ; GRP 2,102
CS 'act1' TYPE B   TITL 'cable stessing 2 '              ; LC 102 FACT  8
CS   130  TYPE G_1 TITL 'segment 3 + cable' ; GRP 3,103
CS 'act1' TYPE B   TITL 'cable stessing 3 '              ; LC 103 FACT 20 $ more as longer cables !

CS   137  TYPE G_1 TITL 'ballast sidespan'               ; LC 137 ATIL 149

CS   139  TYPE G_1 TITL 'weight last seg. '              ; LC 139 ATIL 139
CS   140  TYPE G_1 TITL 'segment 4 + cable' ; GRP 4,104                   HFIX 141 $ last segment placed on cantilever with dead load
                                                                                   $ and then welded (one step later welded)
CS 'act1' TYPE B   TITL 'cable stessing 4 '              ; LC 104 FACT 40 $ more backstay

CS   150  TYPE G_1 TITL 'remove ballast side'

CS   197  TYPE G_1 TITL 'ballast midspan  '              ; LC 197 ATIL 209
CS   199  TYPE G_1 TITL 'weight last seg. '              ; LC 199 ATIL 199
CS   200  TYPE G_1 TITL 'last segment 5   ' ; GRP 5                       HFIX 201 $ last segment placed on cantilever with dead load
                                                                                   $ and then welded (one step later welded)
CS 'act1' TYPE G_1 TITL 'hinges fixed 5   '
CS   210  TYPE G_1 TITL 'remove ballast mid'
CS   500  TYPE G_2 TITL 'g_2              '              ; LC   2

LC  3 ICS1 100   $ always acting on every segment when it is activated for the first time

$ CAMB CS 500 MODE EQIT $ if you activate this line, a simultanious precamber will be computed to
                      $ achieve zero deflection in stage 500
                      $ But notice: also piers will be precambered!

SELE BEAM 5001 X 0[m]        $ beam for AQB stress plots
CTRL STOR 0 ; SCAL AQ_S 0 $ no AQB check print
END

+apply "$(NAME)_csm.dat"
$ To be able to check old results: may be backup of cdb-status till now:
$ +sys copy "$(NAME).cdb" "csmcopyfirst.cdb"

!+!KAPITEL CSM Optimization run 1+2
+PROG CSM URS:32
HEAD CSM-Equation run 1
HEAD Computing required faktors of unit loadcases - here for a System with CSM stages
$ to achieve a desired force state - this run will create a new _csmequ.dat !

$ It is very profitable to assign each variabel loadcase EQLC to a corresponding EQBE
$ to keep an overview which scalable loadcase can effect a result best!
$ Here e.g. beams 746 can only be scaled with LC 5087
$ -> EQLC and corresponding EQBE in one line:

EQLC 5111 ; EQBE NO 1001      X  0[m] MY  -8000 ETYP BEAM CS 500 $ bending moments in superstructure
EQLC 5121 ; EQBE NO 2000+#div X 99[m] MY  -8000 ETYP BEAM CS 500 $ bending moments in superstructure
EQLC 5131 ; EQBE NO 3001      X  0[m] MY  -8000 ETYP BEAM CS 500 $ bending moments in superstructure

EQLC 5141 ; EQBE NO    3      X  0[m] MY      0 ETYP BEAM CS 500 $ desired pylon bending moment = 0.0

EQLC 5137 ; EQBE NO 2001      X  0[m] MY  -8000 ETYP BEAM CS 500 $ bending moments in superstructure  - ballast sidespan
EQLC 5197 ; EQBE NO 5001      X  0[m] MY  -8000 ETYP BEAM CS 500 $ bending moments in superstructure  - ballast midspan

EQIT 1 copy 80000 $ to start iterations manually - see following Iteration 1 - 2 - 3
     $ copy to save the result of stage 500 (loadcase 4500) in iteration check loadcases 80001 - 80002
     $      with check loadcases 80000 = start loadcase before the EQIT iteration !
END
+apply "$(NAME)_csmequ.dat"

!+!KAPITEL CSM Optimization run 2
+sys copy "$(NAME)_csmequ.dat" "$(NAME)_csmequ2.dat"  $ because two following +apply-s must have different names!
+apply "$(NAME)_csmequ2.dat"

!+!KAPITEL CSM Optimization run 3
+sys copy "$(NAME)_csmequ.dat" "$(NAME)_csmequ3.dat"  $ because two following +apply-s must have different names!
+apply "$(NAME)_csmequ3.dat"

+PROG WING URS:6
HEAD Check results after all EQIT Iterations
SIZE TYPE WIN SC 1100 SPLI 2x1 ; ctrl warn 873,95
VIEW TYPE DIRE X 0 Y 1 Z 0 AXIS NEGZ
BOX  XMIN -139.9311 YMIN 12.00012 ZMIN -3.863609 XMAX 133.5521 YMAX -12.00012 ZMAX 59.16440 TYPE BWIN OPER AND BGRP 0

MOVE X DEL DTYP TEXT ; MOVE X 1 14 UNIT PR SCHH .5 C 1001 DTYP TEXT ; TEXT before the EQIT Iteration
LC 80000 ; grp lc yes ; defo yes 25 ; BEAM N UNIT 10000 SCHH 0.35 STYP cabl ; defo no ; BEAM MY UNIT 20000 SCHH 0.30

MOVE X DEL DTYP TEXT ; MOVE X 1 14 UNIT PR SCHH .5 C 1001 DTYP TEXT ; TEXT after EQIT Iteration 1
LC 80001 ; grp lc yes ; defo yes 25 ; BEAM N UNIT 10000 SCHH 0.35 STYP cabl ; defo no ; BEAM MY UNIT 20000 SCHH 0.30

MOVE X DEL DTYP TEXT ; MOVE X 1 14 UNIT PR SCHH .5 C 1001 DTYP TEXT ; TEXT after EQIT Iteration 2
LC 80002 ; grp lc yes ; defo yes 25 ; BEAM N UNIT 10000 SCHH 0.35 STYP cabl ; defo no ; BEAM MY UNIT 20000 SCHH 0.30

MOVE X DEL DTYP TEXT ; MOVE X 1 14 UNIT PR SCHH .5 C 1001 DTYP TEXT ; TEXT after EQIT Iteration 3
LC 80003 ; grp lc yes ; defo yes 25 ; BEAM N UNIT 10000 SCHH 0.35 STYP cabl ; defo no ; BEAM MY UNIT 20000 SCHH 0.30

MOVE X DEL DTYP TEXT ; MOVE X 1 14 UNIT PR SCHH .5 C 1001 DTYP TEXT ; TEXT final result
LC  4500 ; grp lc yes ; defo yes 25 ; BEAM N UNIT 10000 SCHH 0.35 STYP cabl ; defo no ; BEAM MY UNIT 20000 SCHH 0.30
END

!+!KAPITEL Plot of stressfree precamber in database precamber

+sys copy $(name).cdb precamber.cdb
#define project=precamber
$            ^ to not destroy the original csm results in original database,
$              the following PROG work on the database precamber.cdb

+PROG CSM urs:7
HEAD Plot of stressfree precamber for whole superstructure
CAMB MODE ANI CS 100   $ only sum up all segment precamber without analysis (no load deformations)
                     $ only chain up all segment precambers !
                     $ CS 100 : do not use precamber of pylons to get horizontal alignment
                     $ in the superstructure at the pylons
EQIT ITER 0          $ use scalable loadcase factors from last CSM EQIT run, do not change it
END
+apply "$(NAME)_csmequ.dat"

+PROG WING urs:10
HEAD Plot of stressfree precamber for whole superstructure
                SIZE TYPE URS SC 0 SPLI '1*1'  ; SCHH H6 0.370000
MOVE X DEL DTYP TEXT; MOVE X 1 34 UNIT PR SCHH .6 C 1001 ; TEXT Plot of stressfree precamber for whole superstructure without pylon
                      MOVE X 1 28 UNIT PR SCHH .6 C 1001 ; TEXT Summing up precamber is done from stage 100-999
                      MOVE X 1 22 UNIT PR SCHH .6 C 1001 ; TEXT only for cantilevers, see input CAMB mode ANI CS 100
                GRP - yes
                GRP (101 104 1) off
                GRP  NUMB ALAN OPTI OFFL $ no axis plot
                VIEW TYPE DIRE X 0 Y 1 Z 0 AXIS NEGZ ROTA 0 ;  LC NO 4500 DESI 1
                DEFO TYPE YES FAC 100 ; STRU NUME FULL FILL NO REPR DSTR UNIT DEFA SCHH YES
END
$ You can also open Animator on database precamber.cdb and check what happens (pure ANI run, only chain up all segment precambers)

$ For this example, a YOUTUBE video exists, please search for 'SOFiSTiK CSM Force optimization with cable sagging'

$ Clean file folder:

+sys del $(project).$d?