!#!Info  Example:       Beam hinges
!#!Info  Keyword:       plastic hinge; framework
!#!Info  Program:       ASE
$
$

$ english file name: hinge01.dat
+PROG AQUA urs:2
HEAD material and hinge definition
NORM 'BS' 'en1992-2004'
UNIT 5
$ working laws
SFLA   U      F  NO=111 TYPE=MY  $ rotational spring
$    $ mrad   kNm
   -10.0   -200.0
    -2.0   -200.0
     0.0      0.0
    +2.0   +200.0
   +10.0   +200.0

ECHO SECT

STEE 1 S 235
SECT 1 ; PROF - hea 200 ; SV IT 0.001 $ for higher IT -> TH3
SECT 2 ; PROF - hea 300 ; SV IT 0.001 $ for higher IT -> TH3

END

+PROG SOFIMSHA urs:1
HEAD
UNIT 5 ; SYST SPAC GDIV 1000
NODE no  x  y  z  fix
    101  0  0  0  F
    201  0  0 -4  py ! for TH3 Stability
    301  0  0 -8  py
    102  6  0  0  F
    202  6  0 -4  py
    302  6  0 -8  py

GRP 1
  BEAM NA NE NO=fit NCS=1 DIV=4 KR=YY
      101 201
      201 301
      102 202
      202 302
GRP 2
  BEAM fit 201 202 NCS 2 AHIN 111 EHIN 111 DIV 10
  BEAM fit 301 302 NCS 2 AHIN 111 EHIN 111 DIV 10
END

+PROG SOFILOAD urs:30
HEAD
UNIT 5 $ units: sections in mm, geometry+loads in m
LC 101
  NODE  301     TYPE PX 170
  NODE  301,302 TYPE PZ 800
LC 102
  COPY 101
END

+PROG ASE urs:7
HEAD linear analysis
LC 101 TITL linear
END


+PROG ASE urs:31
HEAD nonlinear hinges
SYST PROB NONL
LC 102 TITL nonlinear
END

+PROG ASE urs:32
HEAD TH3 with faktor 0.65
SYST PROB TH3 ITER 100
LC 103 TITL TH3_fact_0.65
  LCC 102 FACT 0.65

END

+PROG WING urs:33
HEAD
LC NO 101 ; BEAM TYPE MY UNIT 250 SCHH 0.30 ND 1
LC NO 102 ; BEAM TYPE MY UNIT 250 SCHH 0.30 ND 1
LC NO 103 ; BEAM TYPE MY UNIT 250 SCHH 0.30 ND 1
END