+PROG TEMPLATE urs:1
KOPF Parameter

!Geometrie
sto#b  0.3   ! Trägerbreite [m]
sto#h  0.4   ! Trägerhöhe [m]
sto#L  3.8   ! Trägerlänge [m]

!Material
 !Beton
sto#fck  30    ! Chark. Zylinderdruckfestigkeit [N/mm²]

!Bewehrung
 !untere Lage
STO#N1   3                  ! Anzahl Bewehrungsstäbe
STO#Ds1 14                  ! Durchmesser [mm]
STO#As1 =PI*#Ds1^2/400*#N1  ! Fläche [cm²]
prt#As1
STO#d1 50                   ! Abstand SP Bew. - UK Balken [mm]

 !obere Lage
STO#N2   2                  ! Anzahl Bewehrungsstäbe
STO#Ds2 10                  ! Durchmesser [mm]
STO#As2 =PI*#Ds2^2/400*#N2  ! Fläche [cm²]
prt#As2
STO#d2 50                   ! Abstand SP Bew. - OK Balken [mm]

ENDE

!+!Kapitel Querschnitt
+PROG AQUA urs:2
KOPF Querschnittsdefinition
ECHO VOLL extr

NORM DIN EN199x-200x  $ Version 2022: EN199x-200x

! Materialien
BETO 1 ART C FCN #fck !FCT 5 FCTK 5
STAH 2 ART B GUET 500B FY 500 FT 540  ! Betonstahl
ARBL EPS GEBR 1.0 TS I MUET #As1/(#b*2.5*#d1*10) FCTF 1.0

! Querschnitt
QB 1 H #h*1000 B #b*1000 MNR 1 SO #d2 SU #d1 BTYP ecke DASO #ds2 DASU #ds1 MBW 2 !ASB #pi*0.3^2/0.15

QNR 2 MNR 1 MBW 2 BEZ 'Rechteckquerschnitt'
  QPOL u
  QP  11  #b*1000/2 -#h/2*1000
      12     =       #h/2*1000
      13 -#b*1000/2    =
      14     =      -#h/2*1000

! Bewehrung
  RANG 1 TID 'Asl,o' MBW 2  typ min
       2 TID 'Asl,u' MBW =  typ =
  LBEW 'L1'  YA -#D2 ZA  #D2 REFA 11     $$
             YE  #D2 ZE  #D2 REFE 14 A #N2[-] D #DS2 RANG 1 TORS AKTI
  LBEW 'L2'  YA -#D1 ZA -#D1 REFA 12     $$
             YE  #D1 ZE -#D1 REFE 13 A #N1[-] D #DS1 RANG 2 TORS AKTI

QNR 3 MNR 1 MBW 2 BEZ 'Recht 1            '
  QPOL upz
  QP  11  #b/2[m]   -#h/2[m]
      12     =       #h/2[m]
  LBEW 'L1'  YA -#D2 ZA  #D2  refa 11  YE  -((#b*1000)-#D2) ZE  #D2  refe 11  A #N2[-] D #DS2 RANG M1 TORS  -    $ Rangtyp M für Mindestbewehrung
       'L2'  YA -#D1 ZA -#D1  refa 12  YE  -((#b*1000)-#D2) ZE -#D1  refe 12  A #N1[-] D #DS1 RANG M1 TORS  -    $ Rangtyp M für Mindestbewehrung

QNR 4 MNR 1 MBW 2 BEZ 'Recht 2            '
  QPOL upz
  QP  11  #b/2[m]   -#h/2[m]
      12     =       #h/2[m]
  LBEW 'L1'  YA -#D2 ZA  #D2  refa 11  YE  -((#b*1000)-#D2) ZE  #D2  refe 11  A #N2[-] D #DS2 RANG M1 TORS  -  dist full   $ DIST-Verteilung FULL
       'L2'  YA -#D1 ZA -#D1  refa 12  YE  -((#b*1000)-#D2) ZE -#D1  refe 12  A #N1[-] D #DS1 RANG M1 TORS  -  dist  =
ENDE



+PROG RESULTS urs:3  $ Grafiken zur definierten Bewehrung
 SIZE DINA "-URS" TEIL "2x1"
 TXTP SHOW RELE OVLP AMAX EXTR   JA
 LF   qnr 1 BA 9999;  QUER TYP NAME STYP  PPT DARS DSCH FILL NEIN SCHR 0.30
                        UND
                      QUER TYP   AR STYP  BEW DARS DSCH FILL NEIN SCHR 0.35
 LF   qnr 2 BA 9999;  QUER TYP NAME STYP  PPT DARS DSCH FILL NEIN SCHR 0.30
                        UND
                      QUER TYP   AR STYP  BEW DARS DSCH FILL NEIN SCHR 0.35
 LF   qnr 3 BA 9999;  QUER TYP NAME STYP  PPT DARS DSCH FILL NEIN SCHR 0.30
                        UND
                      QUER TYP   AR STYP  BEW DARS DSCH FILL NEIN SCHR 0.35
 LF   qnr 4 BA 9999;  QUER TYP NAME STYP  PPT DARS DSCH FILL NEIN SCHR 0.30
                        UND
                      QUER TYP   AR STYP  BEW DARS DSCH FILL NEIN SCHR 0.35
ENDE



!+!Kapitel CAPA

+PROG AQB urs:5
KOPF Interaktionskurven
ECHO VOLL EXTR; echo bew,beme,dehn extr

CAPA NQ 1 TASK MC STAT SL MY 1000 N 0
CAPA NQ 2 TASK MC STAT SL MY 1000 N 0

CAPA NQ 3 TASK MC STAT SL MY  800 N 0  mz 800  $ Einfluss der Bew.verteilung bei Doppelbiegung
     NQ 4 TASK =  STAT =  MY  =   N =  mz  =

ENDE


+PROG AQB urs:4 $ Bew.ausgabe durch AQB bei BEME und DEHN
 echo bew extr
 KOPF SCHULBEISPIEL ZUR BEMESSUNG 2
 BEME ZUS BRUC SMOD KEIN
 S 3 1 0.0 N    0 MY  10
   ende
 echo bew extr
 S 3 1 0.0 N    0 MY  10
 DEHN S0 RW 0.2 CHKC -0.6 CHKS 0.80 CHKT 1.0
ende