!+!Kapitel Eingabeparameter
+PROG TEMPLATE urs:1
KOPF Eingabeparameter

! Geometrie
STO#L 1.0           ! Länge[m]
STO#H 200           ! Höhe [mm]
STO#B #H            ! Breite [mm]
STO#Ac #H*#B*10^-6  ! Querschnittsfläche [m²]

! Material
STO#fck 35              ! Char. Zylinderdruckfestigkeit
STO#fcd 0.85*#fck/1.5   ! Bemessungswert der Betondruckfestigkeit
STO#red 1.00            ! Reduktionsbeiwert Betonzugfestigkeit

! Einwirkung
STO#PZZ 100                  ! Lasteinwirkung [kN]

! Kriechen und Schwinden
STO#T0 2 ! Erstbelastungsalter
STO#TS 2  ! Beginn Austrocknen/Ausschalen
STO#RH 50 ! rel. Luftfeuchte


ENDE

!+!Kapitel Materialien, Querschnitt (Balken)
+PROG AQUA urs:5
KOPF Materialien und Querschnitte
ECHO VOLL

!*!Label Norm
NORM DC DIN NDC EN1992-2004 !CAT D

!*!Label Materialeigenschaften
BETO NR 1 ART C FCN #fck FCTK #red*0.3*#fck^(2/3)
MEXT 1 EXP 'C10'  TYP  AIR VAL 1 1 !immer belüftet
MEXT 1 EXP 'C1I'  TYP  AIR VAL 0 1 !belüftet in BA10, nicht belüftet in BA30 (Oberseite)

$BETO NR 2 ART C FCN #fck FCTK #red*0.3*#fck^(2/3)
$MEXT 2 EXP 'C20'  TYP  AIR VAL 1 1 !immer belüftet
$MEXT 2 EXP 'C2I'  TYP  AIR VAL 0 1 !nicht belüftet in BA30

STAH NR 3 ART B GUET 500

!*!Label Querschnitt
!REFERENZQUERSCHNITT


!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
! Polygon in Querschnitt 1 doppelt definiert -> 1x in BA 10 und 1x in BA 30
! deshalb hier in BA 30 nur einen nichr für die Bemssung relevanten Geometriepunkt eingeführt
! wegen Warnung Nr. 929: Spannungspunkte QSP mit Material 1 mit in den BA 10 gesetzt

QNR NR 1 MNR 1 MBW 3 BTYP 'BEAM'

BA 10 BEZ 'BA10'
QSP  NR         Y               Z
     OM         0               0
     OR         #H/2            0
     UR         #H/2            #H
     UL        -#H/2            #H
     OL        -#H/2             0

QPOL ART U MNR 1
QP  NR   Y      Z       REFP     EXP
    '11'   0      0       OL    'C1I'       ! Diese Seite soll ab dem BA 30 nicht mehr belüftet sein
    '12'   0      0       OR    'C1O'
    '13'   0      0       UR    'C1O'
    '14'   0      0       UL    'C1O'

BA 30 BEZ 'BA30'
qsp TEST 0. 100.  mnr 0

ENDE

!+!Kapitel Querschnitt, System
-PROG SOFIMSHA urs:3
KOPF System
UNIT 5 ; SYST 3D GDIR POSZ GDIV 1000
KNOT NR                 X             Y                    Z
     1,2               0,0           0,0                  0,-#L
KNOT NR FIX ;  1 f

GRUP 1
STAB NR 1 KA 1 KE 2 QNR 1 TEIL 10
ENDE

!+!Kapitel Einwirkungen
-PROG SOFILOAD urs:6
KOPF Einwirkungen

ACT G_1 BEZ 'Eigengewicht'
ACT G_2 BEZ 'Zwangsverformung'
ACT C   BEZ 'Kriechen + Schwinden'

LF 2 TYP 'none'

! Normalkraft
  KNOT 2 TYP PZZ #PZZ

ENDE

-PROG ASE urs:2
KOPF Berechnung lin-el.

LF 2

ENDE

!#!Kapitel Kriechen & Schwinden
-PROG CSM urs:16
KOPF Bauablauf LF4010+
STEU KRIE RKRI
STEU EIGE EN10       ! Auswahl Regelwerk

STEU EG AUTO         ! Eigenlast wird ausgeschaltet

BA 10 TYP G_1                           BEZ 'EG'
BA 20 TYP C_1 RH #RH T 5      NKRI 10   BEZ 'Kriechen Bauzustand'

BA 30 TYP G_2                           BEZ 'Ausbaulast'               !ab hier soll eine Außenseite nicht mehr belüftet sein
BA 40 TYP C_2 RH #RH T 365*50 NKRI 30   BEZ 'Kriechen Endzustand'

GRUP NR - IBA1 10 T0 #T0 TS #TS         BEZ 'Aktivierung aller Elemente'

LF NR 2 IBA1 30 WBIS -

ENDE

$ Dann die Datei $(NAME)_csm.dat  laufen lassen
$ Wird hier automatisch über +apply erledigt
-apply "$(NAME)_csm.dat"