!#!Info  Example:       Slip-Cable with friction
!#!Info  Keyword:       slip-Cable; crosshead; cable; friction
!#!Info  Program:       ASE
$

+PROG AQUA URS:1
HEAD
ECHO PICT no
NORM 'DIN' 'en1992-2004'
CONC 1   C   30      $ C 30  =   C30/37  !
STEE 2   S  500
STEE 3   Y 1770
STEE 4   S  235 TMAX 0
SCIT 1 D 500[mm] MNO 1
SCIT  2 MNO 4 D 20 $ tube or cable
END

+PROG SOFIMSHA URS:2
HEAD Slip mue
UNIT 5 $ units: sections in mm, geometry+loads in m
SYST spac GDIR NEGZ GDIV 1000
NODE  1   0 0 0 FIX  F ; 2 0 0 10 ; 3 0 0 15
NODE 12 -12 0 0 FIX PP ; 13 +12 0 0 FIX PP
GRP 1 ; BEAM - 1  2       ; BEAM - 2 3
GRP 2 ; CABL - 12 2 NCS 2 ; CABL - 2 13 NCS 2
END

+PROG SOFILOAD urs:5
HEAD
LC 901 TYPE NONE
  CABL grp 2 TYPE vx 100
LC 902 TYPE NONE
  NODE 2 PX 50
END

+PROG ASE URS:8
Head
slip -
syst prob LINE
LC 1 FACD 1 titl 'without SLIP'
  LCC 901,902
END

$ +PROG ASE URS:8
Head
slip 2 nog 2
syst prob LINE
LC 2 FACD 1 titl 'SLIP without mue'
  LCC 901,902
END

$ +PROG ASE URS:8
syst prob NONL
slip 2 nog 2 mue 0.20
LC 3 FACD 1 titl 'SLIP mue NONL'
  LCC 901,902
END

syst prob TH3
slip 2 nog 2 mue 0.20
LC 4 FACD 1 titl 'SLIP mue TH3 +inner cable sagging'
  LCC 901,902
END

+PROG WING urs:7
HEAD
VIEW TYPE DIRE X 0 Y 1 Z 0 AXIS NEGZ ROTA 0
loop#i0 4
  let#i1 #i0+1
  LC NO #i1 ; BEAM TYPE  N UNIT DEFA SCHH 0.50 STYP CABL FILL NO REPR DLIN
    AND ; NODE TYPE UX UNIT DEFA SCHH 0.50 FILL NO REPR DVEC
    AND ; NODE TYPE SX UNIT DEFA SCHH 0.50 FILL NO REPR DVEC
endloop
BEAM TYPE UZ UNIT DEFA SCHH 0.50 STYP CABL FILL NO REPR DLIN

END

$ Clean file folder:
+sys del $(project).$d?