!#!KAPITEL Material and System generation
+PROG AQUA urs:1
HEAD
NORM 'NS' 'en199X-200X'

CONC 1    C    30  $ here unused, therefore material 9 is used for brics!
STEE 3 S  500

$ Here material LADE for cracked bric concrete  TCM    Triple_Crack_Model   see also example   bric_smeared_cracked_girder.dat
MATE  9 E 33000 MUE 0.2 TITL 'LADE C30 SLS fcm 38 fctk 2.03'
NMAT  9 'LADE' P1  4353041 P2 1.5 P3 2028 P6 0.2 $ P3=tensile strength
$     The yielding curve is plotted in ASE in the material output!
$     Parameter for other concrete strength see example Beispiel bric_concrete.dat
$     If you change P3 you also must adapt P1 to get the same uniaxial strength!
$     So best change P3 and look to the Ursula plot, then change P1 - and so on!

STEE  2    S   500  $ standard reinforcement steel 500
scit  5 D 36[mm]
scit  8 D 50[mm]
END

+PROG SOFIMSHA -R urs:3
HEAD Video Volume Meshing
CTRL NODE 50000 ; CTRL GTOL 0.020 $ 20 mm tolerance for nodes
UNIT 5 ; SYST SPAC GDIV 100000 GDIR NEGZ
NODE 1 X 0 0  2.00
NODE  NO  X     Z                       $================$
                                         129  1.900 2.00 $
                                         128  1.900 1.25 $
                                         127  1.700 1.25 $
                                         126  1.800 1.25 $=================$
                       115  2.300 1.20 ; 125  1.800 1.20 ; 135  1.300 1.20 $
     104  6.000 0.60 ; 114  2.300 1.00 ; 124  1.800 1.00 ; 134  1.300 1.00 $
     103  6.000 0.40 ; 113  2.300 0.60 ; 123  1.800 0.60 ; 133  1.300 0.50 $
     102  6.000 0.20 ; 112  2.300 0.30 ; 122  1.800 0.30 ; 132  1.500 0.25 $
     101  6.000 0    ; 111  2.300 0    ; 121  1.800 0    ; 131  1.500 0    $
$    ======================================================================$
sto#div 36  $ division in circular direction
$
loop#i0 #div    $ variable loops from 0-1-2-3...7   for #div=8
  let#i1 #i0+1  $ variable loops from 1-2-3-4...8   for #div=8
  TRAN NODE FROM 101 TO 199 DNO #i1*100 phiz #i1*360/#div
endloop

GRP 99 titl 'Test node coordinates'
loop#i0 #div
  let#i1 #i0+1
 $ spri NA #i1*100+1  dz 1 cp 1E6
 $ spri NA #i1*100+31 dz 1 cp 1E6
endloop

loop#i0 #div    $ variable loops from 0-1-2-3...7   for #div=8
  let#i1 #i0+1  $ variable loops from 1-2-3-4...8   for #div=8
  let#plane1 100*#i1            $ plane1 = hundred number of first node plane
  let#plane2 #plane1+100        $ plane2 = hundred number of    2. node plane
  if #i1==#div
         let#plane2 100         $ last bric uses nodeplane 800---100
  endif
  GRP 1 titl 'concrete'
  let#L1 #plane1 ; let#L2 #plane2  $ to have shorter characters
                                BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    M 5 N 2 K 1 MNO 9
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
   $
  let#L1 #plane1+10 ; let#L2 #plane2+10
                                BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    M 2 N 2 K 1 MNO 9
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
$
  let#L1 #plane1+20 ; let#L2 #plane2+20
                                BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
  let#L1 #L1+1 ; let#L2 #L2+1 ; BRIC N1 #L1+1  #L1+11  #L1+12  #L1+2  N5 #L2+1  #L2+11  #L2+12  #L2+2    ==
endloop

$ other elements
loop#i0 #div
  let#i1 #i0+1
  let#plane1 100*#i1            $ plane1 = hundred number of first node plane
  let#plane2 #plane1+100        $ plane2 = hundred number of    2. node plane
  if #i1==#div ; let#plane2 100 ; endif

  GRP 2 titl 'tower'
    QUAD N1 #plane1+28  #plane1+29  #plane2+29  #plane2+28   t 20[mm] M 2 N 1 MNO 3

  GRP 3 titl 'bolt plate'
    QUAD N1 #plane1+27  #plane1+26  #plane2+26  #plane2+27   t 50[mm] M 1 N 1 MNO 3
    QUAD N1 #plane1+26  #plane1+28  #plane2+28  #plane2+26   t 50[mm] M 1 N 1 MNO 3

  GRP 4 titl 'contact springs'
    SPRI NA #plane1+26  #plane1+25  cp 1E6 ct 1E5 CRAC 0

  if MOD(#i1,2)==0    $ only every second node plane:
    GRP 5 titl 'bolts'
      TRUS NA #plane1+26  #plane1+22 NCS 5
  endif

  GRP 7 titl 'bedding quads'
    let#L1 #plane1 ; let#L2 #plane2  $ to have shorter characters
    QUAD N1 #L1+1  N4 #L1+11 N3  #L2+11 N2  #L2+1  T 0 M 1 N 5 c 2E5 ct 1E5
    QUAD N1 #L1+11 N4 #L1+21 N3  #L2+21 N2  #L2+11 T 0 M 1 N 2 c 2E5 ct 1E5
    QUAD N1 #L1+21 N4 #L1+31 N3  #L2+31 N2  #L2+21 T 0 M 1 N 2 c 2E5 ct 1E5
    $ N1-N4-N3-N2 to point local z downwards for nonlinear lifting of bedding

  GRP 8 titl 'stiffening plate'
    TRUS NA #plane1+27  #plane1+29 NCS 8 $ to avoid big rotation of the steel plate

  GRP 9 titl 'coupling to node 1'
    NODE #plane1+29 fix KF 1
endloop
END

!#!KAPITEL Linear Analysis
+prog sofiload urs:4
head Loading
LC 901 type none titl 'PG'
  node 1 PG  10000
LC 902 type none titl 'MY'
  node 1 MY  20000
LC 903 type none titl 'PXX'
  node 1 PXX -1000
end

+prog ase urs:2
HEAD
LC 901
LC 902
LC 903
END

!#!KAPITEL Smeared reinforcement in cracked concrete TCM Triple_Crack_Model
+PROG BEMESS urs:13
HEAD Parameters Circular reinforcement
DI3D 0 0  X 0 Y 0 $ BRIC
PARA NOG - DU 20[mm] ASU 100 200 50
END

$  Mögliche Definitionen:
$  RI3D 0 0
$      1. Bewehrungsrichtung = global-X   2.=global-Y   3.=global-Z
$  RI3D OAL...OAF... ohne Eingabe zu einem Mittelpunkt:
$      Erst Drehung OAL um global-Z
$      dann Drehung um neue 1. Bewehrungsrichtung
$  RI3D mit Eingabe zu einem Mittelpunkt:
$      X und Y sind zusätzlich mit OAL+OAF erlaubt.
$      Eingabe Z nur zulässig mit OAL=OAF=0
$
$      Kreisbewehrung um X,Y (ohne Z Eingabe):
$      Standard Fall mit OAL=OAF=0:
$        z.B. Windanlage-Kreisfundament oder Behälter:
$        RI3D OAL 0 OAF 0  X 0  Y 0
$           1. Bewehrung = radial
$           2. Bewehrung = tangential
$           3. Bewehrung = global z
$      Spezialfall mit OAL+OAF:
$        Zusätzliche Drehung OAL um global-Z
$        dann Drehung um neue 1. Bewehrungsrichtung
$        z.B. Kegel (Klärbecken) mit 30 Grad Gefälle:
$        RI3D OAL 90 OAF 30  X 0  Y 0
$
$      Sonderfall Eingabe Z: nur zulässig mit OAL=OAF=0:
$      Eingabe Y,Z ohne X: Rotationsachse = X um Punkt Y,Z
$      Eingabe X,Z ohne Y: Rotationsachse = Y um Punkt X,Z

+PROG ASE urs:6
HEAD Smeared TCM Triple_Crack_Model
GRP - ; GRP 5 prex 150 $ Prestress bolts
LC 904 DLZ 1 titl 'G_1+PG+MY+Pxx'
  LCC 901,902,903
END

+PROG ASE urs:5
HEAD Smeared TCM Triple_Crack_Model
syst prob nonl nmat yes tol -10.0
GRP - ; GRP 5 prex 150 $ Prestress bolts
LC 914 DLZ 1 titl 'Cracked G_1+PG+MY+Pxx'
  LCC 901,902,903
END

<TEXT> Overview examples:

- lade_concrete_calibration.dat
    Wall with uniaxial pressure to calibrate the LADE material input (uniaxial compression strength)

- bric_concrete.dat
    Single span beam, LADE Triple_Crack_Model, reinforcement with real beam elements

- bric_smeared_cracked_girder.dat
    Two span girder, LADE Triple_Crack_Model, smeared reinforcement with BEMESS input
    Main Smeared reinforcement result: WINGRAF - design - volume - nonlinear - steel stress

- volume_meshing_video.dat
    Wind turbine foundation, LADE Triple_Crack_Model, smeared reinforcement in circular direction
    SOFIMSHA input: see also YOUTUBE Video : search for SOFiSTiK Volume Meshing SOFIMSHA

- bric_lade_yield_surface_plot.dat
    Creates a .cdb with the yield surface for animation of the yield surface

</TEXT>

$ Clean file folder:
+sys del $(project).$d?