!----------------------------------------------------
!---------Abbau der Zwangsschnittgrößen am-----------
!-------------Beispiel einer Kragstütze--------------
!____________________________________________________

!#!Kapitel Zusatzbetrachtung Kriechen und Schwinden
!+!Kapitel Materialien, Querschnitt, System
+PROG AQUA urs:5
KOPF Materialien und Querschnitte
ECHO MAT,QUER,QDEF VOLL
ECHO PICT VOLL
!*!Label Norm
NORM DC DIN NDC EN1992-2004 COUN 49 CAT D

!*!Label Materialeigenschaften

BETO NR 101 ART C FCN 40
STAH NR 102 ART B GUET 500

QB NR 100 H 400 B 400 SO 50 SU 50 MNR 101 MBW 102 BTYP ECKE DASO 20 ASB 2.5
ENDE

+PROG SOFIMSHC URS:8
KOPF System
SYST 3D GDIV 1000 GDIR POSZ
STEU MESH 1
STEU HMIN 1
ECHO MAT VOLL

SPT NR 101         X 0 Y 0 Z 0       FIX F
SPT NR (102 106 1) X 0 Y 0 Z (-1 -1)

SLN - NPA 101 NPE 102 QNR 100 GRP 100
SLN - NPA 102 NPE 103 QNR 100 GRP 100
SLN - NPA 103 NPE 104 QNR 100 GRP 100
SLN - NPA 104 NPE 105 QNR 100 GRP 100
SLN - NPA 105 NPE 106 QNR 100 GRP 100

ENDE

!#!Kapitel Zeitunabhängige Verschiebung (SOFILOAD + CSM)
+PROG SOFILOAD urs:9
KOPF Definition der Einwirkungen und Lasten
UNIT 5
ECHO ACT VOLL

ACT G_1 BEZ 'Eigengewicht'
ACT G_2 BEZ 'Zwangsverformung'
ACT C   BEZ 'Kriechen + Schwinden'

LF 2 TYP 'none' BEZ 'Zwangsverformung'
   KNOT 106 TYP WXX -100
ENDE

+PROG ASE urs:10
KOPF THI t=0
LF 2
ENDE

+PROG CSM urs:11
KOPF Bauablauf
STEU KRIE RKRI
STEU PROB TH3
STEU EG AUTO        ! Eigenlast wird automatisch angesetzt

BA 10 TYP G_1
BA 20 TYP G_2 BEZ 'Zwang'
BA 30 TYP C T 365*100 NKRI 10

GRUP NR - IBA1 10 T0 7 BEZ 'Aktivierung aller Elemente'

LF NR 2 IBA1 20 WBIS -
ENDE

+apply "$(NAME)_csm.dat"

!+!Kapitel Nichtlineare Analyse
!!! Zeitunabhängige Verschiebung (CSM) --> mit K+S
+PROG STAR2 urs:3
KOPF Nichtlineare Analyse
ECHO LAST JA
ECHO DEHN JA
ECHO MAT  JA

LOOP#i 10

LET#LF 20
LET#LC 4030

STEU II 20                                                 ! Theorie 2. Ordnung, weggesteuert, 20 Iterationen
DEHN S1 KSB SL KSV SL RISS JA RW 999                       ! Ermittlung der Sekantensteifigkeit bei vorgegebenem Moment
LF #LF+#i EGZ 1.0                                             ! Eigengewicht Pfeiler + ständige Lasten aus Überbau
    LC #LC+#i
ENDE
ENDLOOP
ENDE

!!! Zeitunabhängige Verschiebung (ASE) --> ohne K+S
+PROG STAR2 urs:14
KOPF Nichtlineare Analyse
ECHO LAST JA
ECHO DEHN JA
ECHO MAT  JA

STEU II 20                                                 ! Theorie 2. Ordnung, weggesteuert, 20 Iterationen
DEHN S1 KSB SL KSV SL RISS JA RW 999                       ! Ermittlung der Sekantensteifigkeit bei vorgegebenem Moment
LF 30 EGZ 1.0                                             ! Eigengewicht Pfeiler + ständige Lasten aus Überbau
    LC 2
ENDE