!#!Info  Example:       Stress verification at prestressed concrete cross-section
!#!Info  Keyword:       Prestress Concrete, Stress, Construction stages
!#!Info  Program:       AQB

!#!Chapter Material and Cross-section

+PROG AQUA URS:1
HEAD Material and Cross-section definition
ECHO SECT,MAT YES
CTRL RFCS 2
NORM 'DIN' NDC 'EN199x-200x'
CONC 1   C 35
STEE 11  Y 1770
SECT  1  MNO 1
POLY  RECT MNO 1  DY 1[m] DZ 1[m]
END

!#!Chapter System definition

+PROG SOFIMSHA urs:6
HEAD Simply Supported Beam
ECHO FULL NO
SYST SPAC GDIV 1000 GDIR ZZ
NODE NO X  Y  Z
     1  0  0  0  FIX PPMX
     2  10 0  0
     3  20 0  0  FIX XPMX
GRP 10
BEAM FIT 1 2  NCS 1 DIV 10
BEAM FIT 2 3  NCS 1 DIV 10
END

!#!Chapter Tendon

+PROG TENDON urs:9
HEAD Prestressing
ECHO FULL NO
ECHO SYSP,TGEO YES
UNIT 5                                 $ units: sections in mm, geometry+loads in m
SYSP NOPS 19 MAT 11 ZV 3899 AZ 2850 LITZ 19 MINR 8.60 BETA 0.30 MUE 0.21 ECC 0 SP 3 DO 97 $19 wires:  A_p = 19*150mm^2 = 2850 mm^2
AXES NOH 1  VAL1  0.00 0.00 0.00  TYPE POLY  KIND BEAM
         1  VAL1 20.00 0.00 0.00  TITL "tendon_axis"
TOPP NOH 1 KIND REFX S 0,20 SP 1,2
TGEO NOG 1 NOH 1 NOPS 19               $ Tendon geometry
PTUV S U   V DVS TYPE=SPAN             $ definition points of geometry: TYPE = SPAN station via high points
     1 0 0.0   -
  1.50 - 0.4   0
     2 0 0.0   -
CS ICS1 11 ICS2 12 ICS3 -              $ construction stages
PSIG 'LE' ANWS 'TS' KAPA 1.5           $ prestress-procedure
TEND NOT 1 NOG 1  LC 2
$ tendon plots:
ECHO plot full
SIZE W 30
SCHH H1 0.50 H3 0.20
PLOT GEOE NO 0 FACH  5 TYPG DUTE PCS 1 $ plot tendon geometry
PLOT FACT NO 1 FACH 50                 $ plot stresses and forces
END


!#!Chapter Analysis

+PROG SOFILOAD URS:13
HEAD Loading
PAGE UNII 5
ECHO FULL NO
ACT G_1,P
LC  1 DLZ 1.0 TYPE 'G_1' TITL 'G'
LC  2         TYPE 'P'   TITL 'P'
END

+PROG ASE URS:4
HEAD Analysis
ECHO full no
LC 1 TYPE 'G_1'
LC 2 TYPE 'P'
END

!#!Chapter  P CS0

+PROG AQB urs:2
HEAD P CS0
ECHO FULL NO
ECHO COMB,TABS
CTRL
BEAM 10010 X 1.0 CS0 11 CS1 12
LC 2 TYPE p   CST  CS0
COMB SUM LC1 p  LCST 100
STRE K
END

!#!Chapter  G+P CS0

+PROG AQB urs:3
HEAD  G+P CS0
ECHO FULL NO
ECHO COMB,TABS
BEAM 10010 X 1.0 CS0 11 CS1 12
LC 1 TYPE G_1 CST  CS0
LC 2 TYPE P   CST  CS0
COMB SUM LC1 G LC2 P LCST 101
STRE E
END

!#!Chapter  P CS1

+PROG AQB urs:7
HEAD P CS1
ECHO FULL NO
ECHO COMB,TABS
BEAM 10010 X 1.0 CS0 11 CS1 12
LC 2 TYPE p   CST  CS1
COMB SUM LC1 P  LCST 102
STRE E
END

!#!Chapter  G+P CS1

+PROG AQB urs:8
HEAD  G+P CS1
ECHO FULL NO
ECHO COMB,TABS
BEAM 10010 X 1.0 CS0 11 CS1 12
LC 1 TYPE G_1 CST  CS1
LC 2 TYPE P   CST  CS1
COMB SUM LC1 g  LC2 p  LCST 103
STRE E
END



!#!Chapter  CSM

+PROG CSM urs:10
head
CTRL    DL  NO

CS  NO  TYPE
    11  P
    12  -
    20  -


GRP NO  ICS1
    10 11


END

+apply "$(NAME)_csm.dat"

!#!Chapter Results

+prog template urs:5
HEAD Result summary

$ Reference values
LET#X_REF    -12.47,-4.82,-11.76,-4.51 $ [MPa]
LET#D_ABS_ALL   3.0                    $ absolute tolerance
LET#D_REL_ALL   3.0                    $ relative tolerance

$ Extract calculated value from database
LOOP#i 4
        @KEY BEAM_STR   100+#i  10010  $ cdb record 105 = Stresses in cross-section of beams, loadcase number, beamnumber
        STO#X(#i)   @(2)/1000          $ stress at bottom
ENDLOOP
$ compute deviation
LOOP#i X
   LET#D_ABS(#i)  ABS(#X_REF(#i)-#X(#i))
   LET#D_REL(#i)  ABS(#D_ABS(#i)/#X_REF(#i)*100.0)
ENDLOOP

$ Printouts
STO#PRINT1  'I','II','III','IV'
STO#PRINT2  '  0',' 0','1',' 1'
$ Print summary
TXB <b>Stresses at concrete</b>
TXB
TXB
TXB  Case   CS    sigma,ref   sigma,calc   diff     diff    tol_all   result
TXB                [MPa]       [MPa]       [MPa]     [%]      [%]
TXB --------------------------------------------------------------------------------
LOOP#i X
  LET#IS_OK 0
  IF (#D_REL<#D_REL_ALL)
          LET#IS_OK 1
  ENDIF
  IF (#IS_OK==1)
    TXB   #PRINT1(#i)    #PRINT2(#i)  #(#X_REF(#i),8.2)    #(#X(#i),8.2)  #(#D_ABS(#i),8.2)  #(#D_REL(#i),8.2) #(#D_REL_ALL,8.2)     <b>OK</b>
  ELSE
    TXB   #PRINT1(#i)    #PRINT2(#i)  #(#X_REF(#i),8.2)    #(#X(#i),8.2)  #(#D_ABS(#i),8.2)  #(#D_REL(#i),8.2) #(#D_REL_ALL,8.2)     <b>Failed</b>
  ENDIF
ENDLOOP
END

+PROG RESULTS urs:15
HEAD Plot Stresses for G+P CS0
SIZE TYPE "-URS"
VIEW TYPE DIRE X -0.795666 Y 0.483621 Z 0.364727 AXIS POSZ
DBO  NAME "beam_sss.sign"  ND   3
DBO  NAME "beam_sss._py"   ND   3
DBO  NAME "beam_sss._pz"   ND   3
LC   NO 101
LC   ENO 10010 X 1
CROS TYPE SIG ETYP BEAM RTYP NONL REPR DLIN FILL NO SCHH 0.4
END

+PROG WING urs:11
HEAD Plot Structure
PAGE UNII 0
CTRL OPT INP
CTRL OPT GSTR VAL DEFA
CTRL OPT AXIS VAL DEFA
PAGE LANO 1 UNIO 5
SIZE TYPE URS SC 0
SIZ2
AND  POSI 1 POSL 0 POSR 100 POSD 0 POSU 100
SCH3 HSUP 0.700000
GRID TYPE NO DIRE DEFA OFFP 0 OFFC 0 OFf3 0 TOLA 15 TOLZ -5
COLO   C12 1317
COL2   C5 1771   C21 1771 C22 1771 C23 1771 C24 1771
LC   NO 1 DESI 1
BOX
VIEW TYPE DIRE X 0.864813 Y -0.422351 Z 0.271511 AXIS POSZ ROTA 0
DEFO TYPE NO EXPO 0 SMOV NO
SELE NUMB 0
STRU NUME FULL FILL NO REPR DSTR UNIT DEFA SCHH FIBU
END