+PROG AQUA urs:1
KOPF 'Definition of Cross sections'

NORM 'DIN' 'en1992-2004'

echo voll extr


BETO 2    C '40' GAM 26 TYPR    B BEZ "=C 40/50 (EN 1992)"

STAH 11    B '500B' TMAX 32 BEZ "=B 500 B (EN 1992)"
stah 12    Y 1770C

let#asa         10
let#asb         10

let#dasa        25
let#dasb        16

let#b         1000
let#h          305

let#su        60+16/2
let#so        60+32/2
let#ss          30



QNR 44 MNR 2 MBW 11 ZSYM NEIN BTYP BEAM
QW   IT 100[o/o]
RANG  1 TYP  MIN MBW 11  TID MBE
RANG  2 TYP  opt MBW 11  TID MUP
RANG  3 TYP  OPT MBW 11  TID BE
RANG  4 TYP  min MBW 11  TID UP

RANG  5 TYP  OPT MBW 11  TID TOR



QPOL ART    U MNR 2
QP '0100' Y -#b/2[mm]      Z -#h/2[mm] EXP 1
QP '0101' Y #b/2[mm]       Z -#h/2[mm] EXP 1
QP '0102' Y #b/2[mm]       Z #h/2[mm]  EXP 1
QP '0103' Y -#b/2[mm]      Z #h/2[mm]  EXP 1
QP '0100' Y -#b/2[mm]      Z -#h/2[mm] EXP 1



$ Erzeuge Torsionsbewehrung in den 4 Ecken
BEW   '-Y-Z'  Y  -#b/2+#ss[mm] Z   -#h/2+#so[mm]  rang z5  tors akti
BEW   '+Y-Z'  Y  #b/2-#ss[mm]  Z   -#h/2+#so[mm]  rang z5  tors akti
BEW   '+Y+Z'  Y  #b/2-#ss[mm]  Z   #h/2-#su[mm]   rang z5  tors akti
BEW   '-Y+Z'  Y  -#b/2+#ss[mm] Z   #h/2-#su[mm]   rang z5  tors akti



QS  'ZS' ZA 'S' NS 0 MS 0 MNR 2 MBW 11 RANG 1 TYP  STEG BNEI 90


!*!Label Bewehrungsdefintion/ Defintion of the reinforcement -----------------------------------------------------------Min↓-----------Max↓
LBEW  'UP-M' YA -#b/2+#ss[mm] ZA -#h/2+#so[mm] YE #b/2-#ss[mm] ZE  -#h/2+#so[mm]   AS    10[cm2]   asma 30[cm2]      RANG   M1        TORS PASS         DIST full                 $D #dasa A 100
LBEW  'UP-O' YA -#b/2+#ss[mm] ZA -#h/2+#so[mm] YE #b/2-#ss[mm] ZE  -#h/2+#so[mm]   AS    10[cm2]   asma 30[cm2]      RANG   z2        TORS PASS         DIST even      D    #dasa

LBEW  'BE-M' YA -#b/2+#ss[mm] ZA #h/2-#su[mm]  YE #b/2-#ss[mm] ZE  #h/2-#su[mm]    as    10[cm2]   asma 30[cm2]      RANG   z3        TORS PASS         DIST even      D    #dasb
LBEW  'BE-O' YA -#b/2+#ss[mm] ZA #h/2-#su[mm]  YE #b/2-#ss[mm] ZE  #h/2-#su[mm]    AS    10[cm2]   asma 30[cm2]      RANG   M4        TORS PASS         DIST full                 $D #dasb A 100





ende

!#!Kapitel Erstellung der externen Schnitte/ Generation of the external sections
-prog aqb urs:2
kopf
stab von 1 x 0 nq 44 typ absc ba auto
stab von 2 x 0 nq 44 typ absc ba auto
stab von 3 x 0 nq 44 typ absc ba auto
ende



!#!Kapitel Umdefinition der Bewehrung/ Redefintion of the reinforcement
-prog aqb urs:4
kopf

stab von 1 x 0  typ absc ba   as ba1  5[cm2] ba2  5[cm2]
stab von 2 x 0  typ absc ba   as ba1 25[cm2] ba2 25[cm2]
stab von 3 x 0  typ absc ba   as ba1 35[cm2] ba2 35[cm2]

bew bmod einz lfb 1
ende




!#!Kapitel Siehe die berücksichtigte Bewherung im Report/ see considered reinforcement  in the report
-PROG AQB urs:3
KOPF 'ULS 1L'

SEIT UNIE 0
echo voll extr


stab von 1 x 0 typ absc
stab von 2 x 0 typ absc
stab von 3 x 0 typ absc

lf 1 (D)
S    MY       nr x
    -37.5     1  0
    -37.5     2  0
    -37.5     3  0


bew bmod accu lfb 1
bew bmod einz lfb 2

BEME ZUS BRUC amax fix

ENDE