!#!Info  Example:       post-tensioning with TENDON
!#!Info  Keyword:       check beam internal forces, stresses and displacements

+prog aqua urs:1
head
echo mat full

norm en 199X-200X 00

conc 1 c 30
stee 2 y 1860

srec 1 500 500 mno 1


end


+prog sofimsha urs:2
head

syst 3d gdiv 1000 gdir posz

node (1 2 1) x (0 10) y -.25 z 0
node (3 4 1) x (0 10) y  .25 z 0

node 1 fix pxpypz
node 2 fix   pypz
node 3 fix   pxpz
node 4 fix     pz


grp 1
quad mesh 1 2 4 3 t 500 mno 1 m 10 n 1

end


+prog sofimshc urs:6
head

syst rest

gax 'axis' tend
gaxa s  1 x  0 y 0 z 0
gaxa s  2 x 10 y 0 z 0

end


+prog tendon urs:3
head post tensioning

SYSP NOPS 1 COMP SUSP ETA NO 404 MAT 2 zv 4*150 sp 0 mue 0 $ nominal force 4*150 and slip and mue 0

AXES NOH 1 TYPE  refx val1 axis kind quad
TOPP NOH 1 KIND refx S 1,2 SP 1,2
TGEO NOG 1 NOH 1 NOPS 1
PTUV    S     U     V     DVS    TYPE=SPAN
        1     0     0.0      -
        1.50  -     0.2      0
        2     0     0.0     -


CS ICS1 20 999 $ unbonded

$ CS ICS1 20 21 $ bond from CS 21

psig ri k2 1000 k4 1000 $ enforce limit of 1000MPa

TEND NOT 1 NOG 1 NTEN 1 LC 20

ECHO PLOT full
SCHH h2 0.25
PLOT FACT NO 1 FACH 5

end


+prog sofiload urs:4
head

lc 1 none
quad grp 1 type pg 1.5


lc 10 type q
quad grp 1 type pg 5


end


+prog csm urs:5
head post tensioning

$ using the CSM construction sequence tendons always generate stress increments (reason: elongations along the member)

cs  no type titl
    10 g_1  concreting
    20 p    prestress   $facp 0.4
    30 g_2  g2
    40 c_1  c+s      t 28 rh 70 temp 20 ncre 1

grp no ics1 atil t0
     1  10   -   28

lc 1 g_2 30

end

+apply $(name)_csm.dat


+prog ase urs:7
head live load

$ in a single ASE using appropriate GRP CS the stress increment can be negelected

grp - cs 50

lc 10
end