+PROG TEMPLATE urs:1
kopf Variablendefinitionen und Parameter

!*!Label Anzahl Segmente
STO#L_Seg                  1[m]   $ Länge der Segmente in X-Richtung
STO#n_Seg                  8[-]   $ Anzahl der Segmente
STO#t_Fuge              0.10[m]   $ Breite der Fuge
STO#L_ges #L_Seg*#n_Seg+#t_Fuge*(#n_Seg-1) $ Gesamtlänge Träger

!*!Label Eingabeparameter Fahrbahn
STO#H_Kb #l_2+2*#l_1              $ Fahrbahnplattenbreite
STO#d_K                0.020[m]   $ Fahrbahnplattendicke Kragarm
STO#l_1                0.225[m]   $ Länge Kragarme

STO#b_f                0.050[m]
STO#d_f                0.020[m]   $ Fahrbahnplattendicke Mitte
STO#b_V2               0.080[m]
STO#d_V2               0.035[m]
STO#d_V1               0.060[m]

!*!Label Eingabeparameter Hohlkasten
STO#H_K                 0.30[m]   $ Hohlkasten Höhe
STO#l_2                 0.55[m]   $ Hohlkasten Breite oben
STO#H_KWeb_d            0.03[m]   $ Hohlkastenwand Dicke

!*!Label Eingabeparameter Längsträger
$ (aktuell: HEA 320)
STO#FT_b               0.300[m]   $ Flanschbreite oben
STO#FT_d              0.0155[m]   $ Flanschdicke oben
STO#WEB_h              0.310[m]   $ Steghöhe (H-2*tf)
STO#WEB_d              0.009[m]   $ Stegdicke
STO#FB_b               0.300[m]   $ Flanschbreite unten
STO#FB_d              0.0155[m]   $ Flanschdicke unten

!*!Label Eingabeparameter Auflagersteifen
STO#H_Steife          0.3255[m]   $ Auflagersteifenhöhe
STO#B_Steife           0.150[m]   $ Auflagersteifenbreite
STO#t_Steife           0.015[m]   $ Auflagersteifendicke

!*!Label Eingabeparameter Auflager
STO#Auf_X1             0.500[m]   $ 1. Auflagerposition in X-Richtung
STO#Auf_X2             6.000[m]   $ 2. Auflagerposition in X-Richtung
STO#Auf_L               0.15[m]   $ Auflagerlänge
STO#Auf_B               0.30[m]   $ Auflagerbreite
STO#Auf_d_w             0.01[m]   $ Auflager dicke weiche Schicht
STO#Auf_d_p             0.05[m]   $ Auflager dicke Platte

!*!Label Eingabeparameter Verschiebungssteuerung
STO#t_load              0.30[m]   $ Länge des Lastangriffs
STO#x_1                 4.90[m]   $ Abstand vom linken Rand zum mittleren Pressenangriffspunkt
STO#x_2                 8.20[m]   $ Abstand vom linken Rand zum Pressenangriffspunkt am Kragarmende

!*!Label Eingabeparameter Lasteinleitungsplatten
STO#B_load_platte       1.00[m]   $ Breite des Lastangriffs am Träger
STO#t_load_platte       0.01[m]   $ Dicke der Lasteinleitungsplatte
STO#B_load_gips         1.00[m]   $ Breite der Gipsschicht
STO#t_load_gips         0.01[m]   $ Dicke der Gipsschicht

!*!Label Eingabeparameter Vorspannung

$ 2 Spannglieder, beide Spannglieder jeweils 22 Litzen
$ Die Litzen sind von der Sorte St 1570/1770 und haben eine Fläche von jeweils A_p = 150mm^2.
$ Die Querschnittsfläche des Spanngliegs beträgt somit A=150*22 = 3300mm^2 (AZ in Code)
$ Das Metallhüllrohr hat einen Außendurchmesser von 102mm.
$ Die Vorspannung beider Spannglieder erfolgte simultan jeweils von einer Seite
$ (Spannkraftverlust aus KSR wurden durch Setzdehnmessungen in Feldmitte zu 2.4kN erfasst und hier vernachlässigt)

STO#ab_SpanL            0.15[m]   $ Linkes Spannglied  Y-Lage
STO#ab_SpanR            0.15[m]   $ Rechtes Spannglied Y-Lage

STO#sysps                  1[-]   $ Nummer des Spannverfahrens
STO#AP                   150      $ Fläche pro Litze in [mm^2]
STO#Litzen_Anz            22[-]   $ Anzahl der Litzen je Spannglied
STO#da_                  102[mm]  $ Hüllrohr 6-22, Typ I, Außendurchmesser in [mm]
STO#exz_spann             10[mm]  $ Exzentrizität im Hüllrohr von
STO#mue_spann            0.2[-]   $ Reibungsbeiwert μ =
STO#k_spann              0.3      $ ungewollte Umlenkwinkel in [deg/m] k =
STO#ss_spann               6[mm]  $ Schlupf am Spannanker
STO#ZV_spann            4208[kN]  $ Spannglied 1-5
STO#AZ #Litzen_Anz*#AP            $ Spannstahlfläche je Spannstrang (alle Litzen/Drähte) in [mm^2]


ENDE


+PROG AQUA urs:2
KOPF
ECHO VOLL

!*! Norm
$ Eurodode mit Deutschem Anhang, Katergorie des Brückenbaus (CAT 'B': Straßenbrücke)
NORM 'DIN' 'en199x-200x-bridge' COUN 49 CAT 'B' UNIT 5


!*! Material

$ *************************************************************************************************************************************

$ Eigenschaften des UHFB
$ Da die hohe Druckfestigkeit von 51.21MPa nicht zum geringen Emodul passt erstellt Sofistik eine falsche Arbeitslinie

BETO NR 1  ART C '120' EC 41000 GAM 40.10000 BEZ "UHFB"    $ GAM=Eigengewicht[kN/m3] - aus Laborbericht Rohdichte: 2490 kg/m3 * 9,81 m/s2 = 24,43 kN/m3 / Warum 40,1 ???

$ Gebrauchsarbeitslinie
ARBL EPS GEBR SIG 1[-] TYP  LIM                 $ mit TYP LIM werden die Spannungen außerhalb des definierten Bereiches Null  // SIG im Startsatz = Sicherheitsbeiwert
$ Zugfestigkeit
ARBL EPS  22.63000  SIG  0         TYP 'POL'
ARBL EPS  5.600000  SIG  9.440000  TYP 'POL'
ARBL EPS  0.150000  SIG  9.440000  TYP 'POL'
$ Druckfestigkeit
ARBL EPS  0         SIG  0         TYP 'POL'
ARBL EPS -2.050000  SIG -131.7000  TYP 'POL'
ARBL EPS -3.070000  SIG -131.7000  TYP 'POL'

$ Brucharbeitslinie
ARBL EPS BRUC SIG 1[-] TYP  LIM
$ Zugfestigkeit
ARBL EPS  22.63000  SIG  0         TYP 'POL'
ARBL EPS  5.600000  SIG  6.290000  TYP 'POL'
ARBL EPS  0.150000  SIG  6.290000  TYP 'POL'
$ Druckfestigkeit
ARBL EPS  0         SIG  0         TYP 'POL'
ARBL EPS -2.050000  SIG -83.96000  TYP 'POL'
ARBL EPS -3.070000  SIG -83.96000  TYP 'POL'

$ Extra Materialwerte - Kriechen und Schwinden
MEXT 1 EXP 'CURV' TYP EIGC VAL 7 0.45 14 0.670000 28 0.810000 100 0.990000 500 1.110000 2000 1.160000 5000 1.180000
MEXT 1 EXP 'CURV' TYP EIGC VAL 107 0 500 0.800000 2000 1 5000 1.400000
MEXT 1 EXP 'CURV' TYP EIGC VAL 500 0 2000 0.600000 5000 1.100000
MEXT 1 EXP 'CURV' TYP EIGS VAL 7 -2.60000E-04 10 -3.10000E-04 28 -4.30000E-04 180 -5.80000E-04 800 -6.40000E-04 2000 -6.60000E-04

$ *************************************************************************************************************************************

$ Bewehrung
STAH NR 2  B '500B' BEZ "=B 500 B (EN 1992)"
ARBL EPS GEBR SIG  1.150000[-]
ARBL EPS BRUC SIG -1.150000[-] TYP EXT
ARBL EPS RECH SIG -1.300000[-] TYP EXT
HMAT 2 TYP FOUR NSP 0 A 1

$ *************************************************************************************************************************************

$STAH NR 3 ART S GUET 235 FY 235 FT 360 ES 210000 BEZ 'S235 (t<=40mm)' TMAX 40
STAH NR 3 ART S GUET 355 FY 335 FT 470 ES 210000 BEZ 'S355 (40<t<80mm)' TMAX 80

$ *************************************************************************************************************************************

$ Weiche Zwischenschicht zwischen Lasteinleitungsplatte und Träger
let#emod_weich 10000 $[N/mm^2]   $ Definition des E-Moduls der weichen Zwischenschicht auf Druckbeanspruchung

STAH NR 4 ART S 355 ES #emod_weich GAM 0 SCM 1
ARBL GEBR 1.00
ARBL  EPS                    SIG      TYP
      1000000                0.0001   POL
      2000                   0.0001   POL
      0                      0        POL
     -300*1000/#emod_weich  -300      POL
     -40                    -300      POL

$ *************************************************************************************************************************************

$ Spannstahl 1570/1770
STAH NR 5 PST 1570S

$ *************************************************************************************************************************************

$ Füll-Beton
BETO NR 6  C '30' TYPR B BEZ "=C 30/37 (EN 1992)"
ARBL EPS GEBR SIG  1.500000[-] TYP  LIM
ARBL EPS BRUC SIG  1.500000[-]
ARBL EPS RECH SIG -1.300000[-]
HMAT 1 TYP FOUR NSP 0.030000 A 1



$ *************************************************************************************************************************************
$ *************************************************************************************************************************************


!*! Arbeitslinie der Auflagerfeder
$ Auch in der Arbeitslinie der Auflagerfedern wird bei Abheben des Trägers eine Abtragung von Zugkräften ausgeschlossen:

SMAT NR 101 MTYP HYPE           $ LTYP STD wegen SARB TYP=P
SARB    U           F  NR=101 TYP=P
#define worklaw
        $ mm        kN
       -1.0        -1100       ! Druckbereich
       -0.5        -1100/2
        0.0         0.0        !-------------
        1           0.00001
        200         0.00001    ! Zugbereich
#enddef
#include worklaw


!*! Arbeitslinie der Lastfeder
$ Ausfall auf Zug

SMAT NR 102 MTYP HYPE
SARB   U            F  NR=102 TYP=P
#define worklaw
       $ mm         kN
      -200         -0.0001     ! Druckbereich
      -1           -0.0001
       0.0          0.0        !-------------
       0.5          9e5/2
       1            9e5        ! Zugbereich
#enddef
#include worklaw



ENDE


!#!Kapitel  Definition Strukturpunkte / Strukturlinien / Strukturflächen / Gruppennummern

PROG SOFIMSHC urs:3
KOPF
UNIT 5
SYST RAUM GDIV 10000 GDIR POSZ      $ RAUM = 3D; GDIV=Gruppendivisior (1000); GDIR=Richtung des Eigengewichts in Z-Richtung

STEU TOPO 0                         $ Aktiviert die Topologische Analyse des Modells - Verschneidung aller Elemente - mechanisch zusammenhängendes Modell
STEU TOLG WERT  0.001[m]            $ Toleranzgrenze für die Verschneidung
STEU MESH 1                         $ Start der Netzgenerierung
STEU HMIN WERT  0.25[m]             $ Globale Netzdichte
STEU FEIN WERT -0.325               $ Verfeinerung an Strukturknoten
STEU PROG WERT  1.238               $ Steuert die Zunahme der Elementkantenlänge bei lokalen Verfeinerungen zwischen zwei benachbarten Elementen
STEU EFAK WERT  1.3986              $ Steuert die Netzdichte entlang von kurzen Strukturkanten
STEU DELN 0

!*! Definition Knotennummern

LET#knt1 4000   $ Knoten FB
LET#lin1 4000   $ Linien FB
LET#fla1 4000   $ Flächen FB

LET#knt2 200   $ Knoten HK L
LET#lin2 200   $ Linien HK L
LET#fla2 200   $ Flächen HK L

LET#knt3 300   $ Knoten HK R
LET#lin3 300   $ Linien HK R
LET#fla3 300   $ Flächen HK R

LET#knt4 400   $ Knoten BP
LET#lin4 400   $ Linien BP
LET#fla4 400   $ Flächen BP

LET#knt5 500   $ Knoten LT FL O
LET#lin5 500   $ Linien LT FL O
LET#fla5 500   $ Flächen LT FL O

LET#knt6 600   $ Knoten LT Steg
LET#lin6 600   $ Linien LT Steg
LET#fla6 600   $ Flächen LT Steg

LET#knt7 700   $ Knoten LT FL U
LET#lin7 700   $ Linien LT FL U
LET#fla7 700   $ Flächen LT FL U

LET#knt8 800   $ Knoten Auflager Rand
LET#lin8 800   $ Linien Auflager Rand
LET#fla8 800   $ Flächen Auflager Rand

LET#knt9 900   $ Knoten Auflager Mitte
LET#lin9 900   $ Linien Auflager Mitte
LET#fla9 900   $ Flächen Auflager Mitte


$ *************************************************************************************************************************
$ *************************************************************************************************************************

!+!Kapitel Erzeugung des Systems

!*! Erzeugung der Platte

$ Knoten FB
LET#n100 0
LOOP #n_Seg+1

    $ Hilfsgrößen
    LET#dYdZ (#H_K+#FT_d/2)/(#l_2/2-#FT_b/2)
    LET#b_V1 (#dYdZ*(#d_V1-#d_f))
    LET#b_V0 (#l_2/2-#H_KWeb_d-#b_V1-#b_V2-#b_f)

    $ Y-Koordinaten der 10 Punkte
    LET#Y0  -#l_2/2-#l_1
    LET#Y1  -#l_2/2+#H_KWeb_d
    LET#Y2  -#l_2/2+#H_KWeb_d+#b_V0
    LET#Y3  -#l_2/2+#H_KWeb_d+#b_V0+#b_V1
    LET#Y4  -#l_2/2+#H_KWeb_d+#b_V0+#b_V1+#b_V2
    LET#Y5   #l_2/2-#H_KWeb_d-#b_V0-#b_V1-#b_V2
    LET#Y6   #l_2/2-#H_KWeb_d-#b_V0-#b_V1
    LET#Y7   #l_2/2-#H_KWeb_d-#b_V0
    LET#Y8   #l_2/2-#H_KWeb_d
    LET#Y9   #l_2/2+#l_1

    $ X-Koordinaten mit Fugenberücksichtigung
    LET#X_FA #L_Seg*#n100+(#n100-1)*#t_Fuge    $ Fugenanfang
    LET#X_FE #L_Seg*#n100+#n100*#t_Fuge        $ Fugenende

    IF #n100==0

        SPT NR #knt1+0  X 0  Y #Y0  Z 0
        SPT NR #knt1+1  X 0  Y #Y1  Z 0
        SPT NR #knt1+2  X 0  Y #Y2  Z 0
        SPT NR #knt1+3  X 0  Y #Y3  Z 0
        SPT NR #knt1+4  X 0  Y #Y4  Z 0
        SPT NR #knt1+5  X 0  Y #Y5  Z 0
        SPT NR #knt1+6  X 0  Y #Y6  Z 0
        SPT NR #knt1+7  X 0  Y #Y7  Z 0
        SPT NR #knt1+8  X 0  Y #Y8  Z 0
        SPT NR #knt1+9  X 0  Y #Y9  Z 0
        LET#n100 #n100+1

    ELSE

        $ Fugenanfang
        SPT NR #knt1+#n100*20-10+0  X #X_FA  Y #Y0  Z 0
        SPT NR #knt1+#n100*20-10+1  X #X_FA  Y #Y1  Z 0
        SPT NR #knt1+#n100*20-10+2  X #X_FA  Y #Y2  Z 0
        SPT NR #knt1+#n100*20-10+3  X #X_FA  Y #Y3  Z 0
        SPT NR #knt1+#n100*20-10+4  X #X_FA  Y #Y4  Z 0
        SPT NR #knt1+#n100*20-10+5  X #X_FA  Y #Y5  Z 0
        SPT NR #knt1+#n100*20-10+6  X #X_FA  Y #Y6  Z 0
        SPT NR #knt1+#n100*20-10+7  X #X_FA  Y #Y7  Z 0
        SPT NR #knt1+#n100*20-10+8  X #X_FA  Y #Y8  Z 0
        SPT NR #knt1+#n100*20-10+9  X #X_FA  Y #Y9  Z 0

        $ Fugenende: nur wenn nicht letzter Querschnitt
        IF #n100<#n_Seg
        SPT NR #knt1+#n100*20+0  X #X_FE  Y #Y0  Z 0
        SPT NR #knt1+#n100*20+1  X #X_FE  Y #Y1  Z 0
        SPT NR #knt1+#n100*20+2  X #X_FE  Y #Y2  Z 0
        SPT NR #knt1+#n100*20+3  X #X_FE  Y #Y3  Z 0
        SPT NR #knt1+#n100*20+4  X #X_FE  Y #Y4  Z 0
        SPT NR #knt1+#n100*20+5  X #X_FE  Y #Y5  Z 0
        SPT NR #knt1+#n100*20+6  X #X_FE  Y #Y6  Z 0
        SPT NR #knt1+#n100*20+7  X #X_FE  Y #Y7  Z 0
        SPT NR #knt1+#n100*20+8  X #X_FE  Y #Y8  Z 0
        SPT NR #knt1+#n100*20+9  X #X_FE  Y #Y9  Z 0
        ENDIF

        LET#n100 #n100+1
    ENDIF

ENDLOOP


$ Linien FB
LET#n100 0
LOOP #n_Seg+1

    $ --- Knotenoffset Fugenanfang (oder erster Querschnitt) ---
    IF #n100==0
        LET#knt_off #knt1
    ELSE
        LET#knt_off #knt1+#n100*20-10
    ENDIF

    $ Querlinien Fugenanfang: 9 Linien
    $ Merke Startnummer der Fugenanfang-Querlinien für spätere Kopplung
    LET#lin_fuge_A #lin1

    LET#j 0
    LOOP 9
        SLN NR #lin1   NPA #knt_off+#j   NPE #knt_off+#j+1
        LET#lin1 #lin1+1
        LET#j #j+1
    ENDLOOP

    $ --- Fugenende Querlinien + Kopplung (nur wenn Fuge existiert) ---
    IF #n100>=1
        IF #n100<#n_Seg
            LET#knt_off2 #knt1+#n100*20    $ Fugenende

            $ Querlinien Fugenende: 9 Linien + direkt Feder koppeln
            LET#j 0
            LOOP 9
                SLN NR #lin1   NPA #knt_off2+#j   NPE #knt_off2+#j+1
                SLNS REFT >SLN #lin_fuge_A+#j CA 15000 $MNR 101
                SLNS REFT >SLN #lin_fuge_A+#j CA 15000 KR LOCZ $MNR 101 KR LOCZ
                LET#lin1 #lin1+1
                LET#j #j+1
            ENDLOOP

            $ Längslinien: Fugenende → nächster Fugenanfang
            LET#knt_next #knt1+(#n100+1)*20-10
            LET#j 0
            LOOP 10
                SLN NR #lin1   NPA #knt_off2+#j   NPE #knt_next+#j
                LET#lin1 #lin1+1
                LET#j #j+1
            ENDLOOP
        ENDIF
    ENDIF

    $ --- Längslinien erstes Segment: knt1 → erste Fugenanfang ---
    IF #n100==0
        LET#knt_next #knt1+1*20-10
        LET#j 0
        LOOP 10
            SLN NR #lin1   NPA #knt1+#j   NPE #knt_next+#j
            LET#lin1 #lin1+1
            LET#j #j+1
        ENDLOOP
    ENDIF

    LET#n100 #n100+1
ENDLOOP



$ Flächen FB
LET#n100 0
LET#lin1 4000
LOOP #n_Seg

$ Fläche 0: konstant Fb_d
    SAR NR #fla1+#n100*9+0 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T #d_K CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte Kragarm links"
    SARB OUT NL #lin1+#n100*28+0
    SARB OUT NL #lin1+#n100*28+10
    SARB OUT NL #lin1+#n100*28+19
    SARB OUT NL #lin1+#n100*28+9

$ Fläche 1: A=Fb_d, B=Fb_ta
    SAR NR #fla1+#n100*9+1 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+1
    SARB OUT NL #lin1+#n100*28+11   T #d_V1
    SARB OUT NL #lin1+#n100*28+20
    SARB OUT NL #lin1+#n100*28+10   T #d_K

$ Fläche 2: A=Fb_ta, B=Fb_ti
    SAR NR #fla1+#n100*9+2 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+2
    SARB OUT NL #lin1+#n100*28+12   T #d_V1
    SARB OUT NL #lin1+#n100*28+21
    SARB OUT NL #lin1+#n100*28+11   T #d_V1

$ Fläche 3: A=Fb_ti, B=Fb_d
    SAR NR #fla1+#n100*9+3 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+3
    SARB OUT NL #lin1+#n100*28+13   T #d_V2
    SARB OUT NL #lin1+#n100*28+22
    SARB OUT NL #lin1+#n100*28+12   T #d_V1

$ Fläche 4: konstant Fb_d
    SAR NR #fla1+#n100*9+4 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T #d_f CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte Mitte"
    SARB OUT NL #lin1+#n100*28+4
    SARB OUT NL #lin1+#n100*28+14
    SARB OUT NL #lin1+#n100*28+23
    SARB OUT NL #lin1+#n100*28+13

$ Fläche 5: A=Fb_d, B=Fb_ti
    SAR NR #fla1+#n100*9+5 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+5
    SARB OUT NL #lin1+#n100*28+15   T #d_V1
    SARB OUT NL #lin1+#n100*28+24
    SARB OUT NL #lin1+#n100*28+14   T #d_V2

$ Fläche 6: A=Fb_ti, B=Fb_ta
    SAR NR #fla1+#n100*9+6 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+6
    SARB OUT NL #lin1+#n100*28+16   T #d_V1
    SARB OUT NL #lin1+#n100*28+25
    SARB OUT NL #lin1+#n100*28+15   T #d_V1

$ Fläche 7: A=Fb_ta, B=Fb_d
    SAR NR #fla1+#n100*9+7 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T 0 CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte"
    SARB OUT NL #lin1+#n100*28+7
    SARB OUT NL #lin1+#n100*28+17   T #d_K
    SARB OUT NL #lin1+#n100*28+26
    SARB OUT NL #lin1+#n100*28+16   T #d_V1

$ Fläche 8: konstant Fb_d
    SAR NR #fla1+#n100*9+8 GRP 10 MNR 1 NX 0 0 -1 NRA 7 QREF UNTE DRX 1 0 0 T #d_K CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Fahrbahnplatte Kragarm rechts"
    SARB OUT NL #lin1+#n100*28+8
    SARB OUT NL #lin1+#n100*28+18
    SARB OUT NL #lin1+#n100*28+27
    SARB OUT NL #lin1+#n100*28+17

    LET#n100 #n100+1
ENDLOOP



!*! Erzeugung der Hohlkastenwand Links

$ Knoten HK Wand Links
LET#n200 0
LOOP #n_Seg+1

    IF #n200==0
    SPT NR #knt2+0   X 0    Y -#l_2/2               Z 0              $ HK Knoten links außen
    SPT NR #knt2+1   X 0    Y -#l_2/2+#H_KWeb_d     Z 0              $ HK Knoten links innen
    SPT NR #knt2+2   X 0    Y -#l_2/2+#H_KWeb_d/2   Z #d_K           $ HK Knoten links mitte
    SPT NR #knt2+3   X 0    Y -#FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten links unten
    LET#n200 #n200+1

    ELSE

    $ X-Koordinaten mit Fugenberücksichtigung
    LET#X_FA #L_Seg*#n200+(#n200-1)*#t_Fuge    $ Fugenanfang
    LET#X_FE #L_Seg*#n200+#n200*#t_Fuge        $ Fugenende

    $ Fugenanfang: immer
    SPT NR #knt2+#n200*8-4   X #X_FA   Y -#l_2/2               Z 0              $ HK Knoten links außen
    SPT NR #knt2+#n200*8-3   X #X_FA   Y -#l_2/2+#H_KWeb_d     Z 0              $ HK Knoten links innen
    SPT NR #knt2+#n200*8-2   X #X_FA   Y -#l_2/2+#H_KWeb_d/2   Z #d_K           $ HK Knoten links mitte
    SPT NR #knt2+#n200*8-1   X #X_FA   Y -#FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten links unten

    $ Fugenende: nur wenn nicht letzter Querschnitt
    IF #n200<#n_Seg
    SPT NR #knt2+#n200*8+0   X #X_FE   Y -#l_2/2               Z 0              $ HK Knoten links außen
    SPT NR #knt2+#n200*8+1   X #X_FE   Y -#l_2/2+#H_KWeb_d     Z 0              $ HK Knoten links innen
    SPT NR #knt2+#n200*8+2   X #X_FE   Y -#l_2/2+#H_KWeb_d/2   Z #d_K           $ HK Knoten links mitte
    SPT NR #knt2+#n200*8+3   X #X_FE   Y -#FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten links unten
    ENDIF

    LET#n200 #n200+1
    ENDIF

ENDLOOP


$ Linien HK L
LET#n200 0
LOOP #n_Seg

    SLN NR #lin2+#n200*6      NPA #knt2+#n200*8+0   NPE #knt2+#n200*8+4  GRP 200
    SLN NR #lin2+#n200*6+1    NPA #knt2+#n200*8+1   NPE #knt2+#n200*8+5  GRP 200
    SLN NR #lin2+#n200*6+2    NPA #knt2+#n200*8+2   NPE #knt2+#n200*8+6  GRP 200
    SLNS REFT >SLN #lin2+#n200*6   FIX F                                           $ fixe Kopplung Hohlkastenwand an Fahrbahnplatte links
    SLNS REFT >SLN #lin2+#n200*6+1 FIX F                                           $ fixe Kopplung Hohlkastenwand an Fahrbahnplatte rechts
    SLN NR #lin2+#n200*6+3    NPA #knt2+#n200*8+2   NPE #knt2+#n200*8+3  GRP 200
    SLN NR #lin2+#n200*6+4    NPA #knt2+#n200*8+3   NPE #knt2+#n200*8+7  GRP 200
    SLN NR #lin2+#n200*6+5    NPA #knt2+#n200*8+7   NPE #knt2+#n200*8+6  GRP 200

    IF (#n200 >=1)
    SLN -(#lin2+#n200*6+3)                                               GRP 200
    SLNS REFT >SLN #lin2+(#n200-1)*6+5 CA 200000
    SLNS REFT >SLN #lin2+(#n200-1)*6+5 CA 200000 KR LOCZ
    ENDIF

    LET#n200 #n200+1

ENDLOOP


$ Fläche HK L
LET#n200 0
LOOP #n_Seg

    SAR NR #fla2+#n200 GRP 20 MNR 1 NX 0 0 -1 NRA 7 DRX 1 0 0 T #H_KWeb_d CB 0 CT 0 MCTL REGM H1 0.20 BEZ "HK-Wand links"

    SARB OUT NL #lin2+#n200*6+2
    SARB OUT NL #lin2+#n200*6+3
    SARB OUT NL #lin2+#n200*6+4
    SARB OUT NL #lin2+#n200*6+5

    LET#n200 #n200+1

ENDLOOP


!*! Erzeugung der Hohlkastenwand Rechts

$ Knoten HK Wand Rechts
LET#n300 0
LOOP #n_Seg+1

    IF #n300==0
    SPT NR #knt3+0   X 0   Y  #l_2/2               Z 0              $ HK Knoten rechts außen
    SPT NR #knt3+1   X 0   Y  #l_2/2-#H_KWeb_d     Z 0              $ HK Knoten rechts innen
    SPT NR #knt3+2   X 0   Y  #l_2/2-#H_KWeb_d/2   Z #d_K           $ HK Knoten rechts mitte
    SPT NR #knt3+3   X 0   Y  #FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten rechts unten
    LET#n300 #n300+1

    ELSE

    $ X-Koordinaten mit Fugenberücksichtigung
    LET#X_FA #L_Seg*#n300+(#n300-1)*#t_Fuge    $ Fugenanfang
    LET#X_FE #L_Seg*#n300+#n300*#t_Fuge        $ Fugenende

    $ Fugenanfang: immer
    SPT NR #knt3+#n300*8-4   X #X_FA   Y  #l_2/2               Z 0              $ HK Knoten rechts außen
    SPT NR #knt3+#n300*8-3   X #X_FA   Y  #l_2/2-#H_KWeb_d     Z 0              $ HK Knoten rechts innen
    SPT NR #knt3+#n300*8-2   X #X_FA   Y  #l_2/2-#H_KWeb_d/2   Z #d_K           $ HK Knoten rechts mitte
    SPT NR #knt3+#n300*8-1   X #X_FA   Y  #FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten rechts unten

    $ Fugenende: nur wenn nicht letzter Querschnitt
    IF #n300<#n_Seg
    SPT NR #knt3+#n300*8+0   X #X_FE   Y  #l_2/2               Z 0              $ HK Knoten rechts außen
    SPT NR #knt3+#n300*8+1   X #X_FE   Y  #l_2/2-#H_KWeb_d     Z 0              $ HK Knoten rechts innen
    SPT NR #knt3+#n300*8+2   X #X_FE   Y  #l_2/2-#H_KWeb_d/2   Z #d_K           $ HK Knoten rechts mitte
    SPT NR #knt3+#n300*8+3   X #X_FE   Y  #FT_b/2              Z #H_K+#FT_d/2   $ HK Knoten rechts unten
    ENDIF

    LET#n300 #n300+1
    ENDIF

ENDLOOP


$ Linien HK R
LET#n300 0
LOOP #n_Seg

    SLN NR #lin3+#n300*6      NPA #knt3+#n300*8+0   NPE #knt3+#n300*8+4  GRP 300
    SLN NR #lin3+#n300*6+1    NPA #knt3+#n300*8+1   NPE #knt3+#n300*8+5  GRP 300
    SLN NR #lin3+#n300*6+2    NPA #knt3+#n300*8+2   NPE #knt3+#n300*8+6  GRP 300
    SLNS REFT >SLN #lin3+#n300*6   FIX F                                 $ fixe Kopplung Hohlkastenwand an Fahrbahnplatte  links
    SLNS REFT >SLN #lin3+#n300*6+1 FIX F                                 $ fixe Kopplung Hohlkastenwand an Fahrbahnplatte  rechts
    SLN NR #lin3+#n300*6+3    NPA #knt3+#n300*8+2   NPE #knt3+#n300*8+3  GRP 300
    SLN NR #lin3+#n300*6+4    NPA #knt3+#n300*8+3   NPE #knt3+#n300*8+7  GRP 300
    SLN NR #lin3+#n300*6+5    NPA #knt3+#n300*8+7   NPE #knt3+#n300*8+6  GRP 300

    IF (#n300 >=1)
    SLN -(#lin3+#n300*6+3)                                               GRP 300
    SLNS REFT >SLN #lin3+(#n300-1)*6+5 CA 200000
    SLNS REFT >SLN #lin3+(#n300-1)*6+5 CA 200000 KR LOCZ
    ENDIF

    LET#n300 #n300+1

ENDLOOP



$ Fläche HK R
LET#n300 0
LOOP #n_Seg

    SAR NR #fla3+#n300 GRP 30 MNR 1 NX 0 0 -1 NRA 7 DRX 1 0 0 T #H_KWeb_d CB 0 CT 0 MCTL REGM H1 0.20 BEZ "HK-Wand rechts"

    SARB OUT NL #lin3+#n300*6+2
    SARB OUT NL #lin3+#n300*6+3
    SARB OUT NL #lin3+#n300*6+4
    SARB OUT NL #lin3+#n300*6+5

    LET#n300 #n300+1

ENDLOOP




!*! Erzeugung des Längsträgers (Flansch oben)

$ Linien
LET#n500 0
LOOP #n_Seg*2-1

    SLN NR #lin5+#n500*4      NPA #knt2+#n500*4+3   NPE #knt3+#n500*4+3
    SLN NR #lin5+#n500*4+1    NPA #knt3+#n500*4+3   NPE #knt3+#n500*4+7
    SLN NR #lin5+#n500*4+2    NPA #knt3+#n500*4+7   NPE #knt2+#n500*4+7
    SLN NR #lin5+#n500*4+3    NPA #knt2+#n500*4+7   NPE #knt2+#n500*4+3

    LET#n500 #n500+1

ENDLOOP


$ Fläche
LET#n500 0
LOOP #n_Seg*2-1

    SAR NR #fla5+#n500 GRP 50 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #FT_d CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Flansch oben"

    SARB OUT NL #lin5+#n500*4+0
    SARB OUT NL #lin5+#n500*4+1
    SARB OUT NL #lin5+#n500*4+2
    SARB OUT NL #lin5+#n500*4+3

    LET#n500 #n500+1

ENDLOOP


!*! Erzeugung des Längsträgers (Steg)

$ Knoten
LET#n600 0
LOOP #n_Seg+1

    IF #n600==0
    SPT NR #knt6+0   X 0   Y 0   Z #H_K+#FT_d/2                   $ Träger Steg Oben
    SPT NR #knt6+1   X 0   Y 0   Z #H_K+#FT_d+#WEB_h+#FB_d/2      $ Träger Steg Unten
    LET#n600 #n600+1

    ELSE

    LET#X_FA #L_Seg*#n600+(#n600-1)*#t_Fuge    $ Fugenanfang
    LET#X_FE #L_Seg*#n600+#n600*#t_Fuge        $ Fugenende

    SPT NR #knt6+#n600*4-2   X #X_FA   Y 0   Z #H_K+#FT_d/2                   $ Träger Steg Oben
    SPT NR #knt6+#n600*4-1   X #X_FA   Y 0   Z #H_K+#FT_d+#WEB_h+#FB_d/2      $ Träger Steg Unten

    IF #n600<#n_Seg
    SPT NR #knt6+#n600*4     X #X_FE   Y 0   Z #H_K+#FT_d/2                   $ Träger Steg Oben
    SPT NR #knt6+#n600*4+1   X #X_FE   Y 0   Z #H_K+#FT_d+#WEB_h+#FB_d/2      $ Träger Steg Unten
    ENDIF

    LET#n600 #n600+1
    ENDIF

ENDLOOP


$ Linien
LET#n600 0
LOOP #n_Seg*2-1

    SLN NR #lin6+#n600*4      NPA #knt6+#n600*2     NPE #knt6+#n600*2+2
    SLN NR #lin6+#n600*4+1    NPA #knt6+#n600*2+1   NPE #knt6+#n600*2+3
    SLN NR #lin6+#n600*4+2    NPA #knt6+#n600*2     NPE #knt6+#n600*2+1
    SLN NR #lin6+#n600*4+3    NPA #knt6+#n600*2+2   NPE #knt6+#n600*2+3

    LET#n600 #n600+1

ENDLOOP

$ Fläche
LET#n600 0
LOOP #n_Seg*2-1

    SAR NR #fla6+#n600 GRP 60 MNR 3  NX 0 0 -1 NRA 7 DRX 1 0 0 T #WEB_d  CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Träger Steg"

    SARB OUT NL #lin6+#n600*4
    SARB OUT NL #lin6+#n600*4+1
    SARB OUT NL #lin6+#n600*4+2
    SARB OUT NL #lin6+#n600*4+3

    LET#n600 #n600+1

ENDLOOP


!*! Erzeugung des Längsträgers (Flansch unten)

                    $ Knoten
LET#n700 0
LOOP #n_Seg+1

    IF #n700==0
    SPT NR #knt7+0   X 0   Y -#FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2
    SPT NR #knt7+1   X 0   Y  #FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2
    LET#n700 #n700+1

    ELSE

    LET#X_FA #L_Seg*#n700+(#n700-1)*#t_Fuge    $ Fugenanfang
    LET#X_FE #L_Seg*#n700+#n700*#t_Fuge        $ Fugenende

    $ Fugenanfang: immer
    SPT NR #knt7+#n700*4-2   X #X_FA   Y -#FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2
    SPT NR #knt7+#n700*4-1   X #X_FA   Y  #FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2

    $ Fugenende: nur wenn nicht letzter Querschnitt
    IF #n700<#n_Seg
    SPT NR #knt7+#n700*4     X #X_FE   Y -#FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2
    SPT NR #knt7+#n700*4+1   X #X_FE   Y  #FB_b/2   Z #H_K+#FT_d+#WEB_h+#FB_d/2
    ENDIF

    LET#n700 #n700+1
    ENDIF

ENDLOOP



$ Linien
LET#n700 0
LOOP #n_Seg*2-1

    SLN NR #lin7+#n700*4      NPA #knt7+#n700*2     NPE #knt7+#n700*2+1
    SLN NR #lin7+#n700*4+1    NPA #knt7+#n700*2+1   NPE #knt7+#n700*2+3
    SLN NR #lin7+#n700*4+2    NPA #knt7+#n700*2+3   NPE #knt7+#n700*2+2
    SLN NR #lin7+#n700*4+3    NPA #knt7+#n700*2+2   NPE #knt7+#n700*2

    LET#n700 #n700+1

ENDLOOP

$ Fläche
LET#n700 0
LOOP #n_Seg*2-1

    SAR NR #fla7+#n700 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #FB_d  CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Träger-FL unten"

    SARB OUT NL #lin7+#n700*4
    SARB OUT NL #lin7+#n700*4+1
    SARB OUT NL #lin7+#n700*4+2
    SARB OUT NL #lin7+#n700*4+3

    LET#n700 #n700+1

ENDLOOP


!*! Auflager-Steife "Mitte" - Versuch 1
SPT 2100 X #Auf_X2   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2101 X #Auf_X2   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2102 X #Auf_X2   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2103 X #Auf_X2   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2104 X #Auf_X2   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2105 X #Auf_X2   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife

SLN 2100,2101,2102      NPA 2100,2102,2104      NPE 2101,2103,2105
SLN 2103,2104,2105,2106 NPA 2105,2101,2104,2100 NPE 2101,2103,2100,2102

SAR NR 2100 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Mitte rechts V1"
SARB OUT NL 2100,2104,2101,2106

SAR NR 2101 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Mitte links V1"
SARB OUT NL 2100,2105,2102,2103


!*! Auflager-Steife "Rand" - Versuch 1
SPT 2106 X #Auf_X1   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2107 X #Auf_X1   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2108 X #Auf_X1   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2109 X #Auf_X1   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2110 X #Auf_X1   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2111 X #Auf_X1   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife

SLN 2107,2108,2109      NPA 2106,2108,2110      NPE 2107,2109,2111
SLN 2110,2111,2112,2113 NPA 2111,2107,2110,2106 NPE 2107,2109,2106,2108

SAR NR 2102 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Rand rechts V1"
SARB OUT NL 2107,2111,2108,2113

SAR NR 2103 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Rand links V1"
SARB OUT NL 2107,2112,2109,2110


!*! Auflager-Steife "Mitte" - Versuch 2 (gespiegelt: X = L_ges - Auf_X1)
SPT 2120 X #L_ges-#Auf_X1   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2121 X #L_ges-#Auf_X1   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2122 X #L_ges-#Auf_X1   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2123 X #L_ges-#Auf_X1   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2124 X #L_ges-#Auf_X1   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2125 X #L_ges-#Auf_X1   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife

SLN 2120,2121,2122      NPA 2120,2122,2124      NPE 2121,2123,2125
SLN 2123,2124,2125,2126 NPA 2125,2121,2124,2120 NPE 2121,2123,2120,2122

SAR NR 2104 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Mitte rechts V2"
SARB OUT NL 2120,2124,2121,2126

SAR NR 2105 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Mitte links V2"
SARB OUT NL 2120,2125,2122,2123


!*! Auflager-Steife "Rand" - Versuch 2 (gespiegelt: X = L_ges - Auf_X2)
SPT 2126 X #L_ges-#Auf_X2   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2127 X #L_ges-#Auf_X2   Y 0           Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2128 X #L_ges-#Auf_X2   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2129 X #L_ges-#Auf_X2   Y #B_Steife   Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife
SPT 2130 X #L_ges-#Auf_X2   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 2131 X #L_ges-#Auf_X2   Y -#B_Steife  Z #H_K+#FT_d+#WEB_h+#FB_d/2-#H_Steife

SLN 2127,2128,2129      NPA 2126,2128,2130      NPE 2127,2129,2131
SLN 2130,2131,2132,2133 NPA 2131,2127,2130,2126 NPE 2127,2129,2126,2128

SAR NR 2106 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Rand rechts V2"
SARB OUT NL 2127,2131,2128,2133

SAR NR 2107 GRP 70 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_Steife CB 0 CT 0 MCTL REGM H1 0.20 BEZ "Auflagersteife Rand links V2"
SARB OUT NL 2127,2132,2129,2130



!*! Erzeugung des Auflagers "Rand"

SPT 800 X #Auf_X1-#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 801 X #Auf_X1-#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 802 X #Auf_X1+#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 803 X #Auf_X1+#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2

SPT 804 X #Auf_X1-#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 805 X #Auf_X1-#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 806 X #Auf_X1+#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 807 X #Auf_X1+#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2

SPT 808 X #Auf_X1-#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 809 X #Auf_X1-#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 810 X #Auf_X1+#Auf_L/2  Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 811 X #Auf_X1+#Auf_L/2  Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2

SPT 812 X #Auf_X1           Y 0            Z #H_K+#FT_d+#WEB_h+#FB_d/2   FIX PYMX


SLN 800,801,802,803 NPA 800,801,802,803 NPE 801,802,803,800
SLN 804,805,806,807 NPA 804,805,806,807 NPE 805,806,807,804
SLN 808,809,810,811 NPA 808,809,810,811 NPE 809,810,811,808

SAR NR 800 GRP 80 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T 0         CB 0    CT 0 MCTL REGM H1 0.20 BEZ "Koppelfläche FL unten"
SARB OUT NL 800,801,802,803

SAR NR 801 GRP 81 MNR 4 NX 0 0 -1 NRA 7 DRX 1 0 0 T #Auf_d_w  CB 0    CT 0 MCTL REGM H1 0.20 BEZ "Auflager weiche Schicht"
SARB OUT NL 804,805,806,807

$ Gebettete Auflagerplatte
SAR NR 802 GRP 82 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #Auf_d_p  CB 6e8  CT 6e8 MCTL REGM H1 0.20 BEZ "Auflager Platte"
SARB OUT NL 808,809,810,811


$***********************************************************************************************************************************************

!*! Erzeugung des Auflagers "Mitte"

SPT 900 X #Auf_X2-#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 901 X #Auf_X2-#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 902 X #Auf_X2+#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2
SPT 903 X #Auf_X2+#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d/2

SPT 904 X #Auf_X2-#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 905 X #Auf_X2-#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 906 X #Auf_X2+#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2
SPT 907 X #Auf_X2+#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w/2

SPT 908 X #Auf_X2-#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 909 X #Auf_X2-#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 910 X #Auf_X2+#Auf_L/2   Y  #Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2
SPT 911 X #Auf_X2+#Auf_L/2   Y -#Auf_B/2    Z #H_K+#FT_d+#WEB_h+#FB_d+#Auf_d_w+#Auf_d_p/2

SPT 912 X #Auf_X2            Y 0            Z #H_K+#FT_d+#WEB_h+#FB_d/2 FIX PYMX

SLN 900,901,902,903 NPA 900,901,902,903 NPE 901,902,903,900
SLN 904,905,906,907 NPA 904,905,906,907 NPE 905,906,907,904
SLN 908,909,910,911 NPA 908,909,910,911 NPE 909,910,911,908

SAR NR 900 GRP 90 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T 0         CB 0    CT 0 MCTL REGM H1 1 BEZ "Koppelfläche FL unten"
SARB OUT NL 900,901,902,903

SAR NR 901 GRP 91 MNR 4 NX 0 0 -1 NRA 7 DRX 1 0 0 T #Auf_d_w  CB 0    CT 0 MCTL REGM H1 1 BEZ "Auflager weiche Schicht"
SARB OUT NL 904,905,906,907

SAR NR 902 GRP 92 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #Auf_d_p  CB 6e10 CT 6e10 MCTL REGM H1 1 BEZ "Auflager Platte "
SARB OUT NL 908,909,910,911



$ *************************************************************************************************************************

!*! Verschiebungssteuerung "FELD"

$ Pressen können maximal 800 kN aufbringen; Versuch wird weggesteurt gefahren!

$ Die Verschiebungssteuerung läuft über jeweils 5 Federn für jede der beiden Pressen.
$ Deshalb müssen zehn fixe Lager über den Rändern und den Mittelpunkten der Lasteinleitungsplatten modelliert werden.
$ Diesen gelagerten Punkte wird anschließend eine Verschiebung aufgezwungen, wodurch die steifen Federn auf die
$ Einleitungsplatten bzw. den Träger drücken und auch diesem diese Verschiebung aufzwingen.
$ Die Federnormalkräfte entsprechen der Pressenlast.


$ Presse FELD:

$ Die 5 gelagerten Punkte "oben":
SPT NR 2010 X #x_1-#t_load/2     Y 0                   Z -1.8       FIX MMZP
SPT NR 2011 X #x_1-#t_load/4     Y 0                   Z -1.8       FIX MMZP
SPT NR 2012 X #x_1               Y 0                   Z -1.8       FIX MMZP
SPT NR 2013 X #x_1+#t_load/4     Y 0                   Z -1.8       FIX MMZP
SPT NR 2014 X #x_1+#t_load/2     Y 0                   Z -1.8       FIX MMZP

$ x1
$ Punkte für Lastangriff Platte:
SPT NR 2020 X #x_1-#t_load/2     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2021 X #x_1-#t_load/4     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2022 X #x_1               Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2023 X #x_1+#t_load/4     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2024 X #x_1+#t_load/2     Y 0                   Z -#t_load_gips-#t_load_platte*1.5

$ Eckpunkte für Lastangriff Stahlplatte (ideal steif):
SPT NR 2025 X #x_1-#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2026 X #x_1-#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2027 X #x_1+#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 2028 X #x_1+#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5

$ Punkte Stahlplatte:
SPT NR 2030 X #x_1-#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 2031 X #x_1-#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 2032 X #x_1+#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 2033 X #x_1+#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte/2

$ Punkte Gipsschicht:
SPT NR 2040 X #x_1-#t_load/2     Y -#B_load_gips/2     Z -#t_load_gips/2
SPT NR 2041 X #x_1-#t_load/2     Y  #B_load_gips/2     Z -#t_load_gips/2
SPT NR 2042 X #x_1+#t_load/2     Y  #B_load_gips/2     Z -#t_load_gips/2
SPT NR 2043 X #x_1+#t_load/2     Y -#B_load_gips/2     Z -#t_load_gips/2

$ Punkte Kopplung auf Fahrbahn:
SPT NR 2050 X #x_1-#t_load/2     Y -#B_load_gips/2     Z 0
SPT NR 2051 X #x_1-#t_load/2     Y  #B_load_gips/2     Z 0
SPT NR 2052 X #x_1+#t_load/2     Y  #B_load_gips/2     Z 0
SPT NR 2053 X #x_1+#t_load/2     Y -#B_load_gips/2     Z 0

SLN 2000,2001,2002,2003 NPA 2025,2026,2027,2028 NPE 2026,2027,2028,2025
SLN 2004,2005,2006,2007 NPA 2030,2031,2032,2033 NPE 2031,2032,2033,2030
SLN 2008,2009,2010,2011 NPA 2040,2041,2042,2043 NPE 2041,2042,2043,2040
SLN 2012,2013,2014,2015 NPA 2050,2051,2052,2053 NPE 2051,2052,2053,2050

SAR NR 2000 GRP 200 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_platte CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Stahlplatte (ideal steif)"
SARB OUT NL 2000,2001,2002,2003

SAR NR 2001 GRP 201 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_platte CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Stahlplatte"
SARB OUT NL 2004,2005,2006,2007

SAR NR 2002 GRP 202 MNR 4 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_gips   CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Gipsschicht"
SARB OUT NL 2008,2009,2010,2011

SAR NR 2003 GRP 203 MNR 1 NX 0 0 -1 NRA 7 DRX 1 0 0 T #d_f          CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Fahrbahnplatte"
SARB OUT NL 2012,2013,2014,2015

$ Diese  Lager sind über steife Federn mit den Lasteinleitungspunkten verbunden:
SPT -2020;
SPTS NR 10 REF 2010 TYP CZZ  GRP 210 MNR 102 ar 0.5  $ cp 6e10/3

SPT -2021;
SPTS NR 11 REF 2011 TYP CZZ  GRP 210 MNR 102         $ cp 6e10 cq 1e5

SPT -2022;
SPTS NR 12 REF 2012 TYP CZZ  GRP 210 MNR 102         $ cp 6e10 cq 1e5

SPT -2023;
SPTS NR 13 REF 2013 TYP CZZ  GRP 210 MNR 102         $ cp 6e10 cq 1e5

SPT -2024;
SPTS NR 14 REF 2014 TYP CZZ  GRP 210 MNR 102 ar 0.5  $ cp 6e10/3

$ **************************************************************************************************************************************

!*! Verschiebungssteuerung "Kragarm"

$ Presse Kragarm:

$ Die 5 gelagerten Punkte "oben":
SPT NR 3010 X #x_2-#t_load/2     Y 0                   Z -1.8       FIX MMZP
SPT NR 3011 X #x_2-#t_load/4     Y 0                   Z -1.8       FIX MMZP
SPT NR 3012 X #x_2               Y 0                   Z -1.8       FIX MMZP
SPT NR 3013 X #x_2+#t_load/4     Y 0                   Z -1.8       FIX MMZP
SPT NR 3014 X #x_2+#t_load/2     Y 0                   Z -1.8       FIX MMZP

$ x1
$ Punkte für Lastangriff Platte:
SPT NR 3020 X #x_2-#t_load/2     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3021 X #x_2-#t_load/4     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3022 X #x_2               Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3023 X #x_2+#t_load/4     Y 0                   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3024 X #x_2+#t_load/2     Y 0                   Z -#t_load_gips-#t_load_platte*1.5

$ Eckpunkte für Lastangriff Stahlplatte (ideal steif):
SPT NR 3025 X #x_2-#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3026 X #x_2-#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3027 X #x_2+#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5
SPT NR 3028 X #x_2+#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte*1.5

$ Punkte Stahlplatte:
SPT NR 3030 X #x_2-#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 3031 X #x_2-#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 3032 X #x_2+#t_load/2     Y  #B_load_platte/2   Z -#t_load_gips-#t_load_platte/2
SPT NR 3033 X #x_2+#t_load/2     Y -#B_load_platte/2   Z -#t_load_gips-#t_load_platte/2

$ Punkte Gipsschicht:
SPT NR 3040 X #x_2-#t_load/2     Y -#B_load_gips/2     Z -#t_load_gips/2
SPT NR 3041 X #x_2-#t_load/2     Y  #B_load_gips/2     Z -#t_load_gips/2
SPT NR 3042 X #x_2+#t_load/2     Y  #B_load_gips/2     Z -#t_load_gips/2
SPT NR 3043 X #x_2+#t_load/2     Y -#B_load_gips/2     Z -#t_load_gips/2

$ Punkte Kopplung auf Fahrbahn:
SPT NR 3050 X #x_2-#t_load/2     Y -#B_load_gips/2     Z 0
SPT NR 3051 X #x_2-#t_load/2     Y  #B_load_gips/2     Z 0
SPT NR 3052 X #x_2+#t_load/2     Y  #B_load_gips/2     Z 0
SPT NR 3053 X #x_2+#t_load/2     Y -#B_load_gips/2     Z 0

SLN 3000,3001,3002,3003 NPA 3025,3026,3027,3028 NPE 3026,3027,3028,3025
SLN 3004,3005,3006,3007 NPA 3030,3031,3032,3033 NPE 3031,3032,3033,3030
SLN 3008,3009,3010,3011 NPA 3040,3041,3042,3043 NPE 3041,3042,3043,3040
SLN 3012,3013,3014,3015 NPA 3050,3051,3052,3053 NPE 3051,3052,3053,3050

SAR NR 3000 GRP 300 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_platte CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Stahlplatte (ideal steif)"
SARB OUT NL 3000,3001,3002,3003

SAR NR 3001 GRP 301 MNR 3 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_platte CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Stahlplatte"
SARB OUT NL 3004,3005,3006,3007

SAR NR 3002 GRP 302 MNR 4 NX 0 0 -1 NRA 7 DRX 1 0 0 T #t_load_gips   CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Gipsschicht"
SARB OUT NL 3008,3009,3010,3011

SAR NR 3003 GRP 303 MNR 1 NX 0 0 -1 NRA 7 DRX 1 0 0 T #d_f          CB 0 CT 0 MCTL REGM H1 0.25 BEZ "Fahrbahnplatte"
SARB OUT NL 3012,3013,3014,3015

$ Diese  Lager sind über steife Federn mit den Lasteinleitungspunkten verbunden:
SPT -3020;
SPTS NR 20 REF 3010 TYP CZZ  GRP 310 MNR 102 ar 0.5  $ cp 6e10/3

SPT -3021;
SPTS NR 21 REF 3011 TYP CZZ  GRP 310 MNR 102         $ cp 6e10 cq 1e5

SPT -3022;
SPTS NR 22 REF 3012 TYP CZZ  GRP 310 MNR 102         $ cp 6e10 cq 1e5

SPT -3023;
SPTS NR 23 REF 3013 TYP CZZ  GRP 310 MNR 102         $ cp 6e10 cq 1e5

SPT -3024;
SPTS NR 24 REF 3014 TYP CZZ  GRP 310 MNR 102 ar 0.5  $ cp 6e10/3


!*! Achsen für Vorspannung in Fahrbahnplatte

$Achse Spannglied links
GAX ID 'A1' TYPC ARC
GAXB X1 0 Y1 -#ab_SpanL  Z1 #d_V1/2   X2 #L_ges Y2 -#ab_SpanL  Z2 #d_V1/2

$Achse Spannglied rechts
GAX ID 'A2' TYPC ARC
GAXB X1 0 Y1  #ab_SpanR  Z1 #d_V1/2   X2 #L_ges Y2  #ab_SpanR  Z2 #d_V1/2

$Achse Mitte
GAX ID 'A0' TYPC ARC
GAXB X1 0 Y1  0          Z1 #d_V1/2   X2 #L_ges Y2  0          Z2 #d_V1/2


ENDE



$ Kopplung der der Auflagerschichten
+prog sofimsha urs:4
KOPF Kopplung der der Auflager- und Lastplatten-Schichten
SYST REST

$ regions 80,81,91,92 and 81,82,90,91 are coupled with spring elements (Auflager)
FEDE QGRP 80 81 CP 6e10 6e10
FEDE QGRP 81 82 CP 6e10 6e10
FEDE QGRP 90 91 CP 6e10 6e10
FEDE QGRP 91 92 CP 6e10 6e10

$ regions 200,201,202 and 201,202,203 are coupled with spring elements (Mitte)
FEDE QGRP 200 201 CP 6e10 6e10
FEDE QGRP 201 202 CP 6e10 6e10
FEDE QGRP 202 203 CP 6e10 6e10

$ regions 300,301,302 and 301,302,303 are coupled with spring elements (Kragarm)
FEDE QGRP 300 301 CP 6e10 6e10
FEDE QGRP 301 302 CP 6e10 6e10
FEDE QGRP 302 303 CP 6e10 6e10

ENDE