!#!Kapitel Variablendefiniton
+prog template urs:2
kopf Variablendefinition
sto#fckF        25            $ Betondruckfestigkeit [MPa]
sto#fckS        25            $ Betondruckfestigkeit [MPa]
sto#teil        0.50         $ Netz                 [m]
sto#teilS       0.125         $ Netz der Stütze      [m]
sto#gdiv        100000         $ Gruppendivisor
sto#F  7        $ Last in MN

$ Geometrie
sto#L       8.00        $ Fundamentplatte Länge und Breite [m]
sto#b       0.50        $ Breite des QSs [m]
sto#h       0.50        $ Höhe des QSs [m]
sto#LS      5.00        $ Stützenhöhe [m]
sto#t       1.75        $ Fundamentstärke [m]

ende

!#!Kapitel Norm, Material
+prog aqua urs:1
kopf Norm, Material

$ Definition der Norm
norm dc oen ndc en199x-200x

$ Material + QS Stütze
echo voll
beto nr 1 art c fcn #fckF mue 0  bez 'Fundament'
beto nr 2 art c fcn #fckS mue 0  bez 'Stütze'
stah nr 3 art b 550
qb 1 h #h[m] b #b[m]  mnr 2  it 0  mbw 0

$Bohrenprofil
bohr 1 0 0 0
blay s 0    es 30000
blay s 5    es 48839
blay s 30   es 113444.1
blay s 100  es 200128.9
blay s 225
ende

!#!Kapitel Knoten + QUADs
+prog sofimsha urs:3
kopf Systemgenerierung
syst art 3D gdiv #gdiv

!*!Label Knoten
$ Stationen für Knoten
let#x 0,0,#L/2-#b/2,#L/2,#L/2+#b/2,#L
let#y 0,0,#L/2-(#h/2),#L/2,#L/2+(#h/2),#L
let#z 0,0,-#t,-(#t+#LS)

let#j 1
loop 3
 let#i 1
 loop 5
  let#k 1
  loop 5

knot nr (#j*1000+#k*100+#i)  x #x(#i) y #y(#k) z #z(#j)

  let#k #k+1
  endloop
 let#i #i+1
 endloop
let#j #j+1
endloop

!*!Label Flächenelemente des Grundrisses
grup 1
quad nr prop mnr 1 nra 7 t #t[m]

let#i 1
loop 4
  let#k 1
  loop 1

if (#i==1)|(#i==4)
let#m  max((#x(#i+1)-#x(#i))/#teil,1)
let#n  max((#y(#k+1)-#y(#k))/#teil,1)
let#j  1
quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n
else
   let#m  max((#x(#i+1)-#x(#i))/#teilS,1)
   let#n  max((#y(#k+1)-#y(#k))/#teil,1)
   let#j  1
   quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n
endif

  let#k #k+1
  endloop
let#i #i+1
endloop

let#i 1
loop 2
  let#k 2
  loop 2

let#m  max((#x(#i+1)-#x(#i))/#teil,1)
let#n  max((#y(#k+1)-#y(#k))/#teilS,1)
let#j  1
quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n

  let#k #k+1
  endloop
let#i #i+3
endloop

let#i 1
loop 4
  let#k 4
  loop 1

if (#i==1)|(#i==4)
let#m  max((#x(#i+1)-#x(#i))/#teil,1)
let#n  max((#y(#k+1)-#y(#k))/#teil,1)
let#j  1
quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n
else
   let#m  max((#x(#i+1)-#x(#i))/#teilS,1)
   let#n  max((#y(#k+1)-#y(#k))/#teil,1)
   let#j  1
   quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n
endif

  let#k #k+1
  endloop
let#i #i+1
endloop

grup 2
let#i 2
loop 2
  let#k 2
  loop 2

let#m  max((#x(#i+1)-#x(#i))/#teilS,1)
let#n  max((#y(#k+1)-#y(#k))/#teilS,1)
let#j  1
quad k4 (#j*1000+#k*100+#i) k3 (#j*1000+#k*100+#i+1) k2 (#j*1000+(#k+1)*100+#i+1) k1 (#j*1000+(#k+1)*100+#i)  m #m  n #n

  let#k #k+1
  endloop
let#i #i+1
endloop
ende

+PROG BEMESS urs:4
GEOM
PARA  DO 10 $ mm Eisendurchmesser
ENDE

+prog sofimsha urs:5
syst rest
$ Stütze + Kopplung
grup 3
stab nr 1 ka 1303 ke 3303 qnr 1 $anfa mymz

sbox a1x #L/2-#b/2 a1y #L/2-#h/2 a1z  0 $$
     b1x #L/2+#b/2 b1y #L/2-#h/2 b1z  0 $$
     a2x #L/2-#b/2 a2y #L/2-#h/2 a2z  0 $$
     b2x #L/2-#b/2 b2y #L/2+#h/2 b2z  0 $$
     a3x #L/2-#b/2 a3y #L/2-#h/2 a3z -0.01 $$
     b3x #L/2-#b/2 b3y #L/2-#h/2 b3z  0.01

knot nr sbox fix kf nr1 1303
ende

!+!Kapitel Load
+prog sofiload urs:7
kopf Last
LF nr 1 typ none  bez 'Normalkraft 7 MN'
point ref node nr 3303  typ pzz P #F*1000
ende

!+!Kapitel HR
+prog hase urs:10
KOPF Boden Steifigkeiten
SEIT UNIE 0
HALB ART KONS FAKX 0.40 FAKY 0.40 Z 0
BOHR 1
ENDE

!+!Kapitel Berechnung
+prog ase urs:8
kopf Berechnung
stex
lf 100 fakg 1 bez 'EG+N'
    lc 1
ende

+prog bemess urs:6
echo dust voll
echo dust 4
steu lfb 1
lf  100
grup 1,2
dust typ 1303
ende