!*!Label  Input variables
#define fck =  50    $MPa
#define height = 350    $   [mm]    Height of the rectangular
#define width  = 150    $   [mm]    Width of the rectangular
#define c_min  = 45     $   [mm]    Concrete cover
#define D_low  = 18     $   [mm]    Diameter bar lower reinforcement
#define n_min  = 4      $   [-]     Number of bars


+prog aqua urs:1
head  Eurocode, materials
!*!Label  Eurocode
NORM DC EN NDC 199x-200x

!*!Label Materials
conc no 1 type c fcn $(fck) titl 'in-situ concrete'
stee no 2 type b clas 500B titl 'reinforcement steel'

!*!Label Cross-section
sect 1 mno 1 mrf 2 titl 'girder
poly type rec+ mno 1 dy $(width) dz $(height)
lrf no 1 yb $(width)/2-$(c_min) zb $(height)-$(c_min) ye -($(width)/2-$(c_min)) ze $(height)-$(c_min) lay 1 D $(D_low) A -$(n_min) tors acti dist full
end

+prog sofimsha urs:2
head  beam
syst 3D gdiv 10000

node    no  X   Y
        101 0   -0.1
        102 0   0
        103 0   0.1
        201 10  -0.1
        202 10  0
        203 10  0.1
        901 10   0 $ detector node
grp 2
    beam na 102 202 ncs 1 div 10
    node no fix
         102 ppmb
         202 xpmx
         101,103 pxmy
    node no
         201,203 fix kf nr1 202  $   Fixed connection to rigid boddy at the reference node

end

+prog sofiload urs:3
head Loads definition
!*!Label permanent loads
act type G
lc 1 dlz 1 titl 'self-weight'
lc 2 titl 'Pavement load'
    beam grp 2 type PG PA 2.4

!*!Label variable loads
act type Q
lc 3 titl 'traffic load'
    beam grp 2 type PG PA 9
echo act full
echo load extr
end


+prog ase urs:4
head linear calculation
LC 1,2,3 titl 'linear'
end

+prog ase urs:5
head  non-linear calculation
syst prob nonl
nstr kmod S1 ksv pl
LC 4 facd 1 titl 'non-linear'
    lcc 2,3
end


+PROG WING urs:7
HEAD  Plot results
SIZE TYPE URS SC 0 SPLI '3*1'
VIEW TYPE DIRE X 0 Y -1 Z 0 AXIS POSZ ROTA 0
SCHH H6 0.450000
LC 4
        BEAM TYPE VY UNIT DEFA SCHH YES STYP BEAM FILL NO REPR DLIN
        BEAM TYPE MY UNIT DEFA SCHH YES STYP BEAM FILL NO REPR DLIN
        BEAM TYPE MY UNIT DEFA SCHH YES STYP DSLN FILL NO REPR DLIN $ DECREATOR MY
        BEAM TYPE sigd UNIT DEFA SCHH YES STYP BEAM FILL NO REPR DLIN
END