+PROG AQUA urs:1
HEAD TEMPLATE SECTION WITH VARIABLES ALONG AN AXIS
$
  NORM DIN EN1992-2004
  ECHO SECT EXTR
  CONC 1 C 30 ; STEE 2 B 500B
$
SECT 10 TITL 'Hollow section'
$
  TVAR HEIGHT 4.0[m]  CMNT 'Total height'
  TVAR WIDTHU 3.6[m]  CMNT 'upper half width of box'
  TVAR WIDTHL 3.5[m]  CMNT 'lower half width of box'
  TVAR INC    0.00    CMNT 'INCLINATION AS TANGENS'
  TVAR ALFR    0.0    CMNT 'INCLINATION ID TO THE RIGHT'
  TVAR ALFL    #PI    CMNT 'INCLINATION ID TO THE LEFT'
$
  SPT  OM   0.00      0.00    MNO 0  $ AXIS OF BRIDGE
  SPT  UM   0.00   '=#HEIGHT' MNO 0  $ LOWER MIDDLE
$
  SPT  OR '=+#WIDTHU'  '=+#WIDTHU*#INC'  MNO 0  $ UPPER RIGHT
  SPT  OL '=-#WIDTHU'  '=-#WIDTHU*#INC'  MNO 0  $ UPPER LEFT
  SPT  UR '=+#WIDTHL'  '=#HEIGHT'        MNO 0  $ LOWER RIGHT
  SPT  UL '=-#WIDTHL'  '=#HEIGHT'        MNO 0  $ LOWER LEFT
  SPT  UX      0.0       -0.22[m]          MNO 0  REFP UM  $ LOWER CENTER
  SPT  OXR  2[m]          0.0          MNO 0  REFP OM '=#ALFR' $ UPPER DECK RIGHT
  SPT  OXL  2[m]          0.0          MNO 0  REFP OM '=#ALFL' $ UPPER DECK LEFT
                                             $  REFP OM '=180+#ALF' MAX 8 CHARS !
$
POLY O
VERT 10     0    0 REFP UR
     11   0.9[m]    0 REFP OR +UR
     12  5[m]  0.6[m] REFP OM +OR
     13  7[m]  0.4[m] REFP OM +OR
     14  7[m]    0 REFP OM +OR
     15     0    0 REFP OM ~OR
     16  7[m]    0 REFP OM +OL
     17  7[m] -0.4[m] REFP OM +OL
     18  5[m] -0.6[m] REFP OM +OL
     19   0.9[m]    0 REFP OL +UL
     20     0    0 REFP UL
$
POLY O MNO 0
VERT A0      0  0.5[m] REFP OM
     A1R  2.75[m]  0.5[m] REFP OM +OR
     A2R  -0.75[m] -0.5[m] REFP UR
     A2L   0.75[m] -0.5[m] REFP UL
     A1L  2.75[m] -0.5[m] REFP OM +OL

END